14195

ID	14195
Data	2026-03-12
Symbol	2026/03/12/14195
Instytucja	Ministerstwo Finansów
Nazwa	WN-CFR WNIOSEK O CERTYFIKAT REZYDENCJI PODATKOWEJ
Czy Aktualny	1

Ustawy (1)

URI://Dziennik_Ustaw/2025/1703/16b/1	Art. 16b ust. 1 ustawy z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (Dz. U. z 2025 r. poz. 1703)

Pliki

• wyroznik.xml
• styl.xsl
• schemat.xsd

Styl

<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tns="http://crd.gov.pl/wzor/2026/03/12/14195/" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="1.0">
	<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/18/eD/DefinicjeSzablony/WspolneSzablonyWizualizacji_v15-0E.xsl"/>
	<xsl:param name="nazwy-dla-kodow" select="true()"/>
	<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
	<xsl:template name="TytulDokumentu">
		WNIOSEK O CERTYFIKAT REZYDENCJI PODATKOWEJ
   	</xsl:template>
	<xsl:template name="StyleDlaFormularza">
		<style type="text/css">
    table.wrapping, .break-word {
    white-space: normal !important;
    word-wrap: break-word;
	}
	table {
    width:100%;
	}
	hr {
        border: none;
        height: 2px;
        background-color: black;
    }
    .lewanaglowek {	font-size: 1.5em; padding: 1px; vertical-align: top; text-align: left;}
    .lewanaglowekczerwony {	font-size: 1.4em; color: red; padding: 1px; vertical-align: top; text-align: left;}
    .lewapozycja { font-size: 1.2em; padding: 1px; vertical-align: top; text-align: left;}
    .srodek { solid black; font-size: 1.2em; padding: 1px; vertical-align: top; text-align: center;}
    .prawa { font-size: 1.2em; padding: 1px; vertical-align: top; text-align: right;}
    .lewa { font-size: 1.2em; padding: 1px; vertical-align: top; text-align: left;}
    .wielkielitery { text-transform: uppercase;}
	</style>
	</xsl:template>
	<xsl:template match="tns:Pismo">
		<div class="deklaracja">
			<xsl:call-template name="NaglowekeUS"/>
			<hr/>
			<xsl:for-each select="*[local-name()='Podmiot2']">
				<xsl:call-template name="Skladajacy"/>
			</xsl:for-each>
			<xsl:if test="*[local-name()='Podmiot2']">
				<hr width="60%" align="left"/>
			</xsl:if>
			<br/>
			<xsl:call-template name="NaglowekData"/>
			<br/>
			<xsl:call-template name="Urzad"/>
			<br/>
			<xsl:call-template name="WniosekV"/>
			<br/>
			<br/>
			<xsl:for-each select="*[local-name()='Podmiot1']">
				<xsl:call-template name="OsobaPodmiot1"/>
			</xsl:for-each>
			<br/>
			<xsl:for-each select="*[local-name()='PozycjeSzczegolowe']">
				<xsl:call-template name="Wniosek"/>
				<xsl:call-template name="PodstawaPrawna"/>
			</xsl:for-each>
			<xsl:call-template name="Podpis"/>
			<xsl:for-each select="*[local-name()='Zalaczniki']">
				<xsl:call-template name="Zalaczniki"/>
			</xsl:for-each>
		</div>
	</xsl:template>
	<xsl:template name="NaglowekeUS">
		<table class="break-word">
			<tr>
				<td>
					<div class="lewanaglowek">
						<b><font style="color:red">e</font>-Urząd Skarbowy</b>
					</div>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="NaglowekData">
		<div class="lewa">
			<xsl:variable name="dt" select="*[local-name()='Naglowek']/*[local-name()='DataWypelnienia']"/>
			<xsl:value-of select="concat(     substring($dt,9,2),'.',     substring($dt,6,2),'.',     substring($dt,1,4))"/>
		</div>
	</xsl:template>
	<xsl:template name="Skladajacy">
		<table class="break-word">
			<tr>
				<td width="20%">
					Składający
				</td>
				<td width="40%">
					<xsl:for-each select="*[local-name()='OsobaFizyczna']">
						<xsl:call-template name="OsobaFizyczna"/>
					</xsl:for-each>
				</td>
				<td width="40%"/>
			</tr>
			<xsl:if test="..//*[local-name()='Podmiot2']">
				<xsl:if test="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_21']">
					<tr>
						<td width="20%"/>
						<td width="40%">
							Adres e-mail: <xsl:value-of select="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_21']"/>
						</td>
						<td width="40%"/>
					</tr>
				</xsl:if>
				<xsl:if test="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_22']">
					<tr>
						<td width="20%"/>
						<td width="40%">
							Telefon: <xsl:value-of select="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_22']"/>
						</td>
						<td width="40%"/>
					</tr>
				</xsl:if>
			</xsl:if>
		</table>
	</xsl:template>
	<xsl:template name="Urzad">
		<div class="lewanaglowek">
			<b>
				<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
			</b>
		</div>
	</xsl:template>
	<xsl:template name="WniosekV">
		<div class="lewanaglowek">
			<b>Wniosek o certyfikat rezydencji podatkowej (<xsl:value-of select="*[local-name()='Naglowek']/*[local-name()='KodFormularza']"/>)</b>
		</div>
	</xsl:template>
	<xsl:template name="OsobaPodmiot1">
		<xsl:if test="*[local-name()='OsobaFizyczna']">
			<div class="lewanaglowekczerwony">
				<b>Osoba, której dotyczy dokument</b>
			</div>
		</xsl:if>
		<xsl:if test="*[local-name()='OsobaNiefizyczna']">
			<div class="lewanaglowekczerwony">
				<b>Podmiot, którego dotyczy dokument</b>
			</div>
		</xsl:if>
		<table class="break-word">
			<tr>
				<td width="40%">
					<xsl:if test="*[local-name()='OsobaFizyczna']">
						<xsl:for-each select="*[local-name()='OsobaFizyczna']">
							<xsl:call-template name="OsobaFizyczna"/>
						</xsl:for-each>
					</xsl:if>
					<xsl:if test="*[local-name()='OsobaNiefizyczna']">
						<xsl:call-template name="OsobaNiefizyczna"/>
					</xsl:if>
					<xsl:if test="*[local-name()='AdresZamieszkaniaSiedziby']/*[local-name()='AdresPol']">
						<xsl:call-template name="AdresPol"/>
					</xsl:if>
					<xsl:if test="*[local-name()='AdresZamieszkaniaSiedziby']/*[local-name()='AdresZagr']">
						<xsl:call-template name="AdresZagr"/>
					</xsl:if>
				</td>
				<td width="60%"/>
			</tr>
			<xsl:if test="not(//*[local-name()='Podmiot2'])">
				<xsl:if test="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_21']">
					<tr>
						<td width="20%">
							Adres e-mail: <xsl:value-of select="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_21']"/>
						</td>
						<td width="80%"/>
					</tr>
				</xsl:if>
				<xsl:if test="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_22']">
					<tr>
						<td width="20%">
							Telefon: <xsl:value-of select="..//*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_22']"/>
						</td>
						<td width="80%"/>
					</tr>
				</xsl:if>
			</xsl:if>
		</table>
	</xsl:template>
	<xsl:template name="Wniosek">
		<div class="lewanaglowekczerwony">
			<b>Szczegóły wniosku</b>
		</div>
		<br/>
		<div class="lewapozycja">
			<b>Treść wniosku</b>
		</div>
		<br/>
		<table class="break-word">
			<tr>
				<td>
					<xsl:value-of select="*[local-name()='P_12']"/>
				</td>
			</tr>
		</table>
		<br/>
		<div class="lewapozycja">
			<b>Państwo</b>
		</div>
		<br/>
		<table class="break-word">
			<tr>
				<td>
					<xsl:for-each select="*[local-name()='P_13']">
						<xsl:call-template name="PokazKodKraju"/>
					</xsl:for-each>
				</td>
			</tr>
		</table>
		<br/>
		<xsl:if test="*[local-name()='P_14']">
			<div class="lewapozycja">
				<b>Okres ważności certyfikatu</b>
			</div>
			<br/>
			<table class="break-word">
				<tr>
					<td>
						<xsl:if test="*[local-name()='P_14'] = '1'">
							Za okres
						</xsl:if>
					</td>
				</tr>
			</table>
			<br/>
			<div class="lewapozycja">
				<b>Od dnia</b>
			</div>
			<br/>
			<table class="break-word">
				<tr>
					<td>
						<div>
							<xsl:variable name="dt" select="*[local-name()='P_16']"/>
							<xsl:value-of select="concat(         substring($dt,9,2),'.',         substring($dt,6,2),'.',         substring($dt,1,4))"/>
						</div>
					</td>
				</tr>
			</table>
			<br/>
			<div class="lewapozycja">
				<b>Do dnia</b>
			</div>
			<br/>
			<table class="break-word">
				<tr>
					<td>
						<div>
							<xsl:variable name="dt" select="*[local-name()='P_17']"/>
							<xsl:value-of select="concat(         substring($dt,9,2),'.',         substring($dt,6,2),'.',         substring($dt,1,4))"/>
						</div>
					</td>
				</tr>
			</table>
			<br/>
		</xsl:if>
		<xsl:if test="*[local-name()='P_15']">
			<div class="lewapozycja">
				<b>Okres ważności certyfikatu</b>
			</div>
			<br/>
			<table class="break-word">
				<tr>
					<td>
						<xsl:if test="*[local-name()='P_15'] = '1'">
							Na dzień złożenia wniosku
						</xsl:if>
					</td>
				</tr>
			</table>
			<br/>
			<div class="lewapozycja">
				<b>Data złożenia wniosku</b>
			</div>
			<br/>
			<table class="break-word">
				<tr>
					<td>
						<div>
							<xsl:variable name="dt" select="*[local-name()='P_18']"/>
							<xsl:value-of select="concat(         substring($dt,9,2),'.',         substring($dt,6,2),'.',         substring($dt,1,4))"/>
						</div>
					</td>
				</tr>
			</table>
			<br/>
		</xsl:if>
		<div class="lewapozycja">
			<b>Cel wydania zaświadczenia</b>
		</div>
		<br/>
		<table class="break-word">
			<tr>
				<td>
					<xsl:value-of select="*[local-name()='P_19']"/>
				</td>
			</tr>
		</table>
		<br/>
	</xsl:template>
	<xsl:template name="PodstawaPrawna">
		<div class="lewanaglowekczerwony">
			<b>Podstawa prawna</b>
		</div>
		<br/>
		<table class="break-word">
			<tr>
				<td>
					<xsl:value-of select="*[local-name()='P_20']"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="Podpis">
		<br/>
		<br/>
		<br/>
		<xsl:choose>
			<xsl:when test="*[local-name()='Podmiot2']/@TRola='UKO'">
				<xsl:for-each select="*[local-name()='Podmiot2']/*[local-name()='OsobaFizyczna']">
					<table class="break-word">
						<tr>
							<td width="60%"/>
							<td class="srodek" width="40%">
								<font style="font-size: 0.8em; font-weight: normal">
									Użytkownik konta organizacji
								</font>
								<br/>
								<xsl:value-of select="*[local-name()='ImiePierwsze']"/>
								<xsl:text> </xsl:text>
								<xsl:value-of select="*[local-name()='Nazwisko']"/>
								<br/>
								<xsl:if test="*[local-name()='NIP']">
									<xsl:value-of select="*[local-name()='NIP']"/>
									<br/>
								</xsl:if>
								<xsl:if test="*[local-name()='PESEL']">
									<xsl:value-of select="*[local-name()='PESEL']"/>
									<br/>
								</xsl:if>
								<font style="font-size: 0.8em; font-weight: normal">
									Dokument wygenerowany elektronicznie
									<br/>
									w e-Urzędzie Skarbowym
								</font>
							</td>
						</tr>
					</table>
				</xsl:for-each>
			</xsl:when>
			<xsl:when test="*[local-name()='Podmiot2']/@TRola='Pełnomocnik'">
				<xsl:for-each select="*[local-name()='Podmiot2']/*[local-name()='OsobaFizyczna']">
					<table class="break-word">
						<tr>
							<td width="60%"/>
							<td class="srodek" width="40%">
								<xsl:value-of select="*[local-name()='ImiePierwsze']"/>
								<xsl:text> </xsl:text>
								<xsl:value-of select="*[local-name()='Nazwisko']"/>
								<br/>
								<xsl:if test="*[local-name()='NIP']">
									<xsl:value-of select="*[local-name()='NIP']"/>
									<br/>
								</xsl:if>
								<xsl:if test="*[local-name()='PESEL']">
									<xsl:value-of select="*[local-name()='PESEL']"/>
									<br/>
								</xsl:if>
								<font style="font-size: 0.8em; font-weight: normal">
									Dokument wygenerowany elektronicznie
									<br/>
									w e-Urzędzie Skarbowym
								</font>
							</td>
						</tr>
					</table>
				</xsl:for-each>
			</xsl:when>
			<xsl:otherwise>
				<xsl:for-each select="*[local-name()='Podmiot1']">
					<table class="break-word">
						<tr>
							<td width="60%"/>
							<td class="srodek" width="40%">
								<xsl:if test="*[local-name()='OsobaNiefizyczna']">
									<br/>
									<xsl:value-of select="*[local-name()='OsobaNiefizyczna']/*[local-name()='PelnaNazwa']"/>
									<br/>
									<xsl:value-of select="*[local-name()='OsobaNiefizyczna']/*[local-name()='NIP']"/>
									<br/>
								</xsl:if>
								<xsl:if test="*[local-name()='OsobaFizyczna']">
									<xsl:value-of select="*[local-name()='OsobaFizyczna']/*[local-name()='ImiePierwsze']"/>
									<xsl:text> </xsl:text>
									<xsl:value-of select="*[local-name()='OsobaFizyczna']/*[local-name()='Nazwisko']"/>
									<br/>
									<xsl:if test="*[local-name()='OsobaFizyczna']/*[local-name()='NIP']">
										<xsl:value-of select="*[local-name()='OsobaFizyczna']/*[local-name()='NIP']"/>
										<br/>
									</xsl:if>
									<xsl:if test="*[local-name()='OsobaFizyczna']/*[local-name()='PESEL']">
										<xsl:value-of select="*[local-name()='OsobaFizyczna']/*[local-name()='PESEL']"/>
										<br/>
									</xsl:if>
								</xsl:if>
								<font style="font-size: 0.8em; font-weight: normal">
									Dokument wygenerowany elektronicznie
									<br/>
									w e-Urzędzie Skarbowym
								</font>
							</td>
						</tr>
					</table>
				</xsl:for-each>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
	<xsl:template name="Zalaczniki">
		<div class="lewanaglowekczerwony">
			<b>Załączniki</b>
		</div>
		<br/>
		<table class="break-word">
			<xsl:for-each select="*[local-name()='InfOKopiiDokumentu']">
				<tr>
					<td>
						<xsl:text>- </xsl:text>
						<xsl:value-of select="*[local-name()='NazwaPliku']"/>
					</td>
				</tr>
			</xsl:for-each>
		</table>
	</xsl:template>
	<xsl:template name="OsobaFizyczna">
		<div class="wielkielitery">
			<xsl:value-of select="*[local-name()='ImiePierwsze']"/>
			 
			<xsl:value-of select="*[local-name()='Nazwisko']"/>
		</div>
		<xsl:if test="*[local-name()='NIP']">
			<xsl:text>NIP: </xsl:text>
			<xsl:value-of select="*[local-name()='NIP']"/>
			<br/>
		</xsl:if>
		<xsl:if test="*[local-name()='PESEL']">
			<xsl:text>PESEL: </xsl:text>
			<xsl:value-of select="*[local-name()='PESEL']"/>
			<br/>
		</xsl:if>
	</xsl:template>
	<xsl:template name="OsobaNiefizyczna">
		<xsl:for-each select="*[local-name()='OsobaNiefizyczna']">
			<xsl:value-of select="*[local-name()='PelnaNazwa']"/>
			<br/>
			<xsl:text>NIP: </xsl:text>
			<xsl:value-of select="*[local-name()='NIP']"/>
			<br/>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="AdresPol">
		<xsl:for-each select="*[local-name()='AdresZamieszkaniaSiedziby']/*[local-name()='AdresPol']">
			<xsl:if test="*[local-name()='Ulica']">
				ul. <xsl:value-of select="*[local-name()='Ulica']"/> 
			</xsl:if>
			<xsl:value-of select="*[local-name()='NrDomu']"/>
			<xsl:if test="*[local-name()='NrLokalu']"> / <xsl:value-of select="*[local-name()='NrLokalu']"/>
			</xsl:if>
			<br/>
			<xsl:value-of select="*[local-name()='KodPocztowy']"/>
			<xsl:text>, </xsl:text>
			<xsl:value-of select="*[local-name()='Miejscowosc']"/>
			<br/>
			<xsl:if test="*[local-name()='KodKraju'] = 'PL'">
				POLSKA
			</xsl:if>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="AdresZagr">
		<xsl:for-each select="*[local-name()='AdresZamieszkaniaSiedziby']/*[local-name()='AdresZagr']">
			<xsl:if test="*[local-name()='Ulica'] or *[local-name()='NrDomu'] or *[local-name()='NrLokalu']">
				<xsl:if test="*[local-name()='Ulica']">
					<xsl:value-of select="*[local-name()='Ulica']"/> 
				</xsl:if>
				<xsl:if test="*[local-name()='NrDomu']">
					<xsl:value-of select="*[local-name()='NrDomu']"/>
				</xsl:if>
				<xsl:if test="*[local-name()='NrLokalu']">
					 / <xsl:value-of select="*[local-name()='NrLokalu']"/>
				</xsl:if>
				<br/>
			</xsl:if>
			<xsl:if test="*[local-name()='KodPocztowy']">
				<xsl:value-of select="*[local-name()='KodPocztowy']"/><xsl:text>, </xsl:text>
			</xsl:if>
			<xsl:value-of select="*[local-name()='Miejscowosc']"/>
			<br/>
			<xsl:apply-templates select="*[local-name()='KodKraju']"/>
			<br/>
		</xsl:for-each>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']">
		<xsl:if test="$nazwy-dla-kodow">
			<span class="nazwa-dla-kodu1">
				<xsl:call-template name="ZnajdzWEnumeracji">
					<xsl:with-param name="schema" select="$schema-naczelnikow-urzedow"/>
					<xsl:with-param name="typ" select="'TKodNaczUS'"/>
					<xsl:with-param name="kod" select="text()"/>
				</xsl:call-template>
			</span>
		</xsl:if>
	</xsl:template>
</xsl:stylesheet>