14065

ID	14065
Data	2025-12-12
Symbol	2025/12/12/14065
Instytucja	Ministerstwo Finansów
Nazwa	ZGL_ZAP ZGŁOSZENIE O ZAMIARZE ZAPRZESTANIA WYSTAWIANIA I PRZESYŁANIA DO KRAJOWEGO SYSTEMU E-FAKTUR FAKTUR Z ZAŁĄCZNIKIEM
Czy Aktualny	1

Ustawy (1)

URI://Dziennik_Ustaw/2025/1703/16b/1	Art. 16b ust. 1 ustawy z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (Dz. U. z 2025 r. poz. 1703)

Pliki

• wyroznik.xml
• styl.xsl
• schemat.xsd

Styl

<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tns="http://crd.gov.pl/wzor/2025/12/12/14065/" version="1.0">
	<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/18/eD/DefinicjeSzablony/Posredni_wspolne_v15-0E.xsl"/>
	<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
	<xsl:template name="TytulDokumentu">Zgłoszenie o zamiarze zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem</xsl:template>
	<xsl:template name="StyleDlaFormularza">
		<style type="text/css">
		 .tlo-formularza { background-color: #d5d5d5; font-size:1.0em; }
		</style>
	</xsl:template>
	<xsl:template match="tns:Zgloszenie">
		<div class="deklaracja">
			<xsl:call-template name="NaglowekTechniczny">
				<xsl:with-param name="naglowek" select="*[local-name()='Naglowek']"/>
				<xsl:with-param name="uzycie" select="'deklaracja'"/>
			</xsl:call-template>
			<xsl:call-template name="NaglowekTytulowy">
				<xsl:with-param name="naglowek" select="tns:Naglowek"/>
				<xsl:with-param name="uzycie" select="'deklaracja'"/>
				<xsl:with-param name="nazwa">
				Zgłoszenie o zamiarze zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem<br/><br/></xsl:with-param>
				<xsl:with-param name="podstawy-prawne">
					<table>
						<tr>
							<td class="etykieta" valign="top">Podstawa prawna:</td>
							<td class="wartosc">Art. 106gba ust. 2 pkt 2 ustawy o podatku od towarów i usług (Dz. U. z 2025 r. poz. 775, z późn. zm.).</td>
						</tr>
						<tr>
							<td class="etykieta" valign="top">Składający:</td>
							<td class="wartosc">Podatnicy podatku od towarów i usług, którzy zamierzają zaprzestać wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem.</td>
						</tr>
						<tr>
							<td class="etykieta" valign="top">Termin składania:</td>
							<td class="wartosc">Przed zaprzestaniem wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem.</td>
						</tr>
						<tr>
							<td class="etykieta" valign="top">Sposób składania:</td>
							<td class="wartosc">Zgłoszenie składa się do Szefa KAS za pośrednictwem konta w e-Urzędzie Skarbowym.</td>
						</tr>
					</table>
				</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="MiejsceZglaszania">
				<xsl:with-param name="sekcja">A.</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="Podmiot1">
				<xsl:with-param name="sekcja">B.</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="Informacja">
				<xsl:with-param name="sekcja">C.</xsl:with-param>
			</xsl:call-template>
			<xsl:call-template name="Oswiadczenie">
				<xsl:with-param name="sekcja">D.</xsl:with-param>
			</xsl:call-template>
		</div>
	</xsl:template>
	<xsl:template name="MiejsceZglaszania">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> MIEJSCE I CEL SKŁADANIA</h2>
		<table class="normalna">
			<tr>
				<td class="wypelniane">
					<div class="opisrubryki">Kod organu</div>
					<xsl:if test="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']='0000'">
						<b>SZEF KRAJOWEJ ADMINISTRACJI SKARBOWEJ</b>
					</xsl:if>
				</td>
			</tr>
			<tr>
				<td class="wypelniane">
					<div class="opisrubryki">Cel złożenia:</div>
					<xsl:choose>
						<xsl:when test="*[local-name()='Naglowek']/*[local-name()='CelZlozenia'] =1">
							<input type="checkbox" checked="checked" disabled="disabled"/>1. złożenie zgłoszenia
							</xsl:when>
					</xsl:choose>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="Podmiot1">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> DANE PODATNIKA
		</h2>
		<xsl:if test="*[local-name()='Podmiot1']/*[local-name()='OsobaFizyczna']">
			<xsl:for-each select="*[local-name()='Podmiot1']/*[local-name()='OsobaFizyczna']">
				<xsl:if test="*[local-name()='NIP'] | *[local-name()='PESEL']">
					<table class="normalna">
						<tr>
							<xsl:if test="*[local-name()='NIP']">
								<td class="wypelniane">
									<div class="opisrubryki">Identyfikator podatkowy NIP</div>
									<xsl:apply-templates select="*[local-name()='NIP']"/>
								</td>
							</xsl:if>
							<xsl:if test="*[local-name()='PESEL']">
								<td class="wypelniane">
									<div class="opisrubryki">Identyfikator podatkowy numer PESEL</div>
									<xsl:apply-templates select="*[local-name()='PESEL']"/>
								</td>
							</xsl:if>
						</tr>
					</table>
				</xsl:if>
				<table class="normalna">
					<tr>
						<xsl:if test="*[local-name()='Nazwisko' ]">
							<td class="wypelniane" style="width:40%">
								<div class="opisrubryki">Nazwisko</div>
								<xsl:apply-templates select="*[local-name() ='Nazwisko']"/>
							</td>
						</xsl:if>
						<xsl:if test="*[local-name()='ImiePierwsze' ]">
							<td class="wypelniane" style="width:40%">
								<div class="opisrubryki">Pierwsze imię</div>
								<xsl:apply-templates select="*[local-name() ='ImiePierwsze']"/>
							</td>
						</xsl:if>
						<xsl:if test="../*[local-name()='Email' ]">
							<td class="wypelniane">
								<div class="opisrubryki">Adres poczty elektronicznej podatnika</div>
								<xsl:value-of select="../*[local-name() = 'Email']"/>
							</td>
						</xsl:if>
					</tr>
				</table>
			</xsl:for-each>
		</xsl:if>
		<xsl:if test="*[local-name()='Podmiot1']//*[local-name()='OsobaNiefizyczna']">
			<xsl:for-each select="*[local-name()='Podmiot1']//*[local-name()='OsobaNiefizyczna']">
				<xsl:if test="*[local-name()='NIP']">
					<table class="normalna">
						<tr>
							<td class="wypelniane">
								<div class="opisrubryki">Identyfikator podatkowy NIP</div>
								<xsl:apply-templates select="*[local-name()='NIP']"/>
							</td>
						</tr>
					</table>
				</xsl:if>
				<table class="normalna">
					<tr>
						<xsl:if test="*[local-name()='PelnaNazwa' ]">
							<td class="wypelniane">
								<div class="opisrubryki">Nazwa pełna</div>
								<xsl:apply-templates select="*[local-name() = 'PelnaNazwa']"/>
							</td>
						</xsl:if>
						<xsl:if test="../*[local-name()='Email' ]">
							<td class="wypelniane">
								<div class="opisrubryki">E-mail</div>
								<xsl:value-of select="../*[local-name() = 'Email']"/>
							</td>
						</xsl:if>
					</tr>
				</table>
			</xsl:for-each>
		</xsl:if>
	</xsl:template>
	<xsl:template name="Informacja">
		<xsl:param name="sekcja"/>
		<xsl:if test="*[local-name()='Informacja']">
			<h2 class="tytul-sekcja-blok">
				<xsl:value-of select="$sekcja"/>INFORMACJA O ZAPRZESTANIU WYSTAWIANIA I PRZESYŁANIA FAKTUR Z ZAŁĄCZNIKIEM DO KRAJOWEGO SYSTEMU E-FAKTUR</h2>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">Wartość 1 oznacza złożenie oświadczenia o zamiarze zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem.</div>
						<xsl:if test="*[local-name()='Informacja']/*[local-name()='Oswiadczenie1']='1'">
								<input type="checkbox" checked="checked" disabled="disabled"/> 1. Zgłaszam zamiar zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem.</xsl:if>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">Data zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem</div>
						<xsl:value-of select="*[local-name()='Informacja']/*[local-name()='Data']"/>
					</td>
				</tr>
			</table>
		</xsl:if>
	</xsl:template>
	<xsl:template name="Oswiadczenie">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> OŚWIADCZENIE</h2>
		<xsl:if test="*[local-name()='Oswiadczenie']">
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">Wartość 1 oznacza złożenie poniższego oświadczenia podatnika o treści:</div>
						<xsl:if test="*[local-name()='Oswiadczenie'] = '1'">
							<input type="checkbox" checked="checked" disabled="disabled"/> 1. Oświadczam, że jestem świadomy/-a, że w związku ze zgłoszeniem zamiaru zaprzestania wystawiania i przesyłania do Krajowego Systemu e-Faktur faktur z załącznikiem powyższa możliwość zostanie mi odebrana.</xsl:if>
					</td>
				</tr>
			</table>
		</xsl:if>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='Data']">
		Data złożenia zgłoszenia 
		<span class="data">
			<span class="opisrubryki">
				<xsl:call-template name="WezNumerPozycji"/>
				<xsl:text>Data  </xsl:text>
			</span>
			<xsl:apply-templates/>
		</span>
	</xsl:template>
</xsl:stylesheet>