410
| ID | 410 |
|---|
| Data | 2010-08-05 |
|---|
| Symbol | 2010/08/05/410 |
|---|
| Instytucja | Urząd Miasta Krakowa |
|---|
| Nazwa | Wniosek o wydanie decyzji w sprawie sprostowania/uzupełnienia aktu urodzenia/małżeństwa/zgonu |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (3)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:adr="http://crd.gov.pl/xml/schematy/adres/2009/03/06/" xmlns:inst="http://crd.gov.pl/xml/schematy/instytucja/2009/03/06/" xmlns:meta="http://crd.gov.pl/xml/schematy/meta/2009/03/06/" xmlns:oso="http://crd.gov.pl/xml/schematy/osoba/2009/03/06/" xmlns:str="http://crd.gov.pl/xml/schematy/struktura/2009/03/06/" xmlns:wnio="http://crd.gov.pl/wzor/2010/08/05/410/" xmlns:custom="Custom" version="1.0">
<xsl:output version="4.0" method="html" indent="yes" encoding="UTF-8"/>
<xsl:variable name="XML" select="/"/>
<xsl:template match="/">
<html>
<head>
<title>
<xsl:text>Wniosek ogólny</xsl:text>
</title>
<style type="text/css"> body { font-family: Arial; font-size: 10pt; color: #000000; text-align: left}</style>
<style type="text/css"> td { font-family: Arial; font-size: 10pt; color: #000000; text-align: left}</style>
<style type="text/css"> .sectionHeader {font-size: 11pt; font-weight: bold;}</style>
<style type="text/css"> .wniosekHeader {font-size: 11pt; font-weight: bold;}</style>
<style type="text/css"> .section {width:4px; background: #aaaaaa}</style>
<style type="text/css"> .tableHeader {font-weight: bold;text-align:center; background: #aaaaaa}</style>
</head>
<body>
<span class="sectionHeader">Nadawca wniosku</span>
<br/>
<xsl:for-each select="wnio:Dokument">
<xsl:for-each select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot/oso:Osoba">
<xsl:value-of select="oso:Imie"/>
<xsl:text> </xsl:text>
<xsl:value-of select="oso:Nazwisko"/>
</xsl:for-each>
<div style="text-align:right">
<xsl:value-of select="wnio:TrescDokumentu/wnio:Wartosc/wnio:RodzajWniosku/wnio:MiejscowoscDokumentu"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="wnio:TrescDokumentu/wnio:Wartosc/wnio:RodzajWniosku/wnio:DataDokumentu/meta:Czas"/>
</div>
<br/>
<xsl:if test="count(wnio:TrescDokumentu/wnio:Wnioskodawcy/wnio:Wnioskodawca) = 1">
<span class="sectionHeader">Wnioskodawca</span>
<br/>
<br/>
</xsl:if>
<xsl:if test="count(wnio:TrescDokumentu/wnio:Wnioskodawcy/wnio:Wnioskodawca) > 1">
<span class="sectionHeader">Wnioskodawcy</span>
<br/>
<br/>
</xsl:if>
<xsl:for-each select="wnio:TrescDokumentu/wnio:Wnioskodawcy/wnio:Wnioskodawca">
<table>
<tr>
<td class="section"/>
<td>
<xsl:for-each select="meta:Podmiot[@typPodmiotu='Osoba']">
<xsl:call-template name="Osoba">
<xsl:with-param name="adres" select="oso:Osoba/adr:Adres"/>
<xsl:with-param name="osoba" select="oso:Osoba"/>
</xsl:call-template>
</xsl:for-each>
<xsl:for-each select="meta:Podmiot[@typPodmiotu='Instytucja']">
<xsl:call-template name="Instytucja">
<xsl:with-param name="adres" select="inst:Instytucja/adr:Adres"/>
<xsl:with-param name="instytucja" select="inst:Instytucja"/>
</xsl:call-template>
</xsl:for-each>
<xsl:for-each select="wnio:Reprezentacja/wnio:Reprezentant">
<br/>
<xsl:if test="@typ!='osobiscie'">
<xsl:choose>
<xsl:when test="@typ='przedstawiciel'">Przedstawiciel<br/>
</xsl:when>
<xsl:when test="@typ='pelnomocnik'">Pełnomocnik<br/>
</xsl:when>
</xsl:choose>
<xsl:call-template name="Osoba">
<xsl:with-param name="osoba" select="oso:Osoba"/>
<xsl:with-param name="adres" select="oso:Osoba/adr:Adres"/>
</xsl:call-template>
<br/>
</xsl:if>
<xsl:if test="wnio:DoreczenieZwrotne/@typ!='elektroniczne'">
Doręczenie zwrotne:
<xsl:choose>
<xsl:when test="wnio:DoreczenieZwrotne/@typ='brak'">Brak</xsl:when>
<xsl:when test="wnio:DoreczenieZwrotne/@typ='listowne'">Listowne</xsl:when>
<xsl:when test="wnio:DoreczenieZwrotne/@typ='elektroniczne-listowne'">Elektroniczne i listowne</xsl:when>
<xsl:when test="wnio:DoreczenieZwrotne/@typ='osobiscie'">Odbiór osobisty</xsl:when>
</xsl:choose>
<br/>
<br/>
</xsl:if>
Adres do korespondencji:<br/>
<xsl:if test="wnio:DoreczenieZwrotne/wnio:AdresZwrotny/@typ='inny'">
<xsl:apply-templates select="wnio:DoreczenieZwrotne/wnio:AdresZwrotny/adr:Adres"/>
<br/>
</xsl:if>
<xsl:if test="wnio:DoreczenieZwrotne/wnio:AdresZwrotny/@typ='wnioskodawcy'">
<xsl:apply-templates select="../../meta:Podmiot/*/adr:Adres"/>
<br/>
</xsl:if>
<xsl:if test="wnio:DoreczenieZwrotne/wnio:AdresZwrotny/@typ='pelnomocnika'">
<xsl:apply-templates select="oso:Osoba/adr:Adres"/>
<br/>
</xsl:if>
</xsl:for-each>
</td>
</tr>
</table>
<br/>
</xsl:for-each> <!-- Wnioskodawca -->
<table width="100%">
<tbody>
<tr>
<td/>
<td style="width:300px">
<span class="sectionHeader">Adresat</span>
<br/>
<br/>
<xsl:call-template name="Instytucja">
<xsl:with-param name="adres" select="wnio:DaneDokumentu/str:Adresaci/meta:Podmiot/inst:Instytucja/adr:Adres"/>
<xsl:with-param name="instytucja" select="wnio:DaneDokumentu/str:Adresaci/meta:Podmiot/inst:Instytucja"/>
</xsl:call-template>
</td>
</tr>
</tbody>
</table>
<br/>
<br/>
<br/>
<xsl:for-each select="wnio:TrescDokumentu">
<center><span>
<b>
<xsl:value-of select="wnio:Wartosc/wnio:TrescWniosku/wnio:NaglowekTresci"/>
</b>
</span></center>
<br/>
<b>Wniosek dotyczy: </b>
<xsl:choose>
<xsl:when test="wnio:Dotyczy='au'">aktu urodzenia</xsl:when>
<xsl:when test="wnio:Dotyczy='am'">aktu małżeństwa</xsl:when>
<xsl:when test="wnio:Dotyczy='az'">aktu zgonu</xsl:when>
</xsl:choose>
<br/><br/>
<b>
<xsl:choose>
<xsl:when test="wnio:Dotyczy='au'">Numer aktu urodzenia</xsl:when>
<xsl:when test="wnio:Dotyczy='am'">Numer aktu małżeństwa</xsl:when>
<xsl:when test="wnio:Dotyczy='az'">Numer aktu zgonu</xsl:when>
</xsl:choose>
: </b>
<xsl:value-of select="wnio:AktNumer"/>
<br/><br/>
<b>
<xsl:choose>
<xsl:when test="wnio:Dotyczy='au'">Data urodzenia</xsl:when>
<xsl:when test="wnio:Dotyczy='am'">Data małżeństwa</xsl:when>
<xsl:when test="wnio:Dotyczy='az'">Data zgonu</xsl:when>
</xsl:choose>
: </b>
<xsl:value-of select="wnio:AktData"/>
<br/><br/>
<b>
<xsl:choose>
<xsl:when test="wnio:Dotyczy='au'">Miejsce urodzenia</xsl:when>
<xsl:when test="wnio:Dotyczy='am'">Miejsce zawarcia małżeństwa</xsl:when>
<xsl:when test="wnio:Dotyczy='az'">Miejsce zgonu</xsl:when>
</xsl:choose>
: </b>
<xsl:value-of select="wnio:AktMiejsce"/>
<br/><br/>
<b>Na nazwisko: </b><xsl:value-of select="wnio:AktNazwisko"/>
<br/><br/>
<xsl:for-each select="wnio:Sprostowania[count(wnio:Sprostowanie) > 0]">
<b>SPROSTOWANIA: </b>
<table border="1" cellspacing="0" cellpadding="4">
<tr>
<td class="tableHeader">L.p.</td>
<td class="tableHeader">W akcie błędnie wpisano</td>
<td class="tableHeader">Powinno być</td>
</tr>
<xsl:for-each select="wnio:Sprostowanie">
<tr>
<td style="width:40px"><xsl:value-of select="position()"/></td>
<td><xsl:value-of select="wnio:Jest"/></td>
<td><xsl:value-of select="wnio:PowinnoByc"/></td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
<br/><br/>
<xsl:for-each select="wnio:Uzupelnienia[count(wnio:Uzupelnienie) > 0]">
<b>UZUPEŁNIENIA: </b>
<table border="1" cellspacing="0" cellpadding="4">
<tr>
<td class="tableHeader">L.p.</td>
<td class="tableHeader">Wpis w akcie</td>
</tr>
<xsl:for-each select="wnio:Uzupelnienie">
<tr>
<td style="width:40px"><xsl:value-of select="position()"/></td>
<td><xsl:value-of select="wnio:Tekst"/></td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
<br/><br/>
<xsl:for-each select="wnio:Strony[count(oso:Osoba) > 0]">
<b>OŚWIADCZAM, ŻE STRONAMI POSTĘPOWANIA SĄ: </b>
<table border="1" cellspacing="0" cellpadding="4">
<tr>
<td class="tableHeader">L.p.</td>
<td class="tableHeader">Strona</td>
</tr>
<xsl:for-each select="oso:Osoba">
<tr>
<td style="width:40px"><xsl:value-of select="position()"/></td>
<td>
<xsl:call-template name="Osoba">
<xsl:with-param name="adres" select="adr:Adres"/>
<xsl:with-param name="osoba" select="."/>
</xsl:call-template>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
<br/><br/>
<b>Odbioru dokumentów dokona: </b>
<br/><br/>
<xsl:call-template name="Osoba">
<xsl:with-param name="adres" select="oso:Osoba/adr:Adres"/>
<xsl:with-param name="osoba" select="oso:Osoba"/>
</xsl:call-template>
</xsl:for-each>
<br/>
<br/>
<xsl:if test="count(wnio:TrescDokumentu/wnio:Wartosc/str:Zalaczniki/str:Zalacznik) > 0">
<span class="sectionHeader">Załączniki</span>
<br/>
<xsl:apply-templates select="wnio:TrescDokumentu/wnio:Wartosc/str:Zalaczniki"/>
<br/>
<b>Potwierdzona zgodność załączników z oryginałami: </b>
<xsl:if test="wnio:TrescDokumentu/wnio:Wartosc/wnio:ZalacznikiEx/@zgodnoscZOryginalem='true'">Tak</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:Wartosc/wnio:ZalacznikiEx/@zgodnoscZOryginalem='false'">Nie</xsl:if>
<br/>
<br/>
</xsl:if>
<br/>
<b>Wyrażam zgodę na wymianę korespondencji drogą elektroniczną: </b>
<xsl:choose>
<xsl:when test="wnio:TrescDokumentu/wnio:Wnioskodawcy/wnio:Wnioskodawca/wnio:ZgodaNaKorespondencjeElektroniczna='true'">Tak</xsl:when>
<xsl:otherwise>Nie</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</body>
</html>
</xsl:template>
<xsl:template match="meta:Podmiot">
<xsl:if test="@typPodmiotu='Osoba'">
<xsl:call-template name="Osoba">
<xsl:with-param name="adres" select="oso:Osoba/adr:Adres"/>
<xsl:with-param name="osoba" select="oso:Osoba"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="@typPodmiotu='Instytucja'">
<xsl:call-template name="Instytucja">
<xsl:with-param name="adres" select="inst:Instytucja/adr:Adres"/>
<xsl:with-param name="instytucja" select="inst:Instytucja"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template name="ImieNazwisko">
<xsl:value-of select="oso:Imie"/>
<xsl:text> </xsl:text>
<xsl:if test="count(oso:Nazwisko) > 0">
<xsl:if test="count(oso:Nazwisko) = 1">
<xsl:value-of select="oso:Nazwisko"/>
<br/>
</xsl:if>
<xsl:if test="count(oso:Nazwisko) > 1">
<xsl:value-of select="oso:Nazwisko[@rodzajCzlonu='pierwszy']"/>
-
<xsl:value-of select="oso:Nazwisko[@rodzajCzlonu='drugi']"/>
<br/>
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:template name="Osoba">
<xsl:param name="adres"/>
<xsl:param name="osoba"/>
<b>
<xsl:value-of select="$osoba/oso:Imie"/>
<xsl:text> </xsl:text>
<xsl:if test="count($osoba/oso:Nazwisko) > 0">
<xsl:if test="count($osoba/oso:Nazwisko) = 1">
<xsl:value-of select="$osoba/oso:Nazwisko"/>
<br/>
</xsl:if>
<xsl:if test="count($osoba/oso:Nazwisko) > 1">
<xsl:value-of select="$osoba/oso:Nazwisko[@rodzajCzlonu='pierwszy']"/>
-
<xsl:value-of select="$osoba/oso:Nazwisko[@rodzajCzlonu='drugi']"/>
<br/>
</xsl:if>
</xsl:if>
</b>
<xsl:if test="$osoba/oso:ImieOjca">
<xsl:text>Imię ojca: </xsl:text>
<xsl:value-of select="$osoba/oso:ImieOjca"/>
<br/>
</xsl:if>
<xsl:if test="$osoba/oso:ImieMatki">
<xsl:text>Imię matki: </xsl:text>
<xsl:value-of select="$osoba/oso:ImieMatki"/>
<br/>
</xsl:if>
<xsl:if test="$adres">
<xsl:apply-templates select="$adres"/>
<br/>
</xsl:if>
<xsl:for-each select="$osoba/oso:IdOsoby/oso:PESEL[text() != '']">
<xsl:text>PESEL: </xsl:text>
<xsl:value-of select="."/>
<br/>
</xsl:for-each>
<xsl:for-each select="$osoba/oso:IdOsoby/oso:NIP[text() != '']">
<xsl:text> NIP: </xsl:text>
<xsl:value-of select="."/>
<br/>
</xsl:for-each>
<xsl:for-each select="$osoba/adr:Kontakt[adr:Telefon != '']">
<xsl:text>Telefon: </xsl:text>
<xsl:value-of select="adr:Telefon"/>
<br/>
</xsl:for-each>
<xsl:for-each select="$osoba/adr:Kontakt[adr:Faks != '']">
<xsl:text>Faks: </xsl:text>
<xsl:value-of select="adr:Faks"/>
<br/>
</xsl:for-each>
<xsl:for-each select="$osoba/adr:Kontakt[adr:Email != '']">
<xsl:text>Email: </xsl:text>
<xsl:value-of select="adr:Email"/>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="Instytucja">
<xsl:param name="adres"/>
<xsl:param name="instytucja"/>
<b>
<xsl:value-of select="$instytucja/inst:NazwaInstytucji"/>
</b>
<br/>
<xsl:for-each select="$instytucja/inst:Jednostka">
<b>
<xsl:value-of select="inst:NazwaInstytucji"/>
</b>
<br/>
</xsl:for-each>
<xsl:apply-templates select="$adres"/>
<br/>
<xsl:for-each select="$instytucja/inst:IdInstytucji/inst:NIP[text() != '']">
<xsl:text> NIP: </xsl:text>
<xsl:value-of select="."/>
<br/>
</xsl:for-each>
<xsl:for-each select="$instytucja/inst:IdInstytucji/inst:REGON[text() != '']">
<xsl:text> REGON: </xsl:text>
<xsl:value-of select="."/>
<br/>
</xsl:for-each>
<xsl:for-each select="$instytucja/inst:IdInstytucji/inst:KRS[text() != '']">
<xsl:text>KRS: </xsl:text>
<xsl:value-of select="."/>
<br/>
</xsl:for-each>
<xsl:for-each select="$instytucja/inst:IdInstytucji/inst:InnyIdentyfikator[inst:TypIdentyfikatora='organizacjaPozarzadowa']/inst:WartoscIdentyfikatora[text() != '']">
<xsl:if test=".='true'">
Organizacja pozarządowa<br/>
</xsl:if>
</xsl:for-each>
<xsl:for-each select="$instytucja/adr:Kontakt[adr:Telefon != '']">
<xsl:text>Telefon: </xsl:text>
<xsl:value-of select="adr:Telefon"/>
<br/>
</xsl:for-each>
<xsl:for-each select="$instytucja/adr:Kontakt[adr:Faks != '']">
<xsl:text>Faks: </xsl:text>
<xsl:value-of select="adr:Faks"/>
<br/>
</xsl:for-each>
<xsl:for-each select="$instytucja/adr:Kontakt[adr:Email != '']">
<xsl:text>Email: </xsl:text>
<xsl:value-of select="adr:Email"/>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template match="adr:Adres" name="Adres">
<xsl:if test="adr:Ulica!=''">
<xsl:for-each select="adr:Ulica[@rodzajUlicy != 'inna']">
<xsl:value-of select="@rodzajUlicy"/>
<xsl:text> </xsl:text>
</xsl:for-each>
<xsl:value-of select="adr:Ulica"/>
<xsl:text> </xsl:text>
<xsl:value-of select="adr:Budynek"/>
<xsl:for-each select="adr:Lokal[text() != '']">
<xsl:text>/</xsl:text>
<xsl:value-of select="."/>
</xsl:for-each>
<br/>
<xsl:choose>
<xsl:when test="not(adr:Poczta) or adr:Poczta='' or (adr:Poczta=adr:Miejscowosc)">
<xsl:text/>
<xsl:value-of select="adr:KodPocztowy"/>
<xsl:text> </xsl:text>
<xsl:value-of select="adr:Miejscowosc"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="adr:Miejscowosc"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="adr:KodPocztowy"/>
<xsl:text> </xsl:text>
<xsl:value-of select="adr:Poczta"/>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
<xsl:if test="adr:Ulica=''">
<xsl:text> </xsl:text>
<xsl:value-of select="adr:Miejscowosc"/>
<xsl:text> </xsl:text>
<xsl:value-of select="adr:Budynek"/>
<xsl:for-each select="adr:Lokal[text() != '']">
<xsl:text>/</xsl:text>
<xsl:value-of select="."/>
</xsl:for-each>
<br/>
<xsl:value-of select="adr:KodPocztowy"/>
<xsl:text> </xsl:text>
<xsl:if test="adr:Poczta!=''">
<xsl:value-of select="adr:Poczta"/>
</xsl:if>
<xsl:if test="adr:Poczta=''">
<xsl:value-of select="adr:Miejscowosc"/>
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:template match="str:Zalaczniki">
<br/>
<xsl:variable name="aktualnyCount" select="count(../wnio:ZalacznikiEx/wnio:Zalacznik[@aktualny='true'])"/>
<table border="1" cellspacing="0" cellpadding="4">
<tr>
<td class="tableHeader">L.p.</td>
<xsl:if test="$aktualnyCount > 0">
<td class="tableHeader">Potwierdzona <br/>aktualność</td>
</xsl:if>
<td class="tableHeader">Nazwa</td>
<td class="tableHeader">Opis</td>
<td class="tableHeader">Plik</td>
</tr>
<xsl:for-each select="str:Zalacznik">
<xsl:variable name="pos" select="position()"/>
<tr>
<td>
<center>
<xsl:value-of select="$pos"/>
</center>
</td>
<xsl:if test="$aktualnyCount > 0">
<td>
<center>
<xsl:if test="../../wnio:ZalacznikiEx/wnio:Zalacznik[$pos]/@aktualny='true'">Tak</xsl:if>
<xsl:if test="../../wnio:ZalacznikiEx/wnio:Zalacznik[$pos]/@aktualny='false'">Nie</xsl:if>
<xsl:if test="../../wnio:ZalacznikiEx/wnio:Zalacznik[$pos]/@aktualny=''">Nie dotyczy</xsl:if>
</center>
</td>
</xsl:if>
<td>
<xsl:value-of select="../../wnio:ZalacznikiEx/wnio:Zalacznik[$pos]/wnio:RodzajNazwa"/>
</td>
<td> <xsl:value-of select="str:OpisZalacznika"/>
</td>
<td>
<xsl:choose>
<xsl:when test="@kodowanie='URI'">
<A>
<xsl:attribute name="HREF">
<xsl:value-of select="str:DaneZalacznika"/>
</xsl:attribute>
<xsl:attribute name="TARGET">_blank</xsl:attribute>
<B>
<xsl:value-of select="@nazwaPliku"/>
</B>
</A>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="@nazwaPliku"/>
</xsl:otherwise>
</xsl:choose>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>