13707
| ID | 13707 |
|---|
| Data | 2025-03-07 |
|---|
| Symbol | 2025/03/07/13707 |
|---|
| Instytucja | Ministerstwo Cyfryzacji |
|---|
| Nazwa | Wniosek o wyrażenie zgody na świadczenie usługi udostępnianej w aplikacji mObywatel, która pozwala na realizację zadań podmiotu |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:adr="http://crd.gov.pl/xml/schematy/adres/2009/11/09/" xmlns:oso="http://crd.gov.pl/xml/schematy/osoba/2009/11/16/" xmlns:inst="http://crd.gov.pl/xml/schematy/instytucja/2009/11/16/" xmlns:meta="http://crd.gov.pl/xml/schematy/meta/2009/11/16/" xmlns:str="http://crd.gov.pl/xml/schematy/struktura/2009/11/16/" xmlns:wnio="http://crd.gov.pl/wzor/2025/03/07/13707/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:ds="http://www.w3.org/2000/09/xmldsig#" xmlns="http://www.w3.org/1999/xhtml" version="1.0" xsi:schemaLocation="http://www.w3.org/1999/XSL/Transform http://www.w3.org/2005/02/schema-for-xslt20.xsd" exclude-result-prefixes="adr oso inst meta wnio ds str xsi">
<xsl:output method="xml" encoding="utf-8" indent="yes" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd" doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN"/>
<xsl:template match="/">
<xsl:apply-templates select="wnio:Dokument"/>
</xsl:template>
<xsl:template match="wnio:Dokument">
<html>
<head>
<meta charset="UTF-8"/>
<style type="text/css">
body {
font-family: sans-serif;
}
td {
padding: 20px 20px 20px 0;
}
.application-title {
font-size: 25px;
font-weight: bold;
}
.section-name {
border-bottom: 1px solid rgba(217, 229, 242, 1);
font-size: 20px;
font-weight: bold;
padding: 20px 20px 20px 0;
}
.application td:first-child {
width: 378px;
}
.field-name {
font-weight: bold;
}
.field-value {
padding-top: 12px;
padding-left: 0;
}
</style>
</head>
<body class="body">
<div style="width: 100%;">
<div class="application-title">Wniosek o nawiązanie współpracy w ramach aplikacji mObywatel</div>
<table class="application">
<tr><td colspan="2" class="section-name">Identyfikator wniosku</td></tr>
<tr><td><xsl:value-of select="wnio:TrescDokumentu/wnio:Identyfikator"/></td></tr>
<tr><td colspan="2" class="section-name">Typ usługi</td></tr>
<tr><td><xsl:value-of select="wnio:TrescDokumentu/wnio:TypUslugi"/></td></tr>
<tr><td colspan="2" class="section-name">Dane podmiotu</td></tr>
<tr>
<td><div class="field-name">Nazwa instytucji</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:NazwaInstytucji"/></div></td>
<td><div class="field-name">Numer REGON</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:Regon"/></div></td>
</tr>
<tr>
<td><div class="field-name">Numer KRS</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:Krs"/></div></td>
<td><div class="field-name">NIP</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:Nip"/></div></td>
</tr>
<xsl:call-template name="Adres">
<xsl:with-param name="adres" select="wnio:TrescDokumentu/wnio:Instytucja/wnio:AdresSiedziby"/>
</xsl:call-template>
<tr><td colspan="2" class="section-name">Adres korespondencyjny</td></tr>
<xsl:choose>
<xsl:when test="wnio:TrescDokumentu/wnio:Instytucja/wnio:AdresKorespondencyjny">
<xsl:call-template name="Adres">
<xsl:with-param name="adres" select="wnio:TrescDokumentu/wnio:Instytucja/wnio:AdresKorespondencyjny"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<tr><td>Adres korespondencyjny zgodny z adresem siedziby</td></tr>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych">
<tr><td colspan="2" class="section-name">Dane do przekazywania w usłudze</td></tr>
<tr>
<td><div class="field-name">Zakres danych</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych/wnio:ZakresDanych"/></div></td>
<td><div class="field-name">Cel przekazywania danych</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych/wnio:CelPrzekazywaniaDanych"/></div></td>
</tr>
<xsl:call-template name="Certyfikat">
<xsl:with-param name="certyfikat" select="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych/wnio:Certyfikat"/>
</xsl:call-template>
<tr><td colspan="2" class="section-name">Dane osoby koordynującej współpracę</td></tr>
<xsl:call-template name="OsobaKontaktowa">
<xsl:with-param name="osoba" select="wnio:TrescDokumentu/wnio:Instytucja/wnio:OsobaKontaktowa"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:UslugaLegitymacja">
<xsl:call-template name="Certyfikat">
<xsl:with-param name="certyfikat" select="wnio:TrescDokumentu/wnio:UslugaLegitymacja/wnio:Certyfikat"/>
</xsl:call-template>
<tr><td colspan="2" class="section-name">
<xsl:choose>
<xsl:when test="wnio:TrescDokumentu/@serviceType = 'SCHOOL_CARD'">Dane dyrektora</xsl:when>
<xsl:otherwise>Dane rektora</xsl:otherwise>
</xsl:choose>
</td></tr>
<xsl:call-template name="OsobaKontaktowaSzkola">
<xsl:with-param name="osoba" select="wnio:TrescDokumentu/wnio:UslugaLegitymacja/wnio:Rektor"/>
</xsl:call-template>
<tr><td colspan="2" class="section-name">Dane osoby koordynującej współpracę</td></tr>
<xsl:call-template name="OsobaKontaktowa">
<xsl:with-param name="osoba" select="wnio:TrescDokumentu/wnio:Instytucja/wnio:OsobaKontaktowa"/>
</xsl:call-template>
<tr><td colspan="2" class="section-name">Dane osób uprawnionych do działań w portalu szkół i uczelni</td></tr>
<xsl:for-each select="wnio:TrescDokumentu/wnio:UslugaLegitymacja/wnio:OsobyUprawnione">
<tr>
<td><div class="field-name">Imię i Nazwisko</div><div class="field-value"><xsl:value-of select="wnio:Imie"/><span style="padding-left: 5px; display: inline-block"><xsl:value-of select="wnio:Nazwisko"/></span></div></td>
<td><div class="field-name">Pesel</div><div class="field-value"><xsl:value-of select="wnio:Pesel"/></div></td>
</tr>
</xsl:for-each>
<tr><td colspan="2" class="section-name">Dane inspektora ochrony danych osobowych</td></tr>
<xsl:call-template name="OsobaKontaktowaSzkola">
<xsl:with-param name="osoba" select="wnio:TrescDokumentu/wnio:UslugaLegitymacja/wnio:InspektorOchrony"/>
</xsl:call-template>
</xsl:if>
<tr><td colspan="2" class="section-name">Kontakt w sprawie wniosku</td></tr>
<tr>
<td colspan="2"><div class="field-name">Adres skrzynki ePUAP</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:EpuapMailBox"/></div></td>
</tr>
<tr>
<td colspan="2"><div class="field-name">Adres skrzynki do e-Doręczeń</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:EdorAddress"/></div></td>
</tr>
<xsl:if test="count(wnio:TrescDokumentu/wnio:Zalacznik) > 0">
<tr><td colspan="2" class="section-name">Załączniki</td></tr>
<xsl:for-each select="wnio:TrescDokumentu/wnio:Zalacznik">
<tr><td> <a href="{wnio:PlikZalacznika}"><xsl:value-of select="wnio:NazwaZalacznika"/></a></td></tr>
</xsl:for-each>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych">
<tr><td colspan="2" class="section-name">Wcześniejsze porozumienie</td></tr>
<tr><td colspan="2">
<xsl:choose>
<xsl:when test="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych/wnio:WczesniejszePorozumienie='true'">
<input type="checkbox" checked="true" disabled="true"/>
</xsl:when>
<xsl:otherwise>
<input type="checkbox" disabled="true"/>
</xsl:otherwise>
</xsl:choose>
Podmiot, dla którego składasz wniosek, zawarł porozumienie z ministrem cyfryzacji lub uzyskał jego zgodę na korzystanie z licencji mObywatel BackSystem w ramach usługi przekazywania danych z aplikacji mObywatel (opcjonalne)
</td></tr>
<tr><td colspan="2" class="section-name">Oświadczenie</td></tr>
<tr><td colspan="2"><input type="checkbox" checked="true" disabled="true"/>Oświadczam, że akceptuję ogólne warunki świadczenia usługi</td></tr>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:UslugaLegitymacja">
<tr><td colspan="2" class="section-name">Oświadczenie</td></tr>
<tr><td colspan="2"><input type="checkbox" checked="true" disabled="true"/>Oświadczam, że akceptuję ogólne warunki świadczenia usługi</td></tr>
</xsl:if>
</table>
<xsl:call-template name="Podpis"/>
</div>
</body>
</html>
</xsl:template>
<xsl:template name="OsobaKontaktowa">
<xsl:param name="osoba"/>
<tr>
<td><div class="field-name">Imię</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Imie"/></div></td>
<td><div class="field-name">Nazwisko</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Nazwisko"/></div></td>
</tr>
<tr>
<td><div class="field-name">Adres e-mail</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Email"/></div></td>
<td><div class="field-name">Numer telefonu</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Telefon"/></div></td>
</tr>
<tr>
<td><div class="field-name">Pesel</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Pesel"/></div></td>
</tr>
</xsl:template>
<xsl:template name="OsobaKontaktowaSzkola">
<xsl:param name="osoba"/>
<tr>
<td><div class="field-name">Imię</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Imie"/></div></td>
<td><div class="field-name">Nazwisko</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Nazwisko"/></div></td>
</tr>
<tr>
<td><div class="field-name">Adres e-mail</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Email"/></div></td>
<td><div class="field-name">Numer telefonu</div><div class="field-value"><xsl:value-of select="$osoba/wnio:Telefon"/></div></td>
</tr>
</xsl:template>
<xsl:template name="Certyfikat">
<xsl:param name="certyfikat"/>
<tr><td colspan="2" class="section-name">Dane do certyfikatu</td></tr>
<tr>
<td><div class="field-name">Pełna nazwa instytucji</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:NazwaInstytucji"/></div></td>
<td><div class="field-name">Zwyczajowa nazwa instytucji</div><div class="field-value"><xsl:value-of select="$certyfikat/wnio:ZwyczajowaNazwaInstytucji"/></div></td>
</tr>
<tr>
<td><div class="field-name">Nazwa jednostki instytucji</div><div class="field-value"><xsl:value-of select="$certyfikat/wnio:NazwaJednostkiInstytucji"/></div></td>
<td><div class="field-name">REGON</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:Instytucja/wnio:Regon"/></div></td>
</tr>
<xsl:if test="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych">
<tr>
<td><div class="field-name">Typ instytucji</div><div class="field-value"><xsl:value-of select="wnio:TrescDokumentu/wnio:UslugaUdostepnianieDanych/wnio:TypInstytucji"/></div></td>
</tr>
</xsl:if>
<xsl:choose>
<xsl:when test="$certyfikat/wnio:AdresPodmiotu">
<tr><td colspan="2" class="section-name">Adres podmiotu do certyfikatu</td></tr>
<xsl:call-template name="Adres">
<xsl:with-param name="adres" select="$certyfikat/wnio:AdresPodmiotu"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<tr><td><div class="field-name">Adres podmiotu do certyfikatu</div><div class="field-value">Taki sam jak adres siedziby</div></td></tr>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="Adres">
<xsl:param name="adres"/>
<tr>
<td><div class="field-name">Kraj</div><div class="field-value"><xsl:value-of select="$adres/wnio:Kraj"/></div></td>
<td><div class="field-name">Miejscowość</div><div class="field-value"><xsl:value-of select="$adres/wnio:Miejscowosc"/></div></td>
</tr>
<tr>
<td><div class="field-name">Województwo</div><div class="field-value"><xsl:value-of select="$adres/wnio:Wojewodztwo"/></div></td>
<td><div class="field-name">Powiat</div><div class="field-value"><xsl:value-of select="$adres/wnio:Powiat"/></div></td>
</tr>
<tr>
<td><div class="field-name">Gmina</div><div class="field-value"><xsl:value-of select="$adres/wnio:Gmina"/></div></td>
<td><div class="field-name">Kod pocztowy</div><div class="field-value"><xsl:value-of select="$adres/wnio:KodPocztowy"/></div></td>
</tr>
<tr>
<td><div class="field-name">Ulica</div><div class="field-value"><xsl:value-of select="$adres/wnio:Ulica"/></div></td>
<td><div class="field-name">Numer budynku</div><div class="field-value"><xsl:value-of select="$adres/wnio:NumerBudynku"/></div></td>
</tr>
<tr>
<td><div class="field-name">Numer lokalu</div><div class="field-value"><xsl:value-of select="$adres/wnio:NumerLokalu"/></div></td>
<td><div class="field-name">Adres e-mail</div><div class="field-value"><xsl:value-of select="$adres/wnio:Email"/></div></td>
</tr>
<tr>
<td><div class="field-name">Numer telefonu</div><div class="field-value"><xsl:value-of select="$adres/wnio:Telefon"/></div></td>
</tr>
</xsl:template>
<xsl:template name="Podpis">
<div align="right" style="text-align: right;font-size: 10px;font-family: Verdana;line-height: 20px;">
<table style="float: right;">
<tr>
<td style="width: 340px;">
<h2 class="acc">Podpisy elektroniczne</h2>
<p align="center" style="text-align: center;font-size: 10px;font-family: Verdana;line-height: 20px;">
<xsl:choose>
<xsl:when test="string-length(//wnio:Dokument/ds:Signature/ds:SignatureValue) > 0">
<xsl:text>Dokument został podpisany, aby go zweryfikować należy użyć oprogramowania do weryfikacji podpisu</xsl:text>
<xsl:choose>
<xsl:when test="count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']) > 1">
<br/>
<xsl:text>Daty złożenia podpisu: </xsl:text>
<xsl:for-each select="//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']">
<xsl:value-of select="."/>
</xsl:for-each>
</xsl:when>
<xsl:when test="count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']) = 1">
<br/>
<xsl:text>Data złożenia podpisu: </xsl:text>
<xsl:for-each select="//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime']">
<xsl:value-of select="."/>
</xsl:for-each>
</xsl:when>
<xsl:when test="0 >= count(//wnio:Dokument/ds:Signature/ds:Object/descendant::*[local-name() = 'SigningTime'])">
</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:text>Dokument nie zawiera podpisu</xsl:text>
</xsl:otherwise>
</xsl:choose>
<br/>
<span style="font-size: 7pt;font-weight: bold;">
Podpis elektroniczny
</span>
</p>
</td>
</tr>
</table>
</div>
<div style="clear: both;"/>
</xsl:template>
</xsl:stylesheet>