13686
| ID | 13686 |
|---|
| Data | 2025-02-17 |
|---|
| Symbol | 2025/02/17/13686 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | CBC-P POWIADOMIENIE W ZAKRESIE OBOWIĄZKU PRZEKAZANIA INFORMACJI O GRUPIE PODMIOTÓW |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:pf="http://crd.gov.pl/wzor/2025/02/17/13686/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/18/eD/DefinicjeSzablony/WspolneSzablonyWizualizacji_v15-0E.xsl"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:template name="TytulDokumentu">POWIADOMIENIE W ZAKRESIE OBOWIĄZKU PRZEKAZANIA INFORMACJI O GRUPIE PODMIOTÓW</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">
.tlo-formularza { background-color:#D3D3D3; }
</style>
</xsl:template>
<xsl:param name="schema-kraju" select="'./schemat.xsd'"/>
<xsl:template match="pf:Deklaracja">
<div class="deklaracja">
<xsl:call-template name="NaglowekTechniczny">
<xsl:with-param name="naglowek" select="pf:Naglowek"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
</xsl:call-template>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="naglowek" select="pf:Naglowek"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa">POWIADOMIENIE W ZAKRESIE OBOWIĄZKU PRZEKAZANIA INFORMACJI O GRUPIE PODMIOTÓW</xsl:with-param>
<xsl:with-param name="podstawy-prawne">
<table>
<tr>
<td class="etykieta" style="width: 10%">Podstawa prawna:</td>
<td class="wartosc">Art. 86 ust. 1 ustawy z dnia 9 marca 2017 roku o wymianie informacji podatkowych z innymi państwami, zwanej dalej „ustawą”.</td>
</tr>
<tr>
<td class="etykieta" valign="top">Składający:</td>
<td class="wartosc">Jednostka wchodząca w skład grupy podmiotów, o której mowa w art. 82 pkt 5 ustawy, która posiada siedzibę lub zarząd na terytorium Rzeczypospolitej Polskiej albo posiada siedzibę lub zarząd poza terytorium Rzeczypospolitej Polskiej, ale prowadzi na terytorium Rzeczypospolitej Polskiej działalność przez zagraniczny zakład.</td>
</tr>
<tr>
<td class="etykieta">Termin składania:</td>
<td class="wartosc">3 miesiące od dnia zakończenia sprawozdawczego roku obrotowego grupy podmiotów, o którym mowa w art. 82 pkt 8 ustawy.</td>
</tr>
<tr>
<td class="etykieta">Miejsce składania:</td>
<td class="wartosc">Ministerstwo Finansów</td>
</tr>
</table>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="CelZlozenia"/>
<xsl:call-template name="Podmiot1_CBC">
<xsl:with-param name="sekcja">A.</xsl:with-param>
</xsl:call-template>
<xsl:for-each select="*[local-name()='Podmiot2']">
<xsl:call-template name="Podmiot2_CBC">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
</xsl:for-each>
<xsl:if test="*[local-name()='RolaJednostkiSkladajacej']">
<xsl:call-template name="RolaJednostki"/>
</xsl:if>
</div>
</xsl:template>
<xsl:template name="Podmiot1_CBC">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> Dane jednostki składającej powiadomienie</h2>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>1. DANE IDENTYFIKACYJNE jednostki składającej powiadomienie</h3>
<div class="sekcja">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Nazwa jednostki składającej powiadomienie</div>
<xsl:apply-templates select="*[local-name()='Podmiot1']/*[local-name()='NazwaPodmiotu']"/>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Numer identyfikacji podatkowej jednostki składającej powiadomienie</div>
<xsl:apply-templates select="*[local-name()='Podmiot1']/*[local-name()='NIP']"/>
</td>
</tr>
</table>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>2. ADRES SIEDZIBY jednostki składającej powiadomienie</h3>
<xsl:for-each select="*[local-name()='Podmiot1']/*[local-name()='AdresSiedziby']/*[local-name()='AdresZagr']|*[local-name()='Podmiot1']/*[local-name()='AdresSiedziby']/*[local-name()='AdresPol']">
<xsl:call-template name="AdresTabela"/>
</xsl:for-each>
</div>
</xsl:template>
<xsl:template name="Podmiot2_CBC">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> DANE JEDNOSTKI RAPORTUJĄCEJ</h2>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>1. DANE IDENTYFIKACYJNE jednostki raportującej</h3>
<div class="sekcja">
<xsl:for-each select="*[local-name()='PodmiotPol']">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Identyfikator podatkowy NIP polskiej jednostki raportującej</div>
<xsl:apply-templates select="*[local-name()='NIP']"/>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Nazwa polskiej jednostki raportującej</div>
<xsl:apply-templates select="*[local-name()='NazwaPodmiotu']"/>
</td>
</tr>
</table>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>2. ADRES jednostki raportującej</h3>
<xsl:for-each select="*[local-name()='AdresPol']">
<xsl:apply-templates select="."/>
</xsl:for-each>
</xsl:for-each>
<xsl:for-each select="*[local-name()='PodmiotZagr']">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Identyfikator podatkowy zagranicznej jednostki raportującej i kod kraju wydania identyfikatora</div>
<xsl:for-each select="*[local-name()='TIN']">
<xsl:apply-templates select="."/> <xsl:text>(</xsl:text>
<xsl:apply-templates select="@issuedBy"/>
<xsl:text>)</xsl:text>
</xsl:for-each>
</td>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Inny numer identyfikacyjny i kod kraju wydania innego numeru identyfikacyjnego</div>
<xsl:for-each select="*[local-name()='IN']">
<xsl:call-template name="OrganisationIN"/>
<xsl:if test="position() != last()">
<xsl:text>, </xsl:text>
</xsl:if>
</xsl:for-each>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Nazwa zagranicznej jednostki raportującej</div>
<xsl:apply-templates select="*[local-name()='Name']"/>
</td>
</tr>
</table>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>2. ADRES jednostki raportującej</h3>
<xsl:for-each select="*[local-name()='AdresZagr']">
<xsl:apply-templates select="."/>
</xsl:for-each>
</xsl:for-each>
</div>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Kod kraju, w którym zostanie przekazana informacja o grupie podmiotów</div>
<xsl:for-each select="*[local-name()='KodKrajuPrzekazania']">
<xsl:call-template name="PokazKodKraju"/>
</xsl:for-each>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="RolaJednostki">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opis-tekstowy">Rola jednostki składającej powiadomienie:</div>
<xsl:choose>
<xsl:when test="*[local-name()='RolaJednostkiSkladajacej']=1">
<input type="checkbox" checked="checked" disabled="disabled"/>1. Jednostka dominująca
</xsl:when>
<xsl:when test="*[local-name()='RolaJednostkiSkladajacej']=2">
<input type="checkbox" checked="checked" disabled="disabled"/>2. Wyznaczona jednostka
</xsl:when>
<xsl:when test="*[local-name()='RolaJednostkiSkladajacej']=3">
<input type="checkbox" checked="checked" disabled="disabled"/>3. Inna jednostka składająca informację o grupie podmiotów
</xsl:when>
</xsl:choose>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="OrganisationIN">
<xsl:apply-templates select="."/> <xsl:text>(</xsl:text>
<xsl:if test="@issuedBy">
<xsl:apply-templates select="@issuedBy"/>
<xsl:text>, </xsl:text>
</xsl:if>
<xsl:choose>
<xsl:when test="@INType='1'">
<xsl:text>US GIIN</xsl:text>
</xsl:when>
<xsl:when test="@INType='2'">
<xsl:text>EIN</xsl:text>
</xsl:when>
<xsl:when test="@INType='3'">
<xsl:text>Other</xsl:text>
</xsl:when>
</xsl:choose>
<xsl:text>) </xsl:text>
</xsl:template>
<xsl:template name="CelZlozenia">
<xsl:param name="sekcja"/>
<table class="normalna">
<tr>
<td class="niewypelnianeopisy">Cel złożenia powiadomienia:</td>
<td class="wypelniane">
<xsl:choose>
<xsl:when test="*[local-name()='Naglowek']/*[local-name()='CelZlozenia'] =1">
<input type="checkbox" checked="checked" disabled="disabled"/>1. złożenie powiadomienia
</xsl:when>
<xsl:when test="*[local-name()='Naglowek']/*[local-name()='CelZlozenia'] =2">
<input type="checkbox" checked="checked" disabled="disabled"/>2. korekta powiadomienia
</xsl:when>
</xsl:choose>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="PokazKodKraju">
<xsl:apply-templates/>
<xsl:if test="$nazwy-dla-kodow">
<span class="nazwa-dla-kodu">
<xsl:text>(</xsl:text>
<xsl:call-template name="ZnajdzWEnumeracji1">
<xsl:with-param name="schema" select="$schema-krajow"/>
<xsl:with-param name="typ" select="'TKodKraju'"/>
<xsl:with-param name="kod" select="text()"/>
</xsl:call-template>
<xsl:text>)</xsl:text>
</span>
</xsl:if>
</xsl:template>
<xsl:template name="ZnajdzWEnumeracji1">
<xsl:param name="schema"/>
<xsl:param name="typ"/>
<xsl:param name="kod"/>
<xsl:variable name="wschema" select="document($schema)"/>
<xsl:value-of select="$wschema//xs:simpleType[@name=$typ]// xs:enumeration[@value = $kod]//xs:documentation"/>
</xsl:template>
</xsl:stylesheet>