13659
| ID | 13659 |
|---|
| Data | 2025-01-10 |
|---|
| Symbol | 2025/01/10/13659 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | PCC-2 DEKLARACJA O WYSOKOŚCI POBRANEGO I WPŁACONEGO PRZEZ PŁATNIKA PODATKU |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:pf="http://crd.gov.pl/wzor/2025/01/10/13659/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/18/eD/DefinicjeSzablony/Posredni_wspolne_v15-0E.xsl"/>
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/09/13/eD/ORDZU/ORD-ZU(3)_v14-0E.xsl"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:template name="TytulDokumentu">DEKLARACJA O WYSOKOŚCI POBRANEGO I WPŁACONEGO PODATKU PRZEZ PŁATNIKA</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">.tlo-formularza {background-color: #D3D3D3; font-size:1.0em;}</style>
</xsl:template>
<xsl:template match="pf:Deklaracja">
<div class="deklaracja">
<xsl:call-template name="NaglowekTechniczny">
<xsl:with-param name="naglowek" select="*[local-name()='Naglowek']"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
</xsl:call-template>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="naglowek" select="*[local-name()='Naglowek']"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa">DEKLARACJA O WYSOKOŚCI POBRANEGO I WPŁACONEGO PODATKU PRZEZ PŁATNIKA</xsl:with-param>
<xsl:with-param name="podstawy-prawne">
<table>
<tr>
<td class="etykieta" style="width: 10%">Podstawa prawna:</td>
<td class="wartosc">Art. 10 ust. 3a pkt 2 ustawy z dnia 9 września 2000 r. o podatku od czynności cywilnoprawnych (Dz. U. z 2015 r. poz. 626, z późn. zm.).</td>
</tr>
<tr>
<td class="etykieta" valign="top">Składający:</td>
<td class="wartosc">Notariusz.</td>
</tr>
<tr>
<td class="etykieta">Termin składania:</td>
<td class="wartosc">Do 7 dnia miesiąca następującego po miesiącu, w którym pobrano podatek.</td>
</tr>
<tr>
<td class="etykieta">Miejsce składania:</td>
<td class="wartosc">Urząd skarbowy, którym kieruje naczelnik urzędu skarbowego właściwy ze względu na siedzibę kancelarii notarialnej.</td>
</tr>
</table>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="MiejsceICel">
<xsl:with-param name="sekcja">A.</xsl:with-param>
</xsl:call-template>
<xsl:for-each select="*[local-name()='Podmiot1']">
<xsl:call-template name="Podmiot1">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
</xsl:for-each>
<!-- Pozycje Szczegolowe -->
<xsl:call-template name="AdresSiedzibyKancelarii">
<xsl:with-param name="sekcja">C.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="DaneDotyczaceNaleznosci">
<xsl:with-param name="sekcja">D.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="InformacjaGmina">
<xsl:with-param name="sekcja">E.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="Oswiadczenie">
<xsl:with-param name="sekcja">F.</xsl:with-param>
<xsl:with-param name="etykieta">OŚWIADCZENIE</xsl:with-param>
</xsl:call-template>
</div>
<!-- deklaracja-->
<xsl:apply-templates select="pf:Zalaczniki"/>
</xsl:template>
<xsl:template name="Podmiot1">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> DANE PŁATNIKA</h2>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>1. DANE IDENTYFIKACYJNE</h3>
<div class="sekcja">
<xsl:apply-templates select="*[local-name()='OsobaFizyczna']"/>
<xsl:call-template name="AdresZamieszkania1">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
</div>
</xsl:template>
<xsl:template match="*[local-name()='OsobaFizyczna']">
<xsl:param name="sekcja"/>
<div class="sekcja">
<table class="normalna">
<tr>
<xsl:if test="*[local-name()='NIP' ]">
<td class="wypelniane">
<div class="opisrubryki">Identyfikator podatkowy NIP</div>
<xsl:apply-templates select="*[local-name() = 'NIP']"/>
</td>
</xsl:if>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:40%">
<div class="opisrubryki">Nazwisko</div>
<xsl:apply-templates select="*[local-name()='Nazwisko']"/>
</td>
<td class="wypelniane" style="width:40%">
<div class="opisrubryki">Pierwsze imię</div>
<xsl:apply-templates select="*[local-name()='ImiePierwsze']"/>
</td>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">Data urodzenia</div>
<xsl:apply-templates select="*[local-name()='DataUrodzenia']"/>
</td>
</tr>
</table>
</div>
</xsl:template>
<xsl:template name="AdresZamieszkania1">
<xsl:param name="sekcja"/>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>2. AKTUALNY ADRES ZAMIESZKANIA</h3>
<div class="sekcja">
<xsl:for-each select="*[local-name()='AdresZamieszkania']">
<xsl:call-template name="AdresTabela"/>
</xsl:for-each>
</div>
</xsl:template>
<xsl:template name="AdresSiedzibyKancelarii">
<xsl:param name="sekcja"/>
<xsl:for-each select="pf:PozycjeSzczegolowe">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> ADRES SIEDZIBY KANCELARII NOTARIALNEJ</h2>
<table class="normalna">
<tr>
<td class="wypelniane" style="width: 60%">
<div class="opisrubryki">20. Województwo</div>
<xsl:value-of select="*[local-name()='P_20']"/>
</td>
<td class="wypelniane" style="width: 40%">
<div class="opisrubryki">21. Powiat</div>
<xsl:value-of select="*[local-name()='P_21']"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width: 30%">
<div class="opisrubryki">22. Gmina</div>
<xsl:value-of select="*[local-name()='P_22']"/>
</td>
<td class="wypelniane" style="width: 40%">
<div class="opisrubryki">23. Ulica</div>
<xsl:value-of select="*[local-name()='P_23']"/>
</td>
<td class="wypelniane" style="width: 15%">
<div class="opisrubryki">24. Nr domu</div>
<xsl:value-of select="*[local-name()='P_24']"/>
</td>
<td class="wypelniane" style="width: 15%">
<div class="opisrubryki">25. Nr lokalu</div>
<xsl:value-of select="*[local-name()='P_25']"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width: 40%">
<div class="opisrubryki">26. Miejscowość</div>
<xsl:value-of select="*[local-name()='P_26']"/>
</td>
<td class="wypelniane" style="width: 20%">
<div class="opisrubryki">27. Kod pocztowy</div>
<xsl:value-of select="*[local-name()='P_27']"/>
</td>
<td class="wypelniane" style="width: 40%">
<div class="opisrubryki">28. Poczta</div>
<xsl:value-of select="*[local-name()='P_28']"/>
</td>
</tr>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="DaneDotyczaceNaleznosci">
<xsl:param name="sekcja"/>
<xsl:for-each select="pf:PozycjeSzczegolowe">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> DANE DOTYCZĄCE NALEŻNOŚCI</h2>
<table class="normalna">
<tr>
<td class="niewypelnianeopisy" style="width: 80%">Łączna kwota podatku pobranego w danym miesiącu</td>
<td class="wypelniane" style="width: 20%">
<div class="opisrubryki">29.</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_29'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
<tr>
<td class="niewypelnianeopisy" style="width: 80%">Kwota podatku pobranego od umowy spółki kapitałowej i jej zmiany</td>
<td class="wypelniane" style="width: 20%">
<div class="opisrubryki">30.</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_30'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
<tr>
<td class="niewypelnianeopisy" style="width: 80%">Kwota potrąconego wynagrodzenia z tytułu poboru podatku - zgodnie z art. 28 § 4 ustawy z dnia 29 sierpnia 1997 r. - Ordynacja podatkowa (Dz. U. z 2015 r. poz. 613, z późn. zm.)</td>
<td class="wypelniane" style="width: 20%">
<div class="opisrubryki">31.</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_31'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
<tr>
<td class="niewypelnianeopisy" style="width: 80%">Kwota podatku wpłaconego na rachunek bankowy właściwego organu podatkowego</td>
<td class="wypelniane" style="width: 20%">
<div class="opisrubryki">32.</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_32'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="InformacjaGmina">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> INFORMACJA O KWOCIE PODATKU NALEŻNEGO GMINIE</h2>
<xsl:for-each select="//pf:P_A">
<table class="normalna">
<tr>
<td class="niewypelnianeopisy" style="width: 2%" rowspan="2">
<xsl:number/>
</td>
<td class="wypelniane" style="width: 30%">
<div class="opisrubryki">Województwo</div>
<div class=".opisrubryki">
<xsl:value-of select=".//*[local-name()='P_A1']"/>
</div>
</td>
<td class="wypelniane" style="width: 30%">
<div class="opisrubryki">Powiat</div>
<div class=".opisrubryki">
<xsl:value-of select=".//*[local-name()='P_A2']"/>
</div>
</td>
<td class="wypelniane" style="width: 38%">
<div class="opisrubryki">Gmina</div>
<div class=".opisrubryki">
<xsl:value-of select=".//*[local-name()='P_A3']"/>
</div>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width: 50%">
<div class="opisrubryki">Identyfikator rejestru TERYT</div>
<div class=".opisrubryki">
<xsl:value-of select=".//*[local-name()='P_A4']"/>
</div>
</td>
<td class="wypelniane" style="width: 50%">
<div class="opisrubryki">Łączna kwota podatku należnego gminie</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(.//*[local-name()='P_A5'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
</table>
<table class="normalna">
<xsl:for-each select=".//*[local-name()='P_A6']">
<tr>
<td class="wypelniane" style="width: 100%">
<div class="opisrubryki">Numer repertorium A (pod którym wpisane są czynności prawne, z tytułu których podatek jest należny gminie)</div>
<div class=".opisrubryki">
<xsl:value-of select="."/>
</div>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="Oswiadczenie">
<xsl:param name="sekcja"/>
<xsl:param name="etykieta"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> <xsl:copy-of select="$etykieta"/>
</h2>
<xsl:if test="pf:Oswiadczenie = 1">
<table class="pouczenia">
<tr>
<td>
<h3 align="justify">Oświadczam, że podana kwota z poz. 29 jest zgodna z kwotami wykazanymi w prowadzonym rejestrze.</h3>
<br/>
</td>
</tr>
</table>
<div class="lamstrone"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>