793
| ID | 793 |
|---|
| Data | 2012-03-05 |
|---|
| Symbol | 2012/03/05/793 |
|---|
| Instytucja | Urząd Marszałkowski Województwa Świętokrzyskiego |
|---|
| Nazwa | Wniosek o zamówienie kopii map topograficznych ukł. „1965” |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
| URI://Dziennik_Ustaw/2011/206/1216/27/2 | Par. 27 ust. 2 rozporządzenia Prezesa Rady Ministrów z dnia 14 września 2011r. w sprawie sporządzania pism w postaci dokumentów elektronicznych, doręczania dokumentów elektronicznych oraz udostępniania formularzy, wzorów i kopii dokumentów elektronic... |
|---|
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.1" xmlns:wnio="http://crd.gov.pl/wzor/2012/03/05/793/" xmlns:adr="http://crd.gov.pl/xml/schematy/adres/2009/03/06/" xmlns:inst="http://crd.gov.pl/xml/schematy/instytucja/2009/03/06/" xmlns:meta="http://crd.gov.pl/xml/schematy/meta/2009/03/06/" xmlns:oso="http://crd.gov.pl/xml/schematy/osoba/2009/03/06/" xmlns:str="http://crd.gov.pl/xml/schematy/struktura/2009/03/06/" xmlns:ds="http://www.w3.org/2000/09/xmldsig#">
<xsl:output method="html" encoding="utf-8" indent="yes"/>
<xsl:template match="/wnio:Dokument">
<html>
<head>
<title>
<xsl:value-of select="wnio:DaneDokumentu/str:Naglowek/str:NazwaDokumentu"/>
</title>
<style type="text/css">
@media screen {
body, table {
font-size: 12px;
}
.NazwaDokumentu {
font-size: 14px;
}
}
@media print {
body, table {
font-size: 10px;
}
.NazwaDokumentu {
font-size: 12px;
}
}
@media screen,print {
body {
font-family: Verdana, Arial, sans-serif;
background-color: #FFFFFF;
margin: 5px;
padding: 0px;
border: none;
}
.DokumentObszar {
border: solid 1px #000000;
margin-bottom: 15px;
}
.DokumentTutul {
color: #ffffff;
font-weight: bold;
background-color: #000000;
padding: 7px;
}
.DokumentWartosc {
padding: 7px;
}
.NadawcyObszar,
.TworcyObszar,
.AdresaciObszar,
.TrescObszar,
.ZalacznikiObszar {
margin-bottom: 10px;
}
.NadawcyTytul1,
.TworcyTytul1,
.AdresaciTytul1,
.TrescTytul1,
.ZalacznikiTytul1 {
color: #000000;
font-weight: bold;
padding: 10px 7px;
}
.NadawcyTytul2,
.TworcyTytul2,
.AdresaciTytul2,
.TrescTytul2,
.ZalacznikiTytul2 {
color: #000000;
font-weight: bold;
padding: 7px;
border-bottom: solid 1px #cccccc;
}
.NadawcyObszar { border: solid 1px #375300; }
.NadawcyTytul1 { background-color: #dbe6c5; }
.NadawcyTytul2 { background-color: #f2f5eb; }
.TworcyObszar { border: solid 1px #430062; }
.TworcyTytul1 { background-color: #decae7; }
.TworcyTytul2 { background-color: #f0e9f4; }
.AdresaciObszar { border: solid 1px #003366; }
.AdresaciTytul1 { background-color: #c8d8e7; }
.AdresaciTytul2 { background-color: #e9eef4; }
.TrescObszar { border: solid 1px #7d0000; }
.TrescTytul1 { background-color: #e9cece }
.TrescTytul2 { background-color: #ffffff; }
.ZalacznikiObszar { border: solid 1px #626600; }
.ZalacznikiTytul1 { background-color: #e9e7cf; }
.ZalacznikiTytul2 { background-color: #ffffff; }
.Kategoria1 {
padding: 7px;
border-bottom: solid 1px #cccccc;
clear: both;
}
.Kategoria1Nazwa {
float: left;
width: 200px;
color: #666666;
line-height: 150%;
}
.Kategoria1Tresc {
height: 16px;
left: 230px;
line-height: 150%;
}
.KategoriaTytulNazwa {
float: left;
width: 200px;
color: #000000;
font-weight: bold;
line-height: 150%;
}
.KategoriaTytulTresc {
height: 16px;
left: 230px;
font-weight: bold;
line-height: 150%;
}
.KategoriaWyczysc {
font-size: 1px;
visibility: hidden;
clear: both;
}
.WierszPodkreslony {
padding: 7px;
border-bottom: solid 1px #cccccc;
}
.Grupa1 {
display: inline-block;
margin-right: 40px;
color: #000000;
}
.Grupa1Nazwa {
color: #666666;
}
.Blad {
color: #ff0000;
font-weight: bold;
padding: 5px;
}
.Tabela1 {
margin-top: 3pt;
margin-bottom: 10pt;
border-collapse: collapse;
empty-cells: show;
border: 1px solid #868686;
}
.Tabela1 th {
margin: auto;
text-align: center;
vertical-align: top;
background-color: #dcdcdc;
border: solid 1px #868686;
}
.Tabela1 td {
vertical-align: top;
border: solid 1px #868686;
}
.Tabela1 td.srodek {
text-align: center;
}
.Margines20 { margin-left: 20px; }
.Margines40 { margin-left: 40px; }
.Margines60 { margin-left: 60px; }
.Margines80 { margin-left: 80px; }
.Margines100 { margin-left: 100px; }
}
</style>
</head>
<body>
<div class="Dokument">
<div class="DokumentObszar">
<xsl:call-template name="NazwaDokumentuTmpl"/>
</div>
<div class="NadawcyObszar">
<xsl:call-template name="NadawcyTmpl"/>
</div>
<div class="TworcyObszar">
<xsl:call-template name="TworcyTmpl"/>
</div>
<div class="AdresaciObszar">
<xsl:call-template name="AdresaciTmpl"/>
</div>
<div class="TrescObszar">
<xsl:call-template name="TrescTmpl"/>
</div>
<xsl:call-template name="ZalacznikiTmpl"/>
</div>
</body>
</html>
</xsl:template>
<xsl:template name="TrescTmpl">
<xsl:param name="TrescSciezka" select="wnio:TrescDokumentu/wnio:Wartosc/wnio:TrescWniosku"/>
<div class="TrescTytul1"><xsl:text>Treść dokumentu</xsl:text></div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Zamówienie dotyczy obszaru:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:ZamawianyObszar != ''">
<xsl:value-of select="$TrescSciezka/wnio:ZamawianyObszar"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Brak informacji o obszarze, którego dotyczy zamówienie!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Nazwa gminy lub powiatu:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:NazwaGminyPowiatu != ''">
<xsl:value-of select="$TrescSciezka/wnio:NazwaGminyPowiatu"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Nie podano nazwy powiatu lub gminy!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Zamówione kopie map:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="ZamowioneMapyTmpl"/>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Razem egzemplarzy:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:RazemEgzemplarzy != ''">
<xsl:value-of select="$TrescSciezka/wnio:RazemEgzemplarzy"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Brak informacji o ilości zamawianych egzemplarzy!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Należność za wykonanie zamówienia opłacimy:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:SposobPlatnosci != ''">
<xsl:value-of select="$TrescSciezka/wnio:SposobPlatnosci"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Nie określono formy płatności za zamówienie!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Faktura bez podpisu zamawiającego:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:FakturaBezPodpisu != ''">
<xsl:value-of select="$TrescSciezka/wnio:FakturaBezPodpisu"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>Nie</xsl:text>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Forma odbioru zamówienia:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:FormaOdbioru != ''">
<xsl:value-of select="$TrescSciezka/wnio:FormaOdbioru"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Nie określono formy odbioru zamówienia!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Oświadczenie:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:choose>
<xsl:when test="$TrescSciezka/wnio:OswiadczenieReprodukcja != ''">
<xsl:value-of select="$TrescSciezka/wnio:OswiadczenieReprodukcja"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>Brak oświadczenia!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:template>
<xsl:template name="ZamowioneMapyTmpl">
<xsl:param name="MapySciezka" select="wnio:TrescDokumentu/wnio:Wartosc/wnio:TrescWniosku/wnio:ZamowioneKopie"/>
<xsl:if test="$MapySciezka and count($MapySciezka/wnio:ZamowionaKopia) > 0">
<div>
<table class="Tabela1" style="width: 98%;" cellspacing="0" cellpadding="5" border="0">
<tbody>
<tr>
<th style="width: 30px;"><xsl:text>Lp.</xsl:text></th>
<th><xsl:text>Nr sekcji:</xsl:text></th>
<th style="width: 80px;"><xsl:text>Ilość egzemplarzy:</xsl:text></th>
</tr>
<xsl:for-each select="$MapySciezka/wnio:ZamowionaKopia">
<tr>
<td class="srodek"><xsl:value-of select="position()"/><xsl:text>.</xsl:text></td>
<td><xsl:value-of select="./wnio:NrSekcji"/></td>
<td class="srodek"><xsl:value-of select="./wnio:IloscEgzemplarzy"/></td>
</tr>
</xsl:for-each>
</tbody>
</table>
<strong><xsl:text>Razem zamówionych kopii: </xsl:text>
<xsl:value-of select="count($MapySciezka/wnio:ZamowionaKopia)"/></strong>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="NazwaDokumentuTmpl">
<xsl:param name="TrescSciezka" select="wnio:TrescDokumentu/wnio:Wartosc"/>
<div class="DokumentTutul">
<xsl:value-of select="wnio:DaneDokumentu/str:Naglowek/str:NazwaDokumentu"/>
</div>
<div class="DokumentWartosc">
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Miejscowość: </xsl:text></span>
<xsl:value-of select="$TrescSciezka/wnio:RodzajWniosku/wnio:MiejscowoscDokumentu"/>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Data: </xsl:text></span>
<xsl:call-template name="PelnaDataTmpl">
<xsl:with-param name="PelnaDataSciezka" select="wnio:OpisDokumentu/meta:Data/meta:Czas"/>
</xsl:call-template>
</span>
</div>
</xsl:template>
<xsl:template name="AdresaciTmpl">
<div class="Sekcja">
<div class="AdresaciTytul1">
<xsl:text>Adresaci dokumentu</xsl:text>
</div>
<div class="SekcjaTresc">
<xsl:choose>
<xsl:when test="count(wnio:DaneDokumentu/str:Adresaci/meta:Podmiot) > 0">
<xsl:for-each select="wnio:DaneDokumentu/str:Adresaci/meta:Podmiot">
<div class="AdresaciTytul2">
<div class="KategoriaTytulNazwa">
<xsl:text>Adresat #</xsl:text>
<xsl:value-of select="position()"/>
<xsl:text>: </xsl:text>
</div>
<div class="KategoriaTytulTresc">
<xsl:call-template name="AdresatNazwaTmpl">
<xsl:with-param name="AdresatSciezka" select="current()"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="KategoriaTresc">
<xsl:call-template name="AdresatTmpl">
<xsl:with-param name="AdresatSciezka" select="current()"/>
</xsl:call-template>
</div>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<div class="Blad">
<xsl:text>UWAGA! Brak informacji o adresatach dokumentu!</xsl:text>
</div>
</xsl:otherwise>
</xsl:choose>
</div>
</div>
</xsl:template>
<xsl:template name="AdresatTmpl">
<xsl:param name="AdresatSciezka"/>
<xsl:if test="not($AdresatSciezka)">
<xsl:call-template name="AdresatTmpl">
<xsl:with-param name="AdresatSciezka" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$AdresatSciezka/@typPodmiotu = 'osoba'">
<xsl:call-template name="OsobaTmpl">
<xsl:with-param name="OsobaSciezka" select="$AdresatSciezka/oso:Osoba"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$AdresatSciezka/@typPodmiotu = 'instytucja'">
<xsl:call-template name="InstytucjaTmpl">
<xsl:with-param name="InstytucjaSciezka" select="$AdresatSciezka/inst:Instytucja"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template name="AdresatNazwaTmpl">
<xsl:param name="AdresatSciezka"/>
<xsl:if test="not($AdresatSciezka)">
<xsl:call-template name="AdresatNazwaTmpl">
<xsl:with-param name="AdresatSciezka" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$AdresatSciezka/@typPodmiotu = 'osoba'">
<xsl:call-template name="OsobaImieNazwiskoTmpl">
<xsl:with-param name="OsobaSciezka" select="$AdresatSciezka/oso:Osoba"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$AdresatSciezka/@typPodmiotu = 'instytucja'">
<xsl:value-of select="$AdresatSciezka/inst:Instytucja/inst:NazwaInstytucji"/>
</xsl:if>
</xsl:template>
<xsl:template name="OsobaTmpl">
<xsl:param name="OsobaSciezka"/>
<xsl:if test="not($OsobaSciezka)">
<xsl:call-template name="OsobaTmpl">
<xsl:with-param name="OsobaSciezka" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot/oso:Osoba"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$OsobaSciezka/self::inst:Pracownik and $OsobaSciezka/inst:Funkcja != ''">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Funkcja:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:value-of select="$OsobaSciezka/inst:Funkcja"/>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:if>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Identyfikacja:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotIdentyfikatoryTmpl">
<xsl:with-param name="PodmiotSciezka" select="$OsobaSciezka/oso:IdOsoby"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:if test="not($OsobaSciezka/self::inst:Pracownik)">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Adres:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotAdresTmpl">
<xsl:with-param name="PodmiotSciezka" select="$OsobaSciezka/adr:Adres"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:if>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Kontakt:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotKontaktTmpl">
<xsl:with-param name="PodmiotSciezka" select="$OsobaSciezka/adr:Kontakt"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:template>
<xsl:template name="InstytucjaTmpl">
<xsl:param name="InstytucjaSciezka"/>
<xsl:if test="not($InstytucjaSciezka)">
<xsl:call-template name="InstytucjaTmpl">
<xsl:with-param name="InstytucjaSciezka" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot/inst:Instytucja"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="$InstytucjaSciezka/self::inst:Jednostka">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Poziom:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:value-of select="$InstytucjaSciezka/inst:Poziom"/>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:if>
<xsl:if test="not($InstytucjaSciezka/self::inst:Jednostka)">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Identyfikacja:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotIdentyfikatoryTmpl">
<xsl:with-param name="PodmiotSciezka" select="$InstytucjaSciezka/inst:IdInstytucji"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
</xsl:if>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Adres:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotAdresTmpl">
<xsl:with-param name="PodmiotSciezka" select="$InstytucjaSciezka/adr:Adres"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Kontakt:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="PodmiotKontaktTmpl">
<xsl:with-param name="PodmiotSciezka" select="$InstytucjaSciezka/adr:Kontakt"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:if test="$InstytucjaSciezka/inst:Jednostka">
<div class="Margines40">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><strong><xsl:text>Jednostka organizacyjna:</xsl:text></strong></div>
<div class="Kategoria1Tresc">
<xsl:value-of select="$InstytucjaSciezka/inst:Jednostka/inst:NazwaInstytucji"/>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:call-template name="InstytucjaTmpl">
<xsl:with-param name="InstytucjaSciezka" select="$InstytucjaSciezka/inst:Jednostka"/>
</xsl:call-template>
</div>
</xsl:if>
<xsl:if test="$InstytucjaSciezka/inst:Pracownik">
<div class="Margines40">
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><strong><xsl:text>Pracownik:</xsl:text></strong></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="OsobaImieNazwiskoTmpl">
<xsl:with-param name="OsobaSciezka" select="$InstytucjaSciezka/inst:Pracownik"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:call-template name="OsobaTmpl">
<xsl:with-param name="OsobaSciezka" select="$InstytucjaSciezka/inst:Pracownik"/>
</xsl:call-template>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="OsobaImieNazwiskoTmpl">
<xsl:param name="OsobaSciezka"/>
<xsl:choose>
<xsl:when test="$OsobaSciezka/oso:Imie != ''">
<xsl:value-of select="$OsobaSciezka/oso:Imie"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad">
<xsl:text>UWAGA! Nie podano imienia!</xsl:text>
</span>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="$OsobaSciezka/oso:ImieDrugie != ''">
<xsl:text> </xsl:text>
<xsl:value-of select="$OsobaSciezka/oso:ImieDrugie"/>
</xsl:if>
<xsl:text> </xsl:text>
<xsl:call-template name="OsobaNazwiskoTmpl">
<xsl:with-param name="OsobaSciezka" select="$OsobaSciezka/oso:Nazwisko"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="OsobaNazwiskoTmpl">
<xsl:param name="OsobaSciezka"/>
<xsl:choose>
<xsl:when test="count($OsobaSciezka) > 0">
<xsl:for-each select="$OsobaSciezka">
<xsl:if test="@rodzajCzlonu != '' and @rodzajCzlonu != 'pierwszy'">
<xsl:text>-</xsl:text>
</xsl:if>
<xsl:value-of select="."/>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<span class="Blad">
<xsl:text>UWAGA! Nie podano nazwiska!</xsl:text>
</span>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="PodmiotIdentyfikatoryTmpl">
<xsl:param name="PodmiotSciezka"/>
<xsl:if test="count($PodmiotSciezka/child::*) > 0">
<xsl:for-each select="$PodmiotSciezka/child::*">
<span class="Grupa1">
<xsl:choose>
<xsl:when test="substring-after(name(), ':') = 'InnyIdentyfikator'">
<xsl:if test="self::node()/child::*[position()=1] != '' and self::node()/child::*[position()=2] != ''">
<span class="Grupa1Nazwa">
<xsl:value-of select="self::node()/child::*[position()=1]"/><xsl:text>: </xsl:text>
</span>
<xsl:value-of select="self::node()/child::*[position()=2]"/>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<xsl:if test="text() != ''">
<span class="Grupa1Nazwa">
<xsl:value-of select="substring-after(name(), ':')"/><xsl:text>: </xsl:text>
</span>
<xsl:value-of select="text()"/>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</span>
</xsl:for-each>
</xsl:if>
</xsl:template>
<xsl:template name="PodmiotAdresTmpl">
<xsl:param name="PodmiotSciezka"/>
<div>
<xsl:value-of select="$PodmiotSciezka/adr:Ulica/@rodzajUlicy"/>
<xsl:text> </xsl:text>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Ulica != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Ulica"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>UWAGA! Nie podano nazwy ulicy!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Budynek != ''">
<xsl:text> </xsl:text><xsl:value-of select="$PodmiotSciezka/adr:Budynek"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>UWAGA! Nie podano numeru budynku!</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="$PodmiotSciezka/adr:Lokal != ''">
<xsl:text> / </xsl:text>
<xsl:value-of select="$PodmiotSciezka/adr:Lokal"/>
</xsl:if>
</div>
<div>
<span class="Grupa1">
<xsl:value-of select="$PodmiotSciezka/adr:KodPocztowy"/>
<xsl:if test="$PodmiotSciezka/adr:Poczta != ''">
<xsl:text> </xsl:text>
<xsl:value-of select="$PodmiotSciezka/adr:Poczta"/>
</xsl:if>
</span>
</div>
<div>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Miejscowość: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Miejscowosc != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Miejscowosc"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
<xsl:if test="$PodmiotSciezka/adr:SkrytkaPocztowa != ''">
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text> Skrytka pocztowa: </xsl:text></span>
<xsl:text> </xsl:text><xsl:value-of select="$PodmiotSciezka/adr:SkrytkaPocztowa"/>
</span>
</xsl:if>
</div>
<div>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Gmina: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Gmina != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Gmina"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>-</xsl:text>
</xsl:otherwise>
</xsl:choose>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Powiat: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Powiat != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Powiat"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>-</xsl:text>
</xsl:otherwise>
</xsl:choose>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Woj.: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Wojewodztwo != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Wojewodztwo"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Kod kraju: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:Kraj != ''">
<xsl:value-of select="$PodmiotSciezka/adr:Kraj"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
</div>
<xsl:if test="$PodmiotSciezka/adr:TERC != '' or $PodmiotSciezka/adr:SIMC != '' or $PodmiotSciezka/adr:ULIC != ''">
<div>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Kod TERC: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:TERC != ''">
<xsl:value-of select="$PodmiotSciezka/adr:TERC"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Kod SIMC: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:SIMC != ''">
<xsl:value-of select="$PodmiotSciezka/adr:SIMC"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
<span class="Grupa1">
<span class="Grupa1Nazwa"><xsl:text>Kod ULIC: </xsl:text></span>
<xsl:choose>
<xsl:when test="$PodmiotSciezka/adr:ULIC != ''">
<xsl:value-of select="$PodmiotSciezka/adr:ULIC"/>
</xsl:when>
<xsl:otherwise>
<span class="Blad"><xsl:text>-</xsl:text></span>
</xsl:otherwise>
</xsl:choose>
</span>
</div>
</xsl:if>
<xsl:if test="$PodmiotSciezka/adr:Uwagi != ''">
<div>
<div><strong><xsl:text>Uwagi:</xsl:text></strong></div>
<xsl:value-of select="$PodmiotSciezka/adr:Uwagi"/>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="PodmiotKontaktTmpl">
<xsl:param name="PodmiotSciezka"/>
<xsl:if test="count($PodmiotSciezka/child::*) > 0">
<xsl:for-each select="$PodmiotSciezka/child::*">
<xsl:if test="text() != ''">
<span class="Grupa1">
<xsl:choose>
<xsl:when test="substring-after(name(), ':') = 'InnyKontakt'">
<span class="Grupa1Nazwa"><xsl:text>Inny kontakt: </xsl:text></span>
<xsl:value-of select="text()"/>
</xsl:when>
<xsl:otherwise>
<span class="Grupa1Nazwa"><xsl:value-of select="substring-after(name(), ':')"/><xsl:text>: </xsl:text></span>
<xsl:value-of select="text()"/>
</xsl:otherwise>
</xsl:choose>
</span>
</xsl:if>
</xsl:for-each>
</xsl:if>
</xsl:template>
<xsl:template name="TworcyTmpl">
<xsl:param name="TworcySciezka" select="wnio:DaneDokumentu/meta:Tworcy"/>
<xsl:if test="$TworcySciezka and count($TworcySciezka/meta:Tworca) > 0">
<div class="Sekcja">
<div class="TworcyTytul1"><xsl:text>Twórcy dokumentu</xsl:text></div>
<div class="SekcjaTresc">
<xsl:for-each select="$TworcySciezka/meta:Tworca">
<div class="TworcyTytul2">
<div class="KategoriaTytulNazwa">
<xsl:text>Twórca #</xsl:text>
<xsl:value-of select="position()"/>
<xsl:text>: </xsl:text>
</div>
<div class="KategoriaTytulTresc">
<xsl:call-template name="AdresatNazwaTmpl">
<xsl:with-param name="AdresatSciezka" select="current()/meta:Podmiot"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<div class="KategoriaTresc">
<xsl:call-template name="TworcaTmpl">
<xsl:with-param name="TworcaSciezka" select="current()"/>
</xsl:call-template>
</div>
</xsl:for-each>
</div>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="TworcaTmpl">
<xsl:param name="TworcaSciezka"/>
<div class="Kategoria1">
<div class="Kategoria1Nazwa"><xsl:text>Funkcja:</xsl:text></div>
<div class="Kategoria1Tresc">
<xsl:call-template name="StworzylTmpl">
<xsl:with-param name="StworzylSciezka" select="$TworcaSciezka/meta:Funkcja"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:call-template name="AdresatTmpl">
<xsl:with-param name="AdresatSciezka" select="$TworcaSciezka/meta:Podmiot"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="StworzylTmpl">
<xsl:param name="StworzylSciezka"/>
<xsl:if test="$StworzylSciezka = 'stworzyl'"><xsl:text>Stworzył</xsl:text></xsl:if>
<xsl:if test="$StworzylSciezka = 'modyfikowal'"><xsl:text>Modyfikował</xsl:text></xsl:if>
<xsl:if test="$StworzylSciezka = 'zatwierdzil'"><xsl:text>Zatwierdził</xsl:text></xsl:if>
</xsl:template>
<xsl:template name="NadawcyTmpl">
<div class="NadawcyTytul1">
<xsl:text>Nadawcy dokumentu</xsl:text>
</div>
<xsl:choose>
<xsl:when test="count(wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot) > 0">
<xsl:for-each select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot">
<div class="NadawcyTytul2">
<div class="KategoriaTytulNazwa">
<xsl:text>Nadawca #</xsl:text>
<xsl:value-of select="position()"/>
<xsl:text>: </xsl:text>
</div>
<div class="KategoriaTytulTresc">
<xsl:call-template name="AdresatNazwaTmpl">
<xsl:with-param name="AdresatSciezka" select="current()"/>
</xsl:call-template>
</div>
<div class="KategoriaWyczysc"/>
</div>
<xsl:call-template name="AdresatTmpl">
<xsl:with-param name="AdresatSciezka" select="current()"/>
</xsl:call-template>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<div class="Blad">
<xsl:text>UWAGA! Brak informacji o adresatach dokumentu!</xsl:text>
</div>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="ZalacznikiTmpl">
<xsl:param name="ZalacznikiSciezka" select="wnio:TrescDokumentu/wnio:Wartosc/str:Zalaczniki"/>
<xsl:if test="$ZalacznikiSciezka and count($ZalacznikiSciezka/str:Zalacznik) > 0">
<div class="ZalacznikiObszar">
<div class="ZalacznikiTytul1">
<xsl:text>Załączone pliki (ilość plików: </xsl:text>
<xsl:value-of select="count($ZalacznikiSciezka/str:Zalacznik)"/>
<xsl:text>)</xsl:text>
</div>
<div style="text-align: center;">
<table class="Tabela1" style="width: 98%;" cellspacing="0" cellpadding="5" border="0">
<tbody>
<tr>
<th><xsl:text>Lp.</xsl:text></th>
<th><xsl:text>Nazwa pliku</xsl:text></th>
<th><xsl:text>Opis pliku</xsl:text></th>
<th><xsl:text>Format pliku</xsl:text></th>
<th><xsl:text>Kodowanie</xsl:text></th>
</tr>
<xsl:for-each select="$ZalacznikiSciezka/str:Zalacznik">
<tr>
<td class="srodek"><xsl:value-of select="position()"/><xsl:text>.</xsl:text></td>
<td><xsl:value-of select="./@nazwaPliku"/></td>
<td><xsl:value-of select="./str:OpisZalacznika"/></td>
<td class="srodek"><xsl:value-of select="./@format"/></td>
<td class="srodek"><xsl:value-of select="./@kodowanie"/></td>
</tr>
</xsl:for-each>
</tbody>
</table>
</div>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="nl2br">
<xsl:param name="string"/>
<xsl:value-of select="normalize-space(substring-before($string,' '))"/>
<xsl:choose>
<xsl:when test="contains($string,' ')">
<br/>
<xsl:call-template name="nl2br">
<xsl:with-param name="string" select="substring-after($string,' ')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$string"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="PelnaDataTmpl">
<xsl:param name="PelnaDataSciezka"/>
<xsl:if test="string-length($PelnaDataSciezka) > 0">
<xsl:choose>
<xsl:when test="contains($PelnaDataSciezka, 'T') or string-length($PelnaDataSciezka) > 10">
<xsl:value-of select="number(substring-before(substring-after(substring-after($PelnaDataSciezka,'-'),'-'), 'T'))"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="number(substring-after(substring-after($PelnaDataSciezka,'-'),'-'))"/>
</xsl:otherwise>
</xsl:choose>
<xsl:variable name="numerMiesiaca" select="number(substring-before(substring-after($PelnaDataSciezka,'-'),'-'))"/>
<xsl:text> </xsl:text>
<xsl:if test="$numerMiesiaca=1"><xsl:text>stycznia</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=2"><xsl:text>lutego</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=3"><xsl:text>marca</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=4"><xsl:text>kwietnia</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=5"><xsl:text>maja</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=6"><xsl:text>czerwca</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=7"><xsl:text>lipca</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=8"><xsl:text>sierpnia</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=9"><xsl:text>września</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=10"><xsl:text>października</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=11"><xsl:text>listopada</xsl:text></xsl:if>
<xsl:if test="$numerMiesiaca=12"><xsl:text>grudnia</xsl:text></xsl:if>
<xsl:text> </xsl:text>
<xsl:value-of select="substring-before($PelnaDataSciezka,'-')"/>
<xsl:text> r.</xsl:text>
</xsl:if>
</xsl:template>
</xsl:stylesheet>