7061

ID	7061
Data	2019-02-18
Symbol	2019/02/18/7061
Instytucja	Ministerstwo Finansów
Nazwa	ZAP-3 ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM
Czy Aktualny	0

Ustawy (1)

URI://Dziennik_Ustaw/2019/63/5/5	Art. 5 ust. 5 ustawy z dnia 13 października 1995 r. o zasadach ewidencji i identyfikacji podatników i płatników (Dz. U. z 2019 r. poz. 63)

Pliki

• wyroznik.xml
• styl.xsl
• schemat.xsd

Styl

<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:pf="http://crd.gov.pl/wzor/2019/02/18/7061/" xmlns:etd="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2018/08/24/eD/DefinicjeTypy/" version="1.0">
	<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2018/09/03/eD/DefinicjeSzablony/Posredni_wspolne_v7-0E.xsl"/>
	<xsl:param name="schema-naczelnikow-urzedow" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2017/02/06/eD/KodyNaczelnikowUrzedowSkarbowych/KodyNaczelnikowUrzedowSkarbowych_v4-0E.xsd'"/>
	<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
	<xsl:template name="TytulDokumentu">ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM</xsl:template>
	<xsl:template name="StyleDlaFormularza">
		<style type="text/css">
			.tlo-formularza { background-color:#D3D3D3;}
		</style>
	</xsl:template>
	<xsl:template match="pf:ZgloszenieNIP">
		<div class="deklaracja">
			<xsl:call-template name="NaglowekTechniczny">
				<xsl:with-param name="naglowek" select="pf:Naglowek"/>
				<xsl:with-param name="uzycie" select="'deklaracja'"/>
			</xsl:call-template>
			<xsl:call-template name="NaglowekTytulowy">
				<xsl:with-param name="uzycie" select="'deklaracja'"/>
				<xsl:with-param name="nazwa">ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM</xsl:with-param>
				<xsl:with-param name="objasnienie">
					<p>Formularz przeznaczony dla osoby fizycznej, spełniającej łącznie poniższe kryteria:</p>
					<ul>- ma nadany numer PESEL,<br/>
						- nie prowadzi działalności gospodarczej,<br/>
						- nie jest zarejestrowanym podatnikiem podatku od towarów i usług,<br/>
						- nie jest płatnikiem podatków,<br/>
						- nie jest płatnikiem składek na ubezpieczenia społeczne oraz ubezpieczenie zdrowotne.</ul>
					<p>Formularz służy do zgłoszenia: aktualnego adresu miejsca zamieszkania (część B.2.), danych kontaktowych (część B.3.) oraz informacji dotyczących rachunku osobistego (część B.4.).</p>
				</xsl:with-param>
				<xsl:with-param name="podstawy-prawne">
					<table>
						<tr>
							<td class="etykieta" valign="top">Podstawa prawna:</td>
							<td class="wartosc">
								Ustawa z dnia 13 października 1995 r. o zasadach ewidencji i identyfikacji podatników i płatników (Dz. U. z 2017 r.  poz. 869, z późn. zm.), zgodnie z art. 9 ust. 1d.
							</td>
						</tr>
					</table>
				</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="MiejsceICelZAP3">
				<xsl:with-param name="sekcja">A.</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="DaneSkladajacego">
				<xsl:with-param name="sekcja">B.</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="DataWypelnienia">
				<xsl:with-param name="sekcja">C.</xsl:with-param>
			</xsl:call-template>
		</div>
	</xsl:template>
	<xsl:template name="MiejsceICelZAP3">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> MIEJSCE ZŁOŻENIA ZGŁOSZENIA</h2>
		<table class="normalna">
			<tr>
				<td class="niewypelnianeopisy" style="width:33%">Naczelnik urzędu skarbowego, do którego jest adresowane zgłoszenie</td>
				<td class="wypelniane" style="width:auto">
					<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="DaneSkladajacego">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> DANE SKŁADAJĄCEGO</h2>
		<h3 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/>1. DANE IDENTYFIKACYJNE<br/>
			<span class="opis-tekstowy">Poz. Imię ojca, Imię matki, Identyfikator podatkowy NIP należy wypełnić tylko w przypadku dokonujących pierwszego zgłoszenia ZAP-3:<br/>
            - poz. Imię ojca, Imię matki dotyczą osób, które przed uzyskaniem numeru PESEL miały status podatnika,<br/>
            - poz. Identyfikator podatkowy NIP dotyczy osób, które przed uzyskaniem numeru PESEL miały nadany identyfikator podatkowy NIP.  
</span>
		</h3>
		<xsl:for-each select="pf:Podmiot1/pf:OsobaFizyczna">
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:100%">
						<div class="opisrubryki">Identyfikator podatkowy numer PESEL</div>
						<xsl:apply-templates select="pf:PESEL"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:50%">
						<div class="opisrubryki">Nazwisko</div>
						<xsl:apply-templates select="pf:Nazwisko"/>
					</td>
					<td class="wypelniane" style="width:50%">
						<div class="opisrubryki">Pierwsze imię</div>
						<xsl:apply-templates select="pf:ImiePierwsze"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:30%">
						<div class="opisrubryki">Imię ojca</div>
						<xsl:apply-templates select="pf:ImieOjca"/>
					</td>
					<td class="wypelniane" style="width:40%">
						<div class="opisrubryki">Imię matki</div>
						<xsl:apply-templates select="pf:ImieMatki"/>
					</td>
					<td class="wypelniane" style="width:30%">
						<div class="opisrubryki">Identyfikator podatkowy NIP</div>
						<xsl:apply-templates select="pf:NIP"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
		<h3 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/>2. ADRES MIEJSCA ZAMIESZKANIA</h3>
		<xsl:for-each select="pf:Podmiot1/pf:AdresZamieszkania">
			<xsl:apply-templates/>
		</xsl:for-each>
		<h3 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/>3. DANE KONTAKTOWE<br/>
			<span class="opis-tekstowy">Podanie informacji w części B.3. nie jest obowiązkowe. Wpisane niżej dane w części B.3.1 i B.3.2. aktualizują poprzedni stan danych.</span>
		</h3>
		<xsl:for-each select="pf:Kontakt">
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:0%">
						<div class="opisrubryki">Telefon</div>
						<xsl:apply-templates select="pf:Telefon"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:50%">
						<div class="opisrubryki">Faks</div>
						<xsl:apply-templates select="pf:Faks"/>
					</td>
					<td class="wypelniane" style="width:50%">
						<div class="opisrubryki">E-mail</div>
						<xsl:apply-templates select="pf:Email"/>
					</td>
				</tr>
			</table>
			<h4 class="tytul-sekcja-blok">
				<xsl:value-of select="$sekcja"/>3.1. ADRES ELEKTRONICZNY
				<span class="opis-tekstowy">
					- adres w systemie teleinformatycznym. Do doręczeń pism za pomocą środków komunikacji elektronicznej może mieć zastosowanie adres elektroniczny na portalu podatkowym lub w systemie ePUAP, w przypadku, jeżeli wniesiono o zastosowanie takiego sposobu doręczania albo wyrażono na to zgodę (art. 144a § 1 pkt 2 lub art. 144a § 1 pkt 3 w związku z art. 3e § 1 ustawy z dnia 29 sierpnia 1997 r. - Ordynacja podatkowa (Dz. U. z 2018 r. poz. 800, z późn. zm.)). Adres elektroniczny w systemie ePUAP może mieć również zastosowanie do doręczeń pism w analogicznych przypadkach określonych w art. 39<sup>1</sup> § 1 pkt 2 lub art. 39<sup>1</sup> § 1 pkt 3 w związku z art. 39<sup>1</sup> § 1a ustawy z dnia 14 czerwca 1960 r. - Kodeks postępowania administracyjnego (Dz. U. z 2018 r. poz. 2096, z późn. zm.). Poniżej można zaznaczyć rezygnację ze wskazanego adresu elektronicznego.
				</span>
			</h4>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:75%">
						<div class="opisrubryki">Adres elektroniczny</div>
						<xsl:if test="pf:AdresElektroniczny">
							<xsl:value-of select="pf:AdresElektroniczny"/>
						</xsl:if>
					</td>
					<td class="wypelniane">
						<div class="opisrubryki">Rezygnacja z adresu elektronicznego</div>
						<xsl:if test="pf:RezygnacjaZAdresuElektronicznego ='T'">
							<input type="checkbox" checked="checked" disabled="disabled"/>Tak
							</xsl:if>
					</td>
				</tr>
			</table>
		</xsl:for-each>
		<h4 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/>3.2.  ADRES DO KORESPONDENCJI<br/>
			<span class="opis-tekstowy">Należy wypełnić tylko wówczas, gdy adres do korespondencji jest inny niż w części B.2.</span>
		</h4>
		<xsl:for-each select="pf:Kontakt/pf:AdresKorespondencyjny">
			<xsl:apply-templates select="*[local-name()='AdresPol'] | *[local-name()='AdresZagr']"/>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:100%">
						<div class="opisrubryki">Utrata aktualności ostatnio wskazanego adresu do korespondencji, innego niż adres w części B.2.</div>
						<xsl:if test="pf:UtrataAktualnosciAdresu ='1'">
							<input type="checkbox" checked="checked" disabled="disabled"/>Tak
						</xsl:if>
					</td>
				</tr>
			</table>
		</xsl:for-each>
		<h3 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/>4. RACHUNEK OSOBISTY - DO ZWROTU PODATKU LUB NADPŁATY<br/>
			<span class="opis-tekstowy">Podanie informacji o rachunku bankowym lub rachunku w spółdzielczej kasie oszczędnościowo-kredytowej nie jest obowiązkowe, jeżeli składający nie wybiera tej formy zwrotu
podatku lub nadpłaty. Można podać jedynie taki rachunek, którego właścicielem lub współwłaścicielem jest składający. Wpisane niżej dane dotyczące rachunku
aktualizują poprzedni stan danych. Zaznaczenie pola Rezygnacja oznacza rezygnację przez składającego z otrzymywania ewentualnego zwrotu nadpłaty lub
podatku na rachunek osobisty (również z powodu likwidacji rachunku).</span>
		</h3>
		<xsl:for-each select="pf:RachunekBankowy">
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:40%">
						<div class="opisrubryki">Kraj siedziby banku (oddziału)  (wypełnić wyłącznie dla rachunku zagranicznego)</div>
						<xsl:for-each select="pf:KrajSiedzibyBanku">
							<xsl:call-template name="PokazKodKraju"/>
						</xsl:for-each>
					</td>
					<td class="wypelniane" style="width:60%">
						<div class="opisrubryki"> Kod SWIFT (wypełnić wyłącznie dla rachunku zagranicznego)</div>
						<xsl:apply-templates select="pf:KodSWIFT"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">Posiadacz rachunku</div>
						<xsl:apply-templates select="pf:PosiadaczRachunku"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:90%">
						<div class="opisrubryki">Pełny numer rachunku</div>
						<span class="opis-tekstowy">Numer IBAN:    </span>
						<xsl:apply-templates select="pf:NrRachunkuBankowego"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
		<table class="normalna">
			<tr>
				<td class="wypelniane" style="width:10%">
					<div class="opisrubryki">Rezygnacja</div>
					<xsl:for-each select="pf:RezygnacjaZRachunkuBankowego">
						<xsl:if test=". ='T'">
							<input type="checkbox" checked="checked" disabled="disabled"/>Tak	
								</xsl:if>
					</xsl:for-each>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="DataWypelnienia">
		<xsl:param name="sekcja"/>
		<h3 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> PODPIS SKŁADAJĄCEGO / DANE I PODPIS OSOBY REPREZENTUJĄCEJ SKŁADAJĄCEGO</h3>
		<table class="normalna">
			<tr>
				<td class="wypelniane" style="width:100%">
					<div class="opisrubryki">Data wypełnienia zgłoszenia</div>
					<xsl:value-of select="pf:Naglowek/pf:Data"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="pf:ObywatelstwoPL | pf:KodKrajuObywatelstwoPozostale | pf:KodkrajuWydaniaNrId">
		<xsl:call-template name="PokazKodKraju"/>
		<xsl:if test="position() != last()">
			<br/>
		</xsl:if>
	</xsl:template>
	<xsl:template match="pf:NrId | pf:RodzajNrId">
		<xsl:apply-templates/>
		<xsl:if test="position() != last()">
			<br/>
		</xsl:if>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']">
		<xsl:apply-templates/> 
		<xsl:if test="$nazwy-dla-kodow">
			<span class="nazwa-dla-kodu">
				<xsl:call-template name="ZnajdzWEnumeracji">
					<xsl:with-param name="schema" select="$schema-naczelnikow-urzedow"/>
					<xsl:with-param name="typ" select="'TKodNaczUS'"/>
					<xsl:with-param name="kod" select="text()"/>
				</xsl:call-template>
			</span>
		</xsl:if>
	</xsl:template>
</xsl:stylesheet>