1891
| ID | 1891 |
|---|
| Data | 2014-12-08 |
|---|
| Symbol | 2014/12/08/1891 |
|---|
| Instytucja | Wojewódzka Stacja Sanitarno-Epidemiologiczna w Białymstoku |
|---|
| Nazwa | Zlecenie badań mikrobiologicznych procesów sterylizacji |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
| URI://Dziennik_Ustaw/2014/1114/16b/1 | Art. 16b ust. 1 ustawy z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (t. j. z 2014r. poz. 1114) |
|---|
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml" xmlns:adr="http://crd.gov.pl/xml/schematy/adres/2009/11/09/" xmlns:ds="http://www.w3.org/2000/09/xmldsig#" xmlns:inst="http://crd.gov.pl/xml/schematy/instytucja/2009/11/16/" xmlns:meta="http://crd.gov.pl/xml/schematy/meta/2009/11/16/" xmlns:oso="http://crd.gov.pl/xml/schematy/osoba/2009/11/16/" xmlns:str="http://crd.gov.pl/xml/schematy/struktura/2009/11/16/" xmlns:wnio="http://crd.gov.pl/wzor/2014/12/08/1891/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" exclude-result-prefixes="adr oso inst meta wnio ds str xsi" version="1.0" xsi:schemaLocation="http://www.w3.org/1999/XSL/Transform http://www.w3.org/2005/02/schema-for-xslt20.xsd">
<xsl:output doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd" encoding="UTF-8" indent="yes" method="xml"/>
<xsl:template match="wnio:Dokument">
<html>
<head>
<meta content="text/html; charset=utf-8" http-equiv="Content-Type"/>
<title>Zlecenie</title>
<style type="text/css">
body {
margin: 0;
padding: 30px 30px 15px 30px;
font-family: "Times New Roman", Times, serif;
font-size: 1.05em;
color: #000;
line-height: 1.5em;
}
div.header, div.content {
margin-bottom: 15px;
overflow: hidden;
}
div.wideTable {
overflow: auto;
}
p {
margin: 0 0 15px 0;
}
p.toRight {
float: right;
}
p.toLeft {
clear: both;
}
p.level1 {
text-indent: 16px;
}
p.level2 {
text-indent: 32px;
}
p.level3 {
text-indent: 48px;
}
p.level4 {
text-indent: 64px;
}
span.title {
font-weight: bold;
}
span.line {
display: block;
}
span.label {
color: #555;
}
h1.print {
text-align: center;
font-size: 140%;
margin: 0 0 30px 0;
}
h2.print {
font-size: 120%;
margin: 0 0 15px 0;
}
ul {
margin: 0 0 15px 0;
list-style-type: square;
}
ol {
margin: 0 0 15px 0;
}
table {
border-collapse: collapse;
margin: 0 0 15px 0;
}
table th, table td {
border: 1px solid #555;
padding: 0 7px;
}
span.formattedText{
display: block;
}
</style>
</head>
<body>
<div class="header">
<p class="toRight">
<span>
<xsl:value-of select="wnio:TrescDokumentu/wnio:MiejscowoscDokumentu"/>,
</span>
<span>
<xsl:value-of select="wnio:TrescDokumentu/wnio:DataDokumentu"/>
</span>
</p>
<xsl:call-template name="wnioskodawca"/>
<xsl:if test="count(wnio:DaneDokumentu/str:Adresaci)>0">
<p class="toRight">
<xsl:call-template name="adresatInstytucja"/>
</p>
</xsl:if>
</div>
<div class="content">
<xsl:call-template name="template_content"/>
</div>
<div class="attachments">
<xsl:call-template name="Zalaczniki"/>
</div>
<div class="footer">
<xsl:call-template name="template_footer"/>
</div>
<div class="podpis">
<xsl:call-template name="Podpis"/>
</div>
</body>
</html>
</xsl:template>
<xsl:template name="wnioskodawca">
<xsl:param name="podmiot" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot"/>
<p class="toLeft">
<span class="title line">Nadawca:</span>
<xsl:if test="count($podmiot/oso:Osoba)>0">
<xsl:call-template name="wnioskodawacaOsoba"/>
</xsl:if>
<xsl:if test="count($podmiot/inst:Instytucja)>0">
<xsl:call-template name="wnioskodawcaInstytucja"/>
</xsl:if>
</p>
</xsl:template>
<xsl:template name="wnioskodawacaOsoba">
<xsl:param name="osoba" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot/oso:Osoba"/>
<xsl:param name="adres" select="$osoba/adr:Adres"/>
<xsl:if test="string-length(normalize-space($osoba/oso:IdOsoby/oso:PESEL)) > 0">
<span class="line">
<span class="label">PESEL: </span>
<span>
<xsl:value-of select="$osoba/oso:IdOsoby/oso:PESEL"/>
</span>
</span>
</xsl:if>
<xsl:if test="string-length(normalize-space($osoba/oso:IdOsoby/oso:NIP)) > 0">
<span class="line">
<span class="label">NIP: </span>
<span>
<xsl:value-of select="$osoba/oso:IdOsoby/oso:NIP"/>
</span>
</span>
</xsl:if>
<span class="line">
<span>
<xsl:value-of select="$osoba/oso:Imie"/>
</span>
<span> </span>
<span>
<xsl:value-of select="$osoba/oso:Nazwisko"/>
</span>
</span>
<xsl:call-template name="adres">
<xsl:with-param name="adres" select="$adres"/>
</xsl:call-template>
<xsl:if test="string-length(normalize-space($osoba/adr:Kontakt/adr:Email)) > 0">
<span class="line">
<span class="label">Adres e-mail:</span>
<span> </span>
<span>
<xsl:element name="a">
<xsl:attribute name="href">
<xsl:text>mailto:</xsl:text>
<xsl:value-of select="$osoba/adr:Kontakt/adr:Email"/>
</xsl:attribute>
<xsl:value-of select="$osoba/adr:Kontakt/adr:Email"/>
</xsl:element>
</span>
</span>
</xsl:if>
</xsl:template>
<xsl:template name="wnioskodawcaInstytucja">
<xsl:param name="instytucja" select="wnio:DaneDokumentu/str:Nadawcy/meta:Podmiot/inst:Instytucja"/>
<xsl:param name="adres" select="$instytucja/adr:Adres"/>
<span class="line">
<span>
<xsl:value-of select="$instytucja/inst:NazwaInstytucji"/>
</span>
</span>
<xsl:if test="string-length($instytucja/inst:IdInstytucji/inst:NIP) > 0">
<span class="line">
<span class="label">NIP: </span>
<span>
<xsl:value-of select="$instytucja/inst:IdInstytucji/inst:NIP"/>
</span>
</span>
</xsl:if>
<xsl:if test="string-length($instytucja/inst:IdInstytucji/inst:REGON) > 0">
<span class="line">
<span class="label">REGON: </span>
<span>
<xsl:value-of select="$instytucja/inst:IdInstytucji/inst:REGON"/>
</span>
</span>
</xsl:if>
<xsl:call-template name="adres">
<xsl:with-param name="adres" select="$adres"/>
</xsl:call-template>
<xsl:if test="string-length(normalize-space($instytucja/adr:Kontakt/adr:Email)) > 0">
<span class="line">
<span class="label">Adres e-mail:</span>
<span> </span>
<span>
<xsl:element name="a">
<xsl:attribute name="href">
<xsl:text>mailto:</xsl:text>
<xsl:value-of select="$instytucja/adr:Kontakt/adr:Email"/>
</xsl:attribute>
<xsl:value-of select="$instytucja/adr:Kontakt/adr:Email"/>
</xsl:element>
</span>
</span>
</xsl:if>
</xsl:template>
<xsl:template name="adresatInstytucja">
<xsl:param name="instytucja" select="wnio:DaneDokumentu/str:Adresaci/meta:Podmiot/inst:Instytucja"/>
<xsl:param name="adres" select="$instytucja/adr:Adres"/>
<span class="title line">
<xsl:value-of select="$instytucja/inst:NazwaInstytucji"/>
</span>
<xsl:call-template name="adres">
<xsl:with-param name="adres" select="$adres"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="adres">
<xsl:param name="adres"/>
<xsl:choose>
<xsl:when test="string-length($adres/adr:KodPocztowy) > 0 or string-length($adres/adr:Poczta) > 0 or string-length($adres/adr:Miejscowosc) > 0">
<span class="line">
<span>
<xsl:value-of select="$adres/adr:KodPocztowy"/>
</span>
<span> </span>
<span>
<xsl:choose>
<xsl:when test="string-length($adres/adr:Poczta) > 0">
<xsl:value-of select="$adres/adr:Poczta"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$adres/adr:Miejscowosc"/>
</xsl:otherwise>
</xsl:choose>
</span>
</span>
</xsl:when>
</xsl:choose>
<xsl:choose>
<xsl:when test="string-length($adres/adr:Ulica) > 0 or string-length($adres/adr:Budynek) > 0 or string-length($adres/adr:Lokal) > 0 or string-length($adres/adr:Poczta) > 0 or string-length($adres/adr:Miejscowosc) > 0">
<span class="line">
<xsl:choose>
<xsl:when test="string-length($adres/adr:Ulica) > 0">
<span>
<xsl:value-of select="$adres/adr:Ulica"/>
</span>
<span> </span>
<span>
<xsl:value-of select="$adres/adr:Budynek"/>
</span>
<xsl:if test="string-length($adres/adr:Lokal) > 0">
<span> / </span>
<span>
<xsl:value-of select="$adres/adr:Lokal"/>
</span>
</xsl:if>
<xsl:if test="string-length($adres/adr:Poczta) > 0">
<span>, </span>
<span>
<xsl:value-of select="$adres/adr:Miejscowosc"/>
</span>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<span>
<xsl:value-of select="$adres/adr:Miejscowosc"/>
</span>
<span> </span>
<span>
<xsl:value-of select="$adres/adr:Budynek"/>
</span>
<xsl:if test="string-length($adres/adr:Lokal) > 0">
<span> / </span>
<span>
<xsl:value-of select="$adres/adr:Lokal"/>
</span>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</span>
</xsl:when>
</xsl:choose>
</xsl:template>
<xsl:template name="formattedText">
<xsl:param name="input"/>
<xsl:choose>
<xsl:when test="contains($input, '
')">
<xsl:value-of select="substring-before($input, '
')"/>
<br/>
<xsl:call-template name="formattedText">
<xsl:with-param name="input" select="substring-after($input, '
')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$input"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="Podpis">
<div>
<h2 class="print">Podpisy elektroniczne</h2>
<ul>
<li>
<xsl:choose>
<xsl:when test="string-length(//wnio:Dokument/ds:Signature/ds:SignatureValue) > 0">
<xsl:text>Dokument został podpisany, aby go zweryfikować należy użyć oprogramowania do weryfikacji podpisu.</xsl:text>
<xsl:choose>
<xsl:when test="count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']) > 1">
<br/>
<xsl:text>Daty złożenia podpisu: </xsl:text>
<xsl:for-each select="//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']">
<xsl:value-of select="."/>
</xsl:for-each>
</xsl:when>
<xsl:when test="count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']) = 1">
<br/>
<xsl:text>Data złożenia podpisu: </xsl:text>
<xsl:for-each select="//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']">
<xsl:value-of select="."/>
</xsl:for-each>
</xsl:when>
<xsl:when test="0 >= count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime'])"/>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:text>Dokument nie zawiera podpisu.</xsl:text>
</xsl:otherwise>
</xsl:choose>
</li>
</ul>
</div>
<div style="clear: both;"/>
</xsl:template>
<xsl:template name="Zalaczniki">
<xsl:param name="zalaczniki" select="wnio:TrescDokumentu/str:Zalaczniki"/>
<xsl:if test="count($zalaczniki/str:Zalacznik) > 0">
<div style="text-align: left;">
<h2 class="print">Załączniki:</h2>
<ol style="padding-top: 0px;margin-top: 0px;">
<xsl:for-each select="$zalaczniki/str:Zalacznik[@nazwaPliku != '']">
<li>
<xsl:if test="@kodowanie='base64'">
<xsl:value-of select="@nazwaPliku"/>
<xsl:if test="string-length(str:OpisZalacznika) > 0"> - </xsl:if>
<xsl:if test="string-length(str:OpisZalacznika) > 0">
<xsl:value-of select="str:OpisZalacznika"/>
</xsl:if>
</xsl:if>
<xsl:if test="@kodowanie='URI'">
<a href="{str:DaneZalacznika}">
<xsl:value-of select="@nazwaPliku"/>
</a>
<xsl:if test="string-length(str:OpisZalacznika) > 0">
(<xsl:value-of select="str:OpisZalacznika"/>)
</xsl:if>
</xsl:if>
</li>
</xsl:for-each>
</ol>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="template_content">
<xsl:call-template name="content"/>
</xsl:template>
<xsl:template name="template_footer">
<xsl:if test="string-length(normalize-space(//wnio:OswiadczenieKorespondencja)) > 0">
<h2 class="print">Oświadczenie korespondencji</h2>
<ul>
<li>
<xsl:choose>
<xsl:when test="string-length(normalize-space(//wnio:OswiadczenieKorespondencja)) > 0">
<p class="matter">
<xsl:value-of select="//wnio:OswiadczenieKorespondencja"/>
</p>
</xsl:when>
<xsl:otherwise>Brak oświadczenia.</xsl:otherwise>
</xsl:choose>
</li>
</ul>
</xsl:if>
</xsl:template>
<xsl:template name="dictZakresBadan">
<xsl:param name="key"/>
<xsl:choose>
<xsl:when test="$key=01">Badanie skuteczności procesów sterylizacji przy użyciu wskaźników biologicznych wg instrukcji producentów testów
PB-01 wyd. 3, data wyd. 02.11.2010 (N)</xsl:when>
<xsl:when test="$key=02">Badanie mikrobiologiczne środowiska szpitalnego
PB-03 wyd. 2, data wyd. 02.02.2009 (N)</xsl:when>
<xsl:when test="$key=03">Badanie mikrobiologiczne materiału biologicznego w kierunku wykrycia i różnicowania pałeczek z rodziny Enterobacteriaceae
PB-04 wyd. 4, data wyd. 31.10.2008 (N)</xsl:when>
<xsl:when test="$key=04">Wykrywanie pasożytów przewodu pokarmowego metodami koproskopowymi wg materiałów źródłowych
PB-05 wyd. 3, data wyd. 12.10.2009 (N)</xsl:when>
<xsl:when test="$key=05">Oznaczanie przeciwciał w surowicy w odczynie immunoenzymatycznym ELISA wg instrukcji producenta testów
PB-06 wyd. 4, data wyd. 27.05.2011 (N)</xsl:when>
<xsl:when test="$key=06">Oznaczanie miana przeciwciał w surowicy w odczynie aglutynacji wg materiałów źródłowych PZH w Warszawie
PB-09 wyd. 3, data wyd. 03.03.2010 (N)</xsl:when>
<xsl:when test="$key=07">Oznaczanie antygenu i przeciwciał anty-HBs w surowicy metodą enzymoimmunofluorescencyjną ELFA przy użyciu automatycznego systemu mini Vidas wg instrukcji producenta testów
PB-37 wyd. 5, data wyd. 05.05.2011</xsl:when>
<xsl:when test="$key=08">Badanie mikrobiologiczne materiału biologicznego w kierunku wykrywania i różnicowania ziarenkowców G(+) przy użyciu analizatora mikrobiologicznego mini-API
PB-40 wyd. 3, data wyd. 15.09.2011 (N)</xsl:when>
<xsl:when test="$key=09">Badania wirusologiczne. Izolacja wirusów grypy z materiału biologicznego na hodowli tkankowej MDCK wg materiałów źródłowych Krajowego Ośrodka ds. grypy PZH w Warszawie
PB-68 wyd. 4, data wyd. 05.05.2011</xsl:when>
<xsl:when test="$key=10">Badanie mikrobiologiczne materiału biologicznego w kierunku wykrywania i różnicowania pałeczek z rodzaju Salmonella, Shigella przy użyciu analizatora mikrobiologicznego mini-API
PB-76 wyd. 2, data wyd. 05.05.2011</xsl:when>
<xsl:when test="$key=11">Wykrywanie astrowirusów, rotawirusów i adenowirusów w kale techniką immunochromatograficzną wg instrukcji producentów testów
PB-29 wyd. 3, data wyd. 21.05.2012 (N)</xsl:when>
<xsl:when test="$key=12">Badanie parazytologiczne gleby w kierunku wykrycia jaj Toxocara spp.
PB-32 wyd. 1, data wyd. 20.04.2009 (N)</xsl:when>
<xsl:when test="$key=13">Jakość gleby - Ocena stanu sanitarnego gleby - Wykrywanie jaj pasożytów jelitowych Ascaris lumbricoides i Trichuris trichiura
Wg normy: PN-Z-19000-4 2001 (N)</xsl:when>
<xsl:when test="$key=14">Wykrywanie wirusów grypy A i B, parainfluenzy typu 1, 2 i 3, RSV oraz adenowirusów z materiału biologicznego metodą immunofluorescencji bezpośredniej
PB-02 wyd. 2, data wyd. 21.05.2012 (N)</xsl:when>
<xsl:when test="$key=15">Wykrywanie obecności wirusów grypy w materiale biologicznym metodą real time RT-PCR wg instrukcji producentów testów
PB-59 wyd. 3, data wyd. 02.01.2012</xsl:when>
<xsl:when test="$key=16">Wykrywanie norowirusów w kale techniką immunochromatograficzną wg instrukcji producenta testu
PB-90 wyd. 1, data wyd. 26.04.2010 (N)</xsl:when>
<xsl:when test="$key=17">Oznaczanie przeciwciał anty-CMV, anty-Rubella, anty-Toxoplazma, oraz ocena awidności w surowicy metodą enzymoimmunofluorescencyjną ELFA przy użyciu automatycznego systemu mini Vidas wg instrukcji producenta testów
PB-93 wyd. 1, data wyd. 26.04.2010 (N)</xsl:when>
</xsl:choose>
</xsl:template>
<xsl:template name="zakresBadan">
<xsl:param name="pText"/>
<xsl:if test="string-length($pText)">
<li>
<xsl:call-template name="dictZakresBadan">
<xsl:with-param name="key" select="substring-before(concat($pText,' '),' ')"/>
</xsl:call-template>
</li>
<xsl:call-template name="zakresBadan">
<xsl:with-param name="pText" select="substring-after($pText, ' ')"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template name="content">
<h1 class="print">Zlecenie</h1>
<h3>Dodatkowe dane wnioskodawcy</h3>
<xsl:if test="//wnio:Wnioskodawca/wnio:ZasadyKomunikacji != ''">
<p>
<span class="label">Zasady komunikowania się z klientem: </span>
<span class="title">
<xsl:value-of select="//wnio:Wnioskodawca/wnio:ZasadyKomunikacji"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:Wnioskodawca/wnio:Telefon != ''">
<p>
<span class="label">Nr telefonu: </span>
<span class="title">
<xsl:value-of select="//wnio:Wnioskodawca/wnio:Telefon"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:Wnioskodawca/wnio:DoKontaktu != ''">
<p>
<span class="label">Dodatkowe informacje do kontaktu: </span>
<span>
<xsl:call-template name="formattedText">
<xsl:with-param name="input" select="//wnio:Wnioskodawca/wnio:DoKontaktu"/>
</xsl:call-template>
</span>
</p>
</xsl:if>
<h3>Próbki</h3>
<xsl:for-each select="//wnio:Probki/wnio:Probka">
<table style="width:100%;">
<tr>
<th colspan="2">
<span>Próbka, nr <xsl:value-of select="position()"/>
</span>
</th>
</tr>
<tr>
<td style="width:20%;">
<span class="label">Rodzaj próbki: </span>
</td>
<td>
<span>
<xsl:value-of select="substring(wnio:RodzajProbki,0)"/>
</span>
</td>
</tr>
<tr>
<td>
<span class="label">Badania: </span>
</td>
<td>
<xsl:if test="wnio:ZakresBadan != ''">
<ul>
<xsl:call-template name="zakresBadan">
<xsl:with-param name="pText" select="wnio:ZakresBadan"/>
</xsl:call-template>
</ul>
</xsl:if>
</td>
</tr>
</table>
</xsl:for-each>
<h3>Dodatkowe informacje</h3>
<xsl:if test="//wnio:PoborProbek != ''">
<p>
<span class="label">Pobór próbek: </span>
<span class="title">
<xsl:value-of select="//wnio:PoborProbek"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:SrodekTransportu != ''">
<p>
<span class="label">Środek transportu: </span>
<span class="title">
<xsl:value-of select="//wnio:SrodekTransportu"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:DataPobrania != ''">
<p>
<span class="label">Data pobrania: </span>
<span class="title">
<xsl:value-of select="//wnio:DataPobrania"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:TerminRealizacji != ''">
<p>
<span class="label"> Termin realizacji zlecenia: </span>
<span class="title">
<xsl:value-of select="//wnio:TerminRealizacji"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:OcenaWynikow != ''">
<p>
<span class="label">Ocena wyników badań: </span>
<span class="title">
<xsl:value-of select="//wnio:OcenaWynikow"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:SposobPodaniaWynikow != ''">
<p>
<span class="label">Sposób podania wyników badań: </span>
<span class="title">
<xsl:value-of select="//wnio:SposobPodaniaWynikow"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:SposobPodaniaWynikow/@niepewnosc != ''">
<p>
<span class="label">z podaniem niepewności: </span>
<span class="title">
<xsl:value-of select="//wnio:SposobPodaniaWynikow/@niepewnosc"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:SposobPrzekazania != ''">
<p>
<span class="label">Sposób przekazania sprawozdania: </span>
<span class="title">
<xsl:value-of select="//wnio:SposobPrzekazania"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:Naleznosc != ''">
<p>
<span class="label">Należność za badania wg cennika WSSE: </span>
<span class="title">
<xsl:value-of select="//wnio:Naleznosc"/>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:InneUwagi != ''">
<p>
<span class="label">Inne: </span>
<span>
<xsl:call-template name="formattedText">
<xsl:with-param name="input" select="//wnio:InneUwagi"/>
</xsl:call-template>
</span>
</p>
</xsl:if>
<xsl:if test="//wnio:ChceBycObserwatorem/@wybor= 'tak'">
<p>
<span class="title">
Chcę uczestniczyć w badaniach jako obserwator.
</span>
</p>
<p>
<span class="label">W dniu: </span>
<span class="title">
<xsl:value-of select="//wnio:ObserwatorDnia"/>
</span>
</p>
</xsl:if>
</xsl:template>
</xsl:stylesheet>