7885
| ID | 7885 |
|---|
| Data | 2019-06-06 |
|---|
| Symbol | 2019/06/06/7885 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | VAT-21 ZAWIADOMIENIE NACZELNIKA URZĘDU SKARBOWEGO O WYBORZE MIEJSCA OPODATKOWANIA / O REZYGNACJI Z WYBORU MIEJSCA OPODATKOWANIA W PRZYPADKU SPRZEDAŻY WYSYŁKOWEJ Z TERYTORIUM KRAJU |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:pf="http://crd.gov.pl/wzor/2019/06/06/7885/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2018/09/03/eD/DefinicjeSzablony/Posredni_wspolne_v7-0E.xsl"/>
<xsl:param name="schema-krajowUE" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2013/05/23/eD/KodyUE/KodyKrajowUE_v2-0E.xsd'"/>
<xsl:param name="schema-naczelnikow-urzedow" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2017/02/06/eD/KodyNaczelnikowUrzedowSkarbowych/KodyNaczelnikowUrzedowSkarbowych_v4-0E.xsd'"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:param name="nazwy-dla-kodow" select="true()"/>
<xsl:template name="TytulDokumentu">ZAWIADOMIENIE NACZELNIKA URZĘDU SKARBOWEGO
O WYBORZE MIEJSCA OPODATKOWANIA / O REZYGNACJI Z WYBORU MIEJSCA OPODATKOWANIA W PRZYPADKU SPRZEDAŻY WYSYŁKOWEJ Z TERYTORIUM KRAJU
</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">
.tlo-formularza { background-color:#D3D3D3; }
</style>
</xsl:template>
<xsl:template match="pf:Deklaracja">
<div class="deklaracja">
<xsl:call-template name="NaglowekTechniczny">
<xsl:with-param name="naglowek" select="pf:Naglowek"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
</xsl:call-template>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa">ZAWIADOMIENIE NACZELNIKA URZĘDU SKARBOWEGO O WYBORZE MIEJSCA OPODATKOWANIA / O REZYGNACJI Z WYBORU MIEJSCA OPODATKOWANIA W PRZYPADKU SPRZEDAŻY WYSYŁKOWEJ Z TERYTORIUM KRAJU
</xsl:with-param>
<xsl:with-param name="objasnienie">
</xsl:with-param>
<xsl:with-param name="podstawy-prawne">
<table>
<tr>
<td class="etykieta">Podstawa prawna:</td>
<td class="wartosc">Art. 23 ust. 5 lub 9 ustawy z dnia 11 marca 2004 r. o podatku od towarów i usług (Dz. U. z 2018 r. poz. 2174, z późn. zm.), zwanej dalej „ustawą”.</td>
</tr>
</table>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="MiejsceVAT21">
<xsl:with-param name="sekcja">A.</xsl:with-param>
</xsl:call-template>
<xsl:for-each select="pf:Podmiot1">
<xsl:call-template name="Podmiot">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
</xsl:for-each>
<xsl:call-template name="CelSkladania">
<xsl:with-param name="sekcja">C.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="Zawiadomienie">
<xsl:with-param name="sekcja"/>
</xsl:call-template>
<xsl:call-template name="Informacja">
<xsl:with-param name="sekcja">F.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="DataWypelnienia"/>
<xsl:call-template name="PouczenieKoncowe"/>
</div>
</xsl:template>
<xsl:template name="CelSkladania">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> CEL SKŁADANIA ZAWIADOMIENIA</h2>
<table class="normalna">
<xsl:for-each select="pf:PozycjeSzczegolowe">
<tr>
<td class="wypelniane" style="width: 25%">
<div class="opisrubryki">16. Cel składania zawiadomienia:<br/>
Jeżeli zaznaczono kwadrat nr 1, ma zastosowanie część D. Jeżeli zaznaczono kwadrat nr 2, ma zastosowanie część E.</div>
<xsl:choose>
<xsl:when test="pf:P_16C1=1">
<input type="checkbox" checked="checked" disabled="disabled"/>1. wybór miejsca opodatkowania
</xsl:when>
<xsl:when test="pf:P_16C2=1">
<input type="checkbox" checked="checked" disabled="disabled"/>2. rezygnacja z wyboru miejsca opodatkowania
</xsl:when>
</xsl:choose>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
<xsl:template name="Zawiadomienie">
<xsl:param name="sekcja"/>
<xsl:for-each select="pf:PozycjeSzczegolowe">
<xsl:if test="pf:P_16C1=1">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>D. ZAWIADOMIENIE</h2>
<table class="normalna">
<tr>
<td class="opis" style="width: 100%">
Zawiadamiam naczelnika urzędu skarbowego, iż zamierzam skorzystać z możliwości wyboru miejsca opodatkowania przy dokonywaniu sprzedaży wysyłkowej z terytorium kraju, zgodnie z art. 23 ust. 5 ustawy.<br/>
Zobowiązuję się w terminie 30 dni od dokonania pierwszej dostawy po dokonaniu zgodnie z niniejszym zawiadomieniem wyboru miejsca opodatkowania do przedstawienia dokumentu potwierdzającego o zawiadomieniu właściwego organu podatkowego w innym państwie / innych państwach członkowskich<sup>1)</sup> Unii Europejskiej o zamiarze rozliczania w tym państwie / w tych państwach<sup>1)</sup> podatku od wartości dodanej od sprzedaży wysyłkowej z terytorium kraju, zgodnie z art. 23 ust. 7 ustawy.<br/>
Należy wypełnić część F kolumny a i b. </td>
</tr>
</table>
</xsl:if>
<xsl:if test="pf:P_16C2=1">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>E. ZAWIADOMIENIE</h2>
<table class="normalna">
<tr>
<td class="opis" style="width: 100%">
Zawiadamiam naczelnika urzędu skarbowego, iż rezygnuję z wyboru miejsca opodatkowania przy dokonywaniu sprzedaży wysyłkowej z terytorium kraju, zgodnie z art. 23 ust. 9 ustawy.<br/>
Należy wypełnić część F kolumny a, c, d i e.
</td>
</tr>
</table>
</xsl:if>
</xsl:for-each>
</xsl:template>
<xsl:template name="Informacja">
<xsl:param name="sekcja"/>
<xsl:for-each select="pf:PozycjeSzczegolowe">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> INFORMACJE O WYBORZE MIEJSCA OPODATKOWANIA / REZYGNACJI Z WYBORU MIEJSCA OPODATKOWANIA</h2>
<table class="normalna">
<tr>
<td class="niewypelniane" style="width: 2%" rowspan="2">Lp.</td>
<td class="niewypelniane" style="width: 28%">Nazwa państwa członkowskiego, którego dotyczy zawiadomienie</td>
<td class="niewypelniane" style="width: 15%">Planowana data pierwszej dostawy po wyborze miejsca opodatkowania</td>
<td class="niewypelniane" style="width: 15%">Data pierwszej dostawy po dokonaniu wyboru miejsca opodatkowania</td>
<td class="niewypelniane" style="width: 15%">Data zgłoszenia wyboru miejsca opodatkowania</td>
<td class="niewypelniane" style="width: 15%">Przewidywana data pierwszej dostawy po rezygnacji z wyboru miejsca opodatkowania</td>
</tr>
<tr>
<td class="niewypelniane" style="width: 28%">a</td>
<td class="niewypelniane" style="width: 15%">b</td>
<td class="niewypelniane" style="width: 15%">c</td>
<td class="niewypelniane" style="width: 15%">d</td>
<td class="niewypelniane" style="width: 15%">e</td>
</tr>
<xsl:for-each select="pf:P_F">
<tr>
<td class="wypelniane">
<xsl:number/>
</td>
<td class="wypelniane">
<xsl:for-each select="pf:P_FAA">
<xsl:call-template name="PokazKodKraju1"/>
</xsl:for-each>
</td>
<td class="wypelniane">
<xsl:value-of select="pf:P_FB"/>
</td>
<td class="wypelniane">
<xsl:value-of select="pf:P_FC"/>
</td>
<td class="wypelniane">
<xsl:value-of select="pf:P_FD"/>
</td>
<td class="wypelniane">
<xsl:value-of select="pf:P_FE"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="MiejsceVAT21">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> MIEJSCE SKŁADANIA ZAWIADOMIENIA</h2>
<table class="normalna">
<tr>
<td class="niewypelnianeopisy" style="width:33%">Naczelnik urzędu skarbowego, do którego adresowane jest zawiadomienie</td>
<td class="wypelniane" style="width:auto">
<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="DataWypelnienia">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">154. Data wypełnienia</div>
<xsl:value-of select="*[local-name()='Naglowek']/*[local-name()='Data']"/>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="PouczenieKoncowe">
<xsl:if test="pf:Pouczenie =1">
<h2 class="tekst">Pouczenie</h2>
<h3 align="justify">
Za podanie nieprawdy lub zatajenie prawdy i przez to narażenie podatku na uszczuplenie grozi odpowiedzialność przewidziana w Kodeksie karnym skarbowym.
</h3>
</xsl:if>
</xsl:template>
<xsl:template name="PokazKodKraju1">
<xsl:apply-templates/>
<xsl:if test="$nazwy-dla-kodow">
<span class="nazwa-dla-kodu">
<xsl:text>(</xsl:text>
<xsl:call-template name="ZnajdzWEnumeracji">
<xsl:with-param name="schema" select="$schema-krajowUE"/>
<xsl:with-param name="typ" select="'TKodKrajuUE'"/>
<xsl:with-param name="kod" select="text()"/>
</xsl:call-template>
<xsl:text>)</xsl:text>
</span>
</xsl:if>
</xsl:template>
<xsl:template match="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']">
<xsl:apply-templates/>
<xsl:if test="$nazwy-dla-kodow">
<span class="nazwa-dla-kodu">
<xsl:call-template name="ZnajdzWEnumeracji">
<xsl:with-param name="schema" select="$schema-naczelnikow-urzedow"/>
<xsl:with-param name="typ" select="'TKodNaczUS'"/>
<xsl:with-param name="kod" select="text()"/>
</xsl:call-template>
</span>
</xsl:if>
</xsl:template>
</xsl:stylesheet>