14164
| ID | 14164 |
|---|
| Data | 2026-02-17 |
|---|
| Symbol | 2026/02/17/14164 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | FA_RR USTRUKTURYZOWANA FAKTURA VAT RR/VAT RR KOREKTA |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
| URI://Dziennik_Ustaw/2025/1703/16b/1 | Art. 16b ust. 1 ustawy z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (Dz. U. z 2025 r. poz. 1703) |
|---|
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tns="http://crd.gov.pl/wzor/2026/02/17/14164/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/01/07/eD/DefinicjeSzablony/WspolneSzablonyWizualizacji_v12-0E.xsl"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:template name="TytulDokumentu">
e-FAKTURA KSeF FA_RR
</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">
.tlo-formularza { background-color:#D3D3D3; }
table.wrapping, .break-word {
white-space: normal !important;
word-wrap: break-word;
}
table {
width:100%;
}
.word-break {
width:100%;
word-break: break-all;
}
.tlo-zalacznika {
background-color: #D3D3D3;
}
.lewa { border: 1px solid black; font-size: 1.2em; padding: 1px; vertical-align: top; text-align: left;}
.srodek { border: 1px solid black; font-size: 1.2em; padding: 1px; vertical-align: top; text-align: center;}
.prawa { border: 1px solid black; font-size: 1.2em; padding: 1px; vertical-align: top; text-align: right;}
</style>
</xsl:template>
<xsl:template match="tns:Faktura">
<div class="deklaracja">
<div class="naglowek">
<table>
<tr>
<td colspan="2">
<span class="kod-formularza">
<xsl:value-of select="tns:Naglowek/tns:KodFormularza"/>
</span>
<xsl:text> </xsl:text>
<span class="wariant">(<xsl:value-of select="tns:Naglowek/tns:WariantFormularza"/>)</span>
</td>
</tr>
<tr>
<td class="etykieta">Kod systemowy <b>
<xsl:value-of select="tns:Naglowek/tns:KodFormularza/@kodSystemowy"/>
</b>
</td>
</tr>
</table>
</div>
<xsl:call-template name="NaglowekTytulowyKSeF"/>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa">
<xsl:choose>
<xsl:when test="tns:FakturaRR/tns:RodzajFaktury = 'VAT_RR'">
<xsl:text>Faktura pierwotna</xsl:text>
</xsl:when>
<xsl:when test="tns:FakturaRR/tns:RodzajFaktury = 'KOR_VAT_RR'">
<xsl:text>Faktura korygująca</xsl:text>
</xsl:when>
</xsl:choose>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="NrFaktury"/>
<xsl:call-template name="DostawcaNabywca"/>
<xsl:call-template name="InnyPodmiot"/>
<xsl:call-template name="FakturaRR"/>
<xsl:call-template name="StawkaVAT"/>
<xsl:call-template name="FakturaKorygowana"/>
<xsl:if test="tns:FakturaRR/tns:DokumentZaplaty">
<xsl:call-template name="DokumentZaplaty"/>
</xsl:if>
<xsl:if test="tns:FakturaRR/tns:DodatkowyOpis">
<xsl:call-template name="DodatkowyOpis"/>
</xsl:if>
<xsl:if test="tns:FakturaRR/tns:Rozliczenie">
<xsl:call-template name="Rozliczenie"/>
</xsl:if>
<xsl:if test="tns:FakturaRR/tns:Platnosc">
<xsl:call-template name="Platnosc"/>
</xsl:if>
<xsl:call-template name="Stopka"/>
<xsl:call-template name="SystemTeleinfor"/>
</div>
</xsl:template>
<xsl:template name="NaglowekTytulowyKSeF">
<div style="text-align:left">
<b>Krajowy System <font style="color:red">e</font>-Faktur (KS<font style="color:red">e</font>F)</b>
</div>
</xsl:template>
<xsl:template name="SystemTeleinfor">
<br/>
<td class="niewypelnianeopisy">Data i czas wytworzenia faktury: </td>
<td class="wypelniane">
<b>
<xsl:value-of select="tns:Naglowek/tns:DataWytworzeniaFa"/>
</b>
</td>
<br/>
<xsl:if test="tns:Naglowek/tns:SystemInfo">
<table class="break-word">
<tr>
<td>Nazwa systemu teleinformatycznego, z którego korzysta podatnik:
<b>
<xsl:value-of select="tns:Naglowek/tns:SystemInfo"/>
</b>
</td>
</tr>
</table>
</xsl:if>
</xsl:template>
<xsl:template name="NrFaktury">
<table class="break-word" width="100%">
<tr>
<td>
Kod waluty (ISO 4217):
<b>
<xsl:value-of select="tns:FakturaRR/tns:KodWaluty"/>
</b>
</td>
</tr>
<xsl:if test="tns:FakturaRR/tns:P_1M">
<tr>
<td>Miejsce wystawienia faktury:
<b>
<xsl:value-of select="tns:FakturaRR/tns:P_1M"/>
</b>
</td>
</tr>
</xsl:if>
<tr>
<td>
<xsl:if test="tns:FakturaRR/tns:P_4A">
Data dokonania nabycia:
<b>
<xsl:value-of select="tns:FakturaRR/tns:P_4A"/>
</b>
</xsl:if>
</td>
</tr>
<tr>
<td>
<xsl:text>Data wystawienia faktury: </xsl:text>
<b>
<xsl:value-of select="tns:FakturaRR/tns:P_4B"/>
</b>
<br/>
<xsl:text> Kolejny numer faktury: </xsl:text>
<b>
<xsl:value-of select="tns:FakturaRR/tns:P_4C"/>
</b>
</td>
</tr>
<xsl:if test="tns:FakturaRR/tns:FP = '1'">
<tr>
<td>Faktura, o której mowa w art. 109 ust. 3d ustawy:
<input type="checkbox" checked="checked" disabled="disabled"/>
<b>1. Tak</b>
</td>
</tr>
</xsl:if>
<xsl:if test="tns:FakturaRR/tns:TP = '1'">
<tr>
<td>Istniejące powiązania między nabywcą a dokonującym dostawy towarów lub usługodawcą, zgodnie z § 10 ust. 4 pkt 3, z zastrzeżeniem ust. 4b rozporządzenia w sprawie szczegółowego zakresu danych zawartych w deklaracjach podatkowych i w ewidencji w zakresie podatku od towarów i usług:
<input type="checkbox" checked="checked" disabled="disabled"/>
<b>1. Tak</b>
</td>
</tr>
</xsl:if>
<br/>
<br/>
</table>
</xsl:template>
<xsl:template name="DostawcaNabywca">
<br/>
<table class="break-word">
<tr>
<td style="width:50%">
<b>DOSTAWCA</b>
</td>
<td style="width:50%">
<b>NABYWCA</b>
<br/>
<br/>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:text>NIP: </xsl:text>
<b>
<xsl:value-of select="tns:Podmiot1/tns:DaneIdentyfikacyjne/tns:NIP"/>
</b>
<br/>
</td>
<td style="width:50%">
<xsl:text>NIP: </xsl:text>
<b>
<xsl:value-of select="tns:Podmiot2/tns:DaneIdentyfikacyjne/tns:NIP"/>
</b>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:text>Imię i nazwisko lub nazwa albo nazwa skrócona: </xsl:text>
<xsl:value-of select="tns:Podmiot1/tns:DaneIdentyfikacyjne/tns:Nazwa"/>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:DaneIdentyfikacyjne/tns:Nazwa">
<xsl:text>Imię i nazwisko lub nazwa albo nazwa skrócona: </xsl:text>
<xsl:value-of select="tns:Podmiot2/tns:DaneIdentyfikacyjne/tns:Nazwa"/>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%">
<b>Adres dostawcy</b>
</td>
<td style="width:50%">
<b>Adres nabywcy</b>
</td>
<td/>
</tr>
<tr>
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:Adres/tns:KodKraju"/>
</td>
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:Adres/tns:KodKraju"/>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:Adres/tns:AdresL1"/>
<xsl:if test="tns:Podmiot1/tns:Adres/tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:Adres/tns:AdresL2"/>
</xsl:if>
</td>
<td style="width:50%">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:Adres/tns:AdresL1"/>
<xsl:if test="tns:Podmiot2/tns:Adres/tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:Adres/tns:AdresL2"/>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:Adres/tns:GLN">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:Podmiot1/tns:Adres/tns:GLN"/>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:Adres/tns:GLN">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:Podmiot2/tns:Adres/tns:GLN"/>
</xsl:if>
</td>
</tr>
<tr>
<xsl:if test="tns:Podmiot1/tns:AdresKoresp/tns:KodKraju|tns:Podmiot1/tns:AdresKoresp/tns:AdresL1">
<td style="width:50%">
<b>Adres korespondencyjny dostawcy</b>
</td>
</xsl:if>
<xsl:if test="tns:Podmiot2/tns:AdresKoresp/tns:KodKraju|tns:Podmiot2/tns:AdresKoresp/tns:AdresL1">
<td style="width:50%">
<b>Adres korespondencyjny nabywcy</b>
</td>
</xsl:if>
</tr>
<tr>
<xsl:if test="tns:Podmiot1/tns:AdresKoresp/tns:KodKraju">
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:AdresKoresp/tns:KodKraju"/>
</td>
</xsl:if>
<xsl:if test="tns:Podmiot2/tns:AdresKoresp/tns:KodKraju">
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:AdresKoresp/tns:KodKraju"/>
</td>
</xsl:if>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:AdresKoresp/tns:AdresL1">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:AdresKoresp/tns:AdresL1"/>
<xsl:if test="tns:Podmiot1/tns:AdresKoresp/tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:Podmiot1/tns:AdresKoresp/tns:AdresL2"/>
</xsl:if>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:AdresKoresp/tns:AdresL1">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:AdresKoresp/tns:AdresL1"/>
<xsl:if test="tns:Podmiot2/tns:AdresKoresp/tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:Podmiot2/tns:AdresKoresp/tns:AdresL2"/>
</xsl:if>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:AdresKoresp/tns:GLN">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:Podmiot1/tns:AdresKoresp/tns:GLN"/>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:AdresKoresp/tns:GLN">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:Podmiot2/tns:AdresKoresp/tns:GLN"/>
</xsl:if>
</td>
</tr>
<tr>
<xsl:if test="tns:Podmiot1/tns:DaneKontaktowe">
<td style="width:50%">
<b>Dane kontaktowe dostawcy</b>
</td>
</xsl:if>
<xsl:if test="tns:Podmiot2/tns:DaneKontaktowe">
<td style="width:50%">
<b>Dane kontaktowe nabywcy</b>
</td>
</xsl:if>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:DaneKontaktowe/tns:Email">
<xsl:text>Adres e-mail: </xsl:text>
<xsl:for-each select="tns:Podmiot1/tns:DaneKontaktowe/tns:Email">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:DaneKontaktowe/tns:Email">
<xsl:text>Adres e-mail: </xsl:text>
<xsl:for-each select="tns:Podmiot2/tns:DaneKontaktowe/tns:Email">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:DaneKontaktowe/tns:Telefon">
<xsl:text>Numer telefonu: </xsl:text>
<xsl:for-each select="tns:Podmiot1/tns:DaneKontaktowe/tns:Telefon">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:DaneKontaktowe/tns:Telefon">
<xsl:text>Numer telefonu: </xsl:text>
<xsl:for-each select="tns:Podmiot2/tns:DaneKontaktowe/tns:Telefon">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%">
<xsl:if test="tns:Podmiot1/tns:NrKontrahenta">
<br/>
<xsl:text>Numer kontrahenta dla przypadków, w których dostawca posługuje się nim w umowie lub zamówieniu: </xsl:text>
<xsl:value-of select="tns:Podmiot1/tns:NrKontrahenta"/>
</xsl:if>
</td>
<td style="width:50%">
<xsl:if test="tns:Podmiot2/tns:StatusInfoPodatnika">
<br/>
<xsl:text>Status podatnika: </xsl:text>
<xsl:for-each select="tns:Podmiot2">
<xsl:choose>
<xsl:when test="tns:StatusInfoPodatnika = 1">
<xsl:text>Podatnik znajdujący się w stanie likwidacji</xsl:text>
</xsl:when>
<xsl:when test="tns:StatusInfoPodatnika = 2">
<xsl:text>Podatnik, który jest w trakcie postępowania restrukturyzacyjnego</xsl:text>
</xsl:when>
<xsl:when test="tns:StatusInfoPodatnika = 3">
<xsl:text>Podatnik znajdujący się w stanie upadłości</xsl:text>
</xsl:when>
<xsl:when test="tns:StatusInfoPodatnika = 4">
<xsl:text>Przedsiębiorstwo w spadku</xsl:text>
</xsl:when>
</xsl:choose>
</xsl:for-each>
</xsl:if>
</td>
</tr>
</table>
<br/>
</xsl:template>
<xsl:template name="InnyPodmiot">
<xsl:if test="tns:Podmiot3">
<xsl:for-each select="tns:Podmiot3">
<table class="break-word">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>Podmiot trzeci <xsl:number value="position()" format="(1) "/>
</b>
</td>
</tr>
<xsl:for-each select="tns:DaneIdentyfikacyjne">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:if test="tns:NIP">
<xsl:text>NIP: </xsl:text>
<xsl:value-of select="tns:NIP"/>
</xsl:if>
<xsl:if test="tns:IDWew">
<xsl:text>Identyfikator wewnętrzny z NIP: </xsl:text>
<xsl:value-of select="tns:IDWew"/>
</xsl:if>
<xsl:if test="tns:BrakID = '1'">
<xsl:text>Podmiot nie posiada identyfikatora podatkowego: </xsl:text>
<input type="checkbox" checked="checked" disabled="disabled"/>
<b>1. Tak</b>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:if test="tns:Nazwa">
<xsl:text>Imię i nazwisko lub nazwa albo nazwa skrócona podmiotu trzeciego: </xsl:text>
<xsl:value-of select="tns:Nazwa"/>
</xsl:if>
</td>
</tr>
</xsl:for-each>
<xsl:if test="tns:Adres">
<xsl:for-each select="tns:Adres">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>Adres podmiotu trzeciego</b>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:KodKraju"/>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:AdresL1"/>
<xsl:if test="tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:AdresL2"/>
</xsl:if>
</td>
</tr>
<xsl:if test="tns:GLN">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:GLN"/>
</td>
</tr>
</xsl:if>
</xsl:for-each>
</xsl:if>
<xsl:if test="tns:AdresKoresp">
<xsl:for-each select="tns:AdresKoresp">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>Adres korespondencyjny podmiotu trzeciego</b>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>Kod kraju: </xsl:text>
<xsl:apply-templates select="tns:KodKraju"/>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>Adres: </xsl:text>
<xsl:apply-templates select="tns:AdresL1"/>
<xsl:if test="tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:AdresL2"/>
</xsl:if>
</td>
</tr>
<xsl:if test="tns:GLN">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:text>GLN: </xsl:text>
<xsl:value-of select="tns:GLN"/>
</td>
</tr>
</xsl:if>
</xsl:for-each>
</xsl:if>
<xsl:if test="tns:DaneKontaktowe">
<tr>
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>Dane kontaktowe podmiotu trzeciego</b>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:if test="tns:DaneKontaktowe/tns:Email">
<xsl:text>Adres e-mail: </xsl:text>
<xsl:for-each select="tns:DaneKontaktowe/tns:Email">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
</tr>
<tr>
<td style="width:50%"/>
<td style="width:50%">
<xsl:if test="tns:DaneKontaktowe/tns:Telefon">
<xsl:text>Numer telefonu: </xsl:text>
<xsl:for-each select="tns:DaneKontaktowe/tns:Telefon">
<xsl:value-of select="."/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:if>
</td>
</tr>
</xsl:if>
<tr>
<xsl:if test="tns:Rola">
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>
<xsl:text>Rola</xsl:text>
</b>
<br/>
<xsl:choose>
<xsl:when test="tns:Rola = '1'">
<xsl:text>Faktor - w przypadku, gdy na fakturze występują dane faktora</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '2'">
<xsl:text>Odbiorca - w przypadku, gdy na fakturze występują dane jednostek wewnętrznych, w tym oddziałów wyodrębnionych w ramach nabywcy, które same nie stanowią nabywcy w rozumieniu ustawy</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '3'">
<xsl:text>Podmiot pierwotny - w przypadku, gdy na fakturze występują dane podmiotu będącego w stosunku do nabywcy podmiotem przejętym lub przekształconym, który nabywał produkty rolne lub usługę rolniczą. Z wyłączeniem przypadków, o których mowa w art. 116 ust. 5e pkt 3 ustawy, gdy dane te wykazywane są w sekcji Podmiot2K</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '5'">
<xsl:text>Wystawca faktury - w przypadku, gdy na fakturze występują dane podmiotu wystawiającego fakturę w imieniu nabywcy</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '6'">
<xsl:text>Dokonujący płatności - w przypadku, gdy na fakturze występują dane podmiotu regulującego zobowiązanie w miejsce nabywcy</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '7'">
<xsl:text>Jednostka samorządu terytorialnego - wystawca</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '8'">
<xsl:text>Jednostka samorządu terytorialnego - odbiorca</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '9'">
<xsl:text>Członek grupy VAT - wystawca</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '10'">
<xsl:text>Członek grupy VAT - odbiorca</xsl:text>
</xsl:when>
<xsl:when test="tns:Rola = '11'">
<xsl:text>Pracownik</xsl:text>
</xsl:when>
</xsl:choose>
</td>
</xsl:if>
<xsl:if test="tns:RolaInna">
<td style="width:50%"/>
<td style="width:50%">
<br/>
<b>
<xsl:text>Rola</xsl:text>
</b>
<br/>
<xsl:choose>
<xsl:when test="tns:RolaInna = '1'">
<xsl:text>Rola inna: </xsl:text>
<xsl:value-of select="tns:OpisRoli"/>
<br/>
</xsl:when>
</xsl:choose>
</td>
</xsl:if>
</tr>
</table>
</xsl:for-each>
</xsl:if>
</xsl:template>
<xsl:template name="StawkaVAT">
<xsl:for-each select="tns:FakturaRR">
<b>Podsumowanie wg stawki zryczałtowanego zwrotu 7%</b>
<br/>
<br/>
<table class="break-word" width="100%">
<tr>
<td class="niewypelniane" width="25%">Wartość nabytych produktów rolnych lub wykonanych usług rolniczych. W przypadku faktur korygujących - kwota różnicy, o której mowa w art. 116 ust. 5e pkt 5 ustawy</td>
<td class="niewypelniane" width="25%">Wartość nabytych produktów rolnych lub wykonanych usług rolniczych, przeliczona zgodnie z art. 116 ust. 2b i 2c ustawy. W przypadku faktur korygujących - kwota różnicy, o której mowa w art. 116 ust. 5e pkt 5 ustawy</td>
<td class="niewypelniane" width="25%">Kwota zryczałtowanego zwrotu podatku. W przypadku faktur korygujących - kwota różnicy, o której mowa w art. 116 ust. 5e pkt 5 ustawy</td>
<td class="niewypelniane" width="25%">Kwota zryczałtowanego zwrotu podatku, przeliczona zgodnie z art. 116 ust. 2b i 2c ustawy. W przypadku faktur korygujących - kwota różnicy, o której mowa w art. 116 ust. 5e pkt 5 ustawy</td>
</tr>
<tr>
<td class="prawa" width="25%">
<xsl:value-of select="tns:P_11_1"/>
</td>
<td class="prawa" width="25%">
<xsl:value-of select="tns:P_11_1W"/>
</td>
<td class="prawa" width="25%">
<xsl:value-of select="tns:P_11_2"/>
</td>
<td class="prawa" width="25%">
<xsl:value-of select="tns:P_11_2W"/>
</td>
</tr>
</table>
<br/>
<table class="break-word" width="100%">
<tr>
<td>
Kwota należności ogółem wyrażona cyfrowo, a w przypadku faktur korygujących – kwota różnicy kwoty należności ogółem z kwotą zryczałtowanego zwrotu podatku:
<b>
<xsl:value-of select="tns:P_12_1"/>
</b>
</td>
</tr>
<tr>
<td>
Kwota należności ogółem przeliczona zgodnie z art. 116 ust. 2a ustawy, a w przypadku faktur korygujących – kwota różnicy kwoty należności ogółem z kwotą zryczałtowanego zwrotu:
<b>
<xsl:value-of select="tns:P_12_1W"/>
</b>
</td>
</tr>
<tr>
<td>
Kwota należności ogółem wyrażona słownie, a w przypadku faktur korygujących – kwota różnicy kwoty należności ogółem z kwotą zryczałtowanego zwrotu podatku:
<b>
<xsl:value-of select="tns:P_12_2"/>
</b>
</td>
</tr>
</table>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="FakturaRR">
<br/>
<xsl:if test="tns:FakturaRR/tns:FakturaRRWiersz">
<table class="white-space">
<tr>
<td class="niewypelniane">Numer wiersza faktury</td>
<td class="niewypelniane">Uniwersalny unikalny numer wiersza faktury</td>
<td class="niewypelniane">Data dokonania nabycia. Pole wypełnia się w przypadku, gdy dla poszczególnych pozycji faktury występują różne daty</td>
<td class="niewypelniane">Nazwa nabytego produktu rolnego lub nabytej usługi rolniczej</td>
<td class="niewypelniane">Globalny numer jednostki handlowej</td>
<td class="niewypelniane">Symbol Polskiej Klasyfikacji Wyrobów i Usług</td>
<td class="niewypelniane">Symbol Nomenklatury Scalonej</td>
<td class="niewypelniane">Jednostka miary nabytego produktu rolnego lub nabytej usługi rolniczej</td>
<td class="niewypelniane">Ilość nabytego produktu rolnego lub nabytej usługi rolniczej</td>
<td class="niewypelniane">Oznaczenie (opis) klasy lub jakości tego produktu lub nabytej usługi rolniczej</td>
<td class="niewypelniane">Cena jednostkowa nabytego produktu rolnego lub nabytej usługi rolniczej bez kwoty zryczałtowanego zwrotu podatku</td>
<td class="niewypelniane">Wartość nabytego produktu rolnego lub nabytej usługi rolniczej bez kwoty zryczałtowanego zwrotu podatku</td>
<td class="niewypelniane">Stawka zryczałtowanego zwrotu podatku</td>
<td class="niewypelniane">Kwota zryczałtowanego zwrotu podatku od wartości nabytego produktu rolnego lub nabytej usługi rolniczej</td>
<td class="niewypelniane">Wartość nabytego produktu rolnego lub nabytej usługi rolniczej wraz z kwotą zryczałtowanego zwrotu podatku</td>
<td class="niewypelniane">Znacznik stanu przed korektą w przypadku faktury korygującej, gdy korekta dotyczy danych wykazanych w pozycjach faktury i wystawiana jest w sposób polegający na wykazaniu danych przed korektą i po korekcie jako osobnych wierszy z odrębną numeracją oraz w przypadku potwierdzania braku zmiany wartości danej pozycji</td>
<td class="niewypelniane">Kurs waluty stosowany do wyliczenia zwrotu podatku w przypadkach, o których mowa w art. 116 ust. 2b ustawy</td>
</tr>
<xsl:for-each select="tns:FakturaRR/tns:FakturaRRWiersz">
<tr>
<td class="srodek" width="auto">
<xsl:value-of select="tns:NrWierszaFa"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:UU_ID"/>
</td>
<td class="srodek" width="auto">
<xsl:value-of select="tns:P_4AA"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:P_5"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:GTIN"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:PKWiU"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:CN"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:P_6A"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_6B"/>
</td>
<td class="lewa" width="auto">
<xsl:value-of select="tns:P_6C"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_7"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_8"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_9"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_10"/>
</td>
<td class="prawa" width="auto">
<xsl:value-of select="tns:P_11"/>
</td>
<td class="prawa">
<xsl:value-of select="tns:StanPrzed"/>
</td>
<td class="prawa">
<xsl:value-of select="tns:KursWaluty"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:if>
<br/>
</xsl:template>
<xsl:template name="FakturaKorygowana">
<xsl:for-each select="tns:FakturaRR">
<b>Korekta</b>
<br/>
<br/>
<xsl:if test="tns:PrzyczynaKorekty">
<table class="break-word" width="100%">
<tr>
<td class="niewypelniane" width="25%">Przyczyna korekty dla faktur korygujących</td>
<td class="wypelniane" width="75%">
<xsl:value-of select="tns:PrzyczynaKorekty"/>
</td>
</tr>
</table>
<br/>
</xsl:if>
<xsl:if test="tns:TypKorekty">
<table width="100%">
<tr>
<td class="niewypelniane" width="25%">Typ skutku korekty w ewidencji</td>
<td class="wypelniane" width="75%">
<xsl:choose>
<xsl:when test="tns:TypKorekty = '1'">
Korekta skutkująca w dacie ujęcia faktury pierwotnej
</xsl:when>
<xsl:when test="tns:TypKorekty = '2'">
Korekta skutkująca w dacie wystawienia faktury korygującej
</xsl:when>
<xsl:when test="tns:TypKorekty = '3'">
Korekta skutkująca w dacie innej
</xsl:when>
<xsl:when test="tns:TypKorekty = '4'">
Korekta skutkująca w dacie dokonania zwrotu całości lub części należności
</xsl:when>
</xsl:choose>
</td>
</tr>
</table>
<br/>
</xsl:if>
<table class="break-word">
<tr>
<td class="niewypelniane" width="10%">Znacznik faktury korygowanej</td>
<td class="niewypelniane" width="10%">Data wystawienia faktury korygowanej</td>
<td class="niewypelniane" width="50%">Numer faktury korygowanej</td>
<td class="niewypelniane" width="30%">Numer identyfikujący fakturę korygowaną w KSeF</td>
</tr>
<xsl:for-each select="tns:DaneFaKorygowanej">
<tr>
<td class="wypelniane, srodek" width="10%">
<xsl:if test="tns:NrKSeF = '1'">
<i>
<xsl:text>KSeF</xsl:text>
</i>
</xsl:if>
<xsl:if test="tns:NrKSeFN = '1'">
<i>
<xsl:text>poza KSeF</xsl:text>
</i>
</xsl:if>
</td>
<td class="srodek" width="10%">
<xsl:value-of select="tns:DataWystFaKorygowanej"/>
</td>
<td class="wypelniane" width="50%">
<xsl:value-of select="tns:NrFaKorygowanej"/>
</td>
<td class="wypelniane, prawa" width="30%">
<xsl:value-of select="tns:NrKSeFFaKorygowanej"/>
</td>
</tr>
</xsl:for-each>
</table>
<br/>
<xsl:if test="tns:NrFaKorygowany">
<table class="break-word">
<tr>
<td class="niewypelniane" width="25%">Poprawny numer faktury korygowanej w przypadku, gdy przyczyną korekty jest błędny numer faktury korygowanej</td>
<td class="wypelniane" width="75%">
<xsl:value-of select="tns:NrFaKorygowany"/>
</td>
</tr>
</table>
<br/>
</xsl:if>
<xsl:if test="tns:Podmiot1K">
<xsl:for-each select="tns:Podmiot1K">
<table class="break-word">
<tr>
<td class="niewypelniane" colspan="2">Dane i adres dostawcy występujące w fakturze korygowanej</td>
</tr>
<tr>
<td class="niewypelniane" width="10%">Identyfikator podatkowy NIP</td>
<td class="niewypelniane" width="90%">Imię i nazwisko lub nazwa albo nazwa skrócona</td>
</tr>
<tr>
<td class="srodek" width="10%">
<xsl:value-of select="tns:DaneIdentyfikacyjne/tns:NIP"/>
</td>
<td class="lewa" width="90%">
<xsl:value-of select="tns:DaneIdentyfikacyjne/tns:Nazwa"/>
</td>
</tr>
</table>
<xsl:for-each select="tns:Adres">
<table class="break-word">
<tr>
<td class="niewypelniane" width="10%">Kod kraju</td>
<td class="niewypelniane" width="80%">Adres</td>
<td class="niewypelniane" width="10%">GLN</td>
</tr>
<tr>
<td class="srodek" style="width:10%">
<xsl:apply-templates select="tns:KodKraju"/>
</td>
<td class="lewa" style="width:80%">
<xsl:apply-templates select="tns:AdresL1"/>
<xsl:if test="tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:AdresL2"/>
</xsl:if>
</td>
<td class="srodek" style="width:10%">
<xsl:if test="tns:GLN">
<xsl:value-of select="tns:GLN"/>
</xsl:if>
</td>
</tr>
</table>
<br/>
</xsl:for-each>
</xsl:for-each>
</xsl:if>
<xsl:if test="tns:Podmiot2K">
<xsl:for-each select="tns:Podmiot2K">
<table class="break-word">
<tr>
<td class="niewypelniane" colspan="6">Dane i adres nabywcy występujące na fakturze korygowanej</td>
</tr>
<tr>
<td class="niewypelniane" width="10%">Identyfikator podatkowy NIP</td>
<td class="niewypelniane" width="90%">Imię i nazwisko lub nazwa albo nazwa skrócona</td>
</tr>
<tr>
<td class="srodek" width="10%">
<xsl:value-of select="tns:DaneIdentyfikacyjne/tns:NIP"/>
</td>
<td class="srodek" width="90%">
<xsl:value-of select="tns:DaneIdentyfikacyjne/tns:Nazwa"/>
</td>
</tr>
</table>
<xsl:for-each select="tns:Adres">
<table class="break-word">
<tr>
<td class="niewypelniane" width="10%">Kod kraju</td>
<td class="niewypelniane" width="80%">Adres</td>
<td class="niewypelniane" width="10%">GLN</td>
</tr>
<tr>
<td class="srodek" style="width:10%">
<xsl:apply-templates select="tns:KodKraju"/>
</td>
<td class="lewa" style="width:80%">
<xsl:apply-templates select="tns:AdresL1"/>
<xsl:if test="tns:AdresL2">
<xsl:text> </xsl:text>
<xsl:apply-templates select="tns:AdresL2"/>
</xsl:if>
</td>
<td class="srodek" style="width:10%">
<xsl:if test="tns:GLN">
<xsl:value-of select="tns:GLN"/>
</xsl:if>
</td>
</tr>
</table>
<br/>
</xsl:for-each>
<xsl:if test="tns:IDNabywcy">
<div>
Unikalny klucz powiązania danych nabywcy na fakturach korygujących, w przypadku gdy dane nabywcy na fakturze korygującej zmieniły się w stosunku do danych na fakturze korygowanej:
<b>
<xsl:value-of select="tns:IDNabywcy"/>
</b>
</div>
<br/>
</xsl:if>
</xsl:for-each>
</xsl:if>
</xsl:for-each>
</xsl:template>
<xsl:template name="DokumentZaplaty">
<b>Dane dokumentu/-ów zapłaty</b>
<br/>
<br/>
<xsl:for-each select="tns:FakturaRR">
<table class="break-word">
<tr>
<td class="niewypelniane" width="85%">Dane identyfikacyjne dokumentu, o którym mowa w art. 116 ust. 6 pkt 3 ustawy, lub dokumentu potwierdzającego dokonanie zapłaty zaliczki, o którym mowa w art. 116 ust. 9 pkt 1 i ust. 9b ustawy</td>
<td class="niewypelniane" width="15%">Data dokumentu potwierdzającego dokonanie zapłaty lub zapłaty zaliczki</td>
</tr>
<xsl:for-each select="tns:DokumentZaplaty">
<tr>
<td class="lewa" width="85%">
<xsl:value-of select="tns:NrDokumentu"/>
</td>
<td class="srodek" width="15%">
<xsl:value-of select="tns:DataDokumentu"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
<br/>
</xsl:template>
<xsl:template name="DodatkowyOpis">
<table>
<b>Dodatkowy opis</b>
</table>
<br/>
<table class="break-word" width="100%">
<tr>
<td class="niewypelniane" colspan="3">Pola przeznaczone dla wykazywania dodatkowych danych na fakturze, w tym wymaganych przepisami prawa, dla których nie przewidziano innych pól/elementów</td>
</tr>
<tr>
<td class="niewypelniane" width="20%">Numer wiersza podany w polu NrWierszaFa, jeśli informacja odnosi się wyłącznie do danej pozycji faktury</td>
<td class="niewypelniane" width="40%">Klucz</td>
<td class="niewypelniane" width="40%">Wartość</td>
</tr>
<xsl:for-each select="tns:FakturaRR/tns:DodatkowyOpis">
<tr>
<td class="srodek" width="20%">
<xsl:value-of select="tns:NrWiersza"/>
</td>
<td class="lewa" width="40%">
<xsl:value-of select="tns:Klucz"/>
</td>
<td class="lewa" width="40%">
<xsl:value-of select="tns:Wartosc"/>
</td>
</tr>
</xsl:for-each>
</table>
<br/>
</xsl:template>
<xsl:template name="Rozliczenie">
<xsl:for-each select="tns:FakturaRR/tns:Rozliczenie">
<b>Dodatkowe rozliczenia na fakturze</b>
<br/>
<br/>
<xsl:if test="tns:Obciazenia">
<table class="break-word">
<tr>
<td class="niewypelniane" colspan="2">Obciążenia</td>
</tr>
<tr>
<td class="niewypelniane" width="80%">Powód obciążenia</td>
<td class="niewypelniane" width="20%">Kwota doliczona do kwoty wykazanej w polu P_12_1</td>
</tr>
<xsl:for-each select="tns:Obciazenia">
<tr>
<td class="wypelniane" width="80%">
<xsl:value-of select="tns:Powod"/>
</td>
<td class="prawa" width="20%">
<xsl:value-of select="tns:Kwota"/>
</td>
</tr>
</xsl:for-each>
<tr>
<td class="niewypelniane" width="20%">Suma obciążeń</td>
<td class="prawa" width="80%">
<xsl:value-of select="tns:SumaObciazen"/>
</td>
</tr>
</table>
<br/>
</xsl:if>
<xsl:if test="tns:Odliczenia">
<table class="break-word">
<tr>
<td class="niewypelniane" colspan="2">Odliczenia</td>
</tr>
<tr>
<td class="niewypelniane" width="80%">Powód odliczenia</td>
<td class="niewypelniane" width="20%">Kwota odliczona od kwoty wykazanej w polu P_12_1</td>
</tr>
<xsl:for-each select="tns:Odliczenia">
<tr>
<td class="wypelniane" width="80%">
<xsl:value-of select="tns:Powod"/>
</td>
<td class="prawa" width="20%">
<xsl:value-of select="tns:Kwota"/>
</td>
</tr>
</xsl:for-each>
<tr>
<td class="niewypelniane" width="20%">Suma odliczeń</td>
<td class="prawa" width="80%">
<xsl:value-of select="tns:SumaOdliczen"/>
</td>
</tr>
</table>
<br/>
<b>Do zapłaty / Do rozliczenia</b>
<br/>
<br/>
<table class="break-word">
<tr>
<xsl:choose>
<xsl:when test="tns:DoZaplaty">
<td class="niewypelniane" width="80%">Kwota należności do zapłaty równa polu P_12_1 powiększonemu o Obciazenia i pomniejszonemu o Odliczenia</td>
<td class="prawa" width="20%">
<xsl:value-of select="tns:DoZaplaty"/>
</td>
</xsl:when>
<xsl:when test="tns:DoRozliczenia">
<td class="niewypelniane" width="80%">Kwota nadpłacona do rozliczenia/zwrotu</td>
<td class="prawa" width="20%">
<xsl:value-of select="tns:DoRozliczenia"/>
</td>
</xsl:when>
</xsl:choose>
</tr>
</table>
</xsl:if>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="Platnosc">
<xsl:for-each select="tns:FakturaRR/tns:Platnosc">
<b>Warunki płatności</b>
<br/>
<br/>
<xsl:if test="tns:FormaPlatnosci='1'">
<table class="break-word" width="100%">
<tr>
<td>
Forma płatności:
<input type="checkbox" checked="checked" disabled="disabled"/>
<b>1. przelew</b>
</td>
</tr>
</table>
</xsl:if>
<xsl:if test="tns:PlatnoscInna='1'">
<table class="break-word" width="100%">
<tr>
<td>
Znacznik innej formy płatności:
<input type="checkbox" checked="checked" disabled="disabled"/>
<b>1 - inna forma płatności</b>
</td>
</tr>
<tr>
<td>
Uszczegółowienie innej formy płatności:
<b>
<xsl:value-of select="tns:OpisPlatnosci"/>
</b>
</td>
</tr>
</table>
</xsl:if>
<xsl:if test="tns:RachunekBankowy1">
<br/>
<b>Numer rachunku rolnika</b>
<br/>
<table class="break-word">
<tr>
<br/>
<td class="niewypelniane" width="20%">Pełny numer rachunku<br/>Kod SWIFT</td>
<td class="niewypelniane" width="40%">Nazwa</td>
<td class="niewypelniane" width="40%">Opis rachunku</td>
</tr>
<xsl:for-each select="tns:RachunekBankowy1">
<tr>
<td class="wypelniane" width="20%">
<xsl:value-of select="tns:NrRB"/>
<br/>
<xsl:if test="tns:SWIFT">
SWIFT:
<xsl:value-of select="tns:SWIFT"/>
</xsl:if>
</td>
<td class="wypelniane" width="40%">
<xsl:value-of select="tns:NazwaBanku"/>
</td>
<td class="wypelniane" width="40%">
<xsl:value-of select="tns:OpisRachunku"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:if>
<xsl:if test="tns:RachunekBankowy2">
<br/>
<b>Numer rachunku nabywcy</b>
<br/>
<table class="break-word">
<tr>
<br/>
<td class="niewypelniane" width="20%">Pełny numer rachunku<br/>Kod SWIFT</td>
<td class="niewypelniane" width="40%">Nazwa</td>
<td class="niewypelniane" width="40%">Opis rachunku</td>
</tr>
<xsl:for-each select="tns:RachunekBankowy2">
<tr>
<td class="wypelniane" width="20%">
<xsl:value-of select="tns:NrRB"/>
<br/>
<xsl:if test="tns:SWIFT">
SWIFT:
<xsl:value-of select="tns:SWIFT"/>
</xsl:if>
</td>
<td class="wypelniane" width="40%">
<xsl:value-of select="tns:NazwaBanku"/>
</td>
<td class="wypelniane" width="40%">
<xsl:value-of select="tns:OpisRachunku"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:if>
<br/>
<xsl:if test="tns:IPKSeF">
<table class="break-word" width="100%">
<tr>
<td>
Identyfikator płatności Krajowego Systemu e-Faktur:
<b>
<xsl:value-of select="tns:IPKSeF"/>
</b>
</td>
</tr>
</table>
<br/>
<xsl:if test="tns:LinkDoPlatnosci">
<table class="break-word" width="100%">
<tr>
<td>
Link do płatności bezgotówkowej:
<b>
<xsl:value-of select="tns:LinkDoPlatnosci"/>
</b>
</td>
</tr>
</table>
</xsl:if>
</xsl:if>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="Stopka">
<xsl:if test="tns:Stopka">
<div>
<b>Pozostałe informacje na fakturze</b>
</div>
<br/>
<xsl:for-each select="tns:Stopka/tns:Informacje">
<table class="break-word">
<tr>
<td>
<xsl:number value="position()" format="1. "/>
<xsl:value-of select="tns:StopkaFaktury"/>
<xsl:text>;</xsl:text>
</td>
</tr>
</table>
<br/>
</xsl:for-each>
<div>
<b>Numery podmiotu lub grupy podmiotów w innych rejestrach i bazach danych</b>
</div>
<br/>
<xsl:for-each select="tns:Stopka/tns:Rejestry">
<table class="break-word">
<tr>
<td class="niewypelniane" colspan="2">
<xsl:number value="position()" format=" (1) "/>
<xsl:value-of select="tns:PelnaNazwa"/>
</td>
</tr>
</table>
<table class="break-word">
<tr>
<td class="niewypelniane" width="10%">KRS</td>
<td class="wypelniane" width="90%">
<xsl:value-of select="tns:KRS"/>
</td>
</tr>
<tr>
<td class="niewypelniane" width="10%">REGON</td>
<td class="wypelniane" width="90%">
<xsl:value-of select="tns:REGON"/>
</td>
</tr>
<tr>
<td class="niewypelniane" width="10%">BDO</td>
<td class="wypelniane" width="90%">
<xsl:value-of select="tns:BDO"/>
</td>
</tr>
</table>
<br/>
</xsl:for-each>
<br/>
<div align="center">
<a href="https://www.gov.pl/web/kas/krajowy-system-e-faktur">
<b>Krajowy System <font style="color:red">e</font>-Faktur</b>
</a>
</div>
<br/>
<br/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>