13582
| ID | 13582 |
|---|
| Data | 2024-11-20 |
|---|
| Symbol | 2024/11/20/13582 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | VAT-S1K INFORMACJA DLA ROZLICZEŃ KWARTALNYCH O DOKONANYM LIKWIDACYJNYM SPISIE Z NATURY |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:etd="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/09/13/eD/DefinicjeTypy/" xmlns:tns="http://crd.gov.pl/wzor/2024/11/20/13582/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/18/eD/DefinicjeSzablony/Posredni_wspolne_v15-0E.xsl"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:param name="nazwy-dla-kodow" select="true()"/>
<xsl:template name="TytulDokumentu">INFORMACJA DLA ROZLICZEŃ KWARTALNYCH O DOKONANYM LIKWIDACYJNYM SPISIE Z NATURY</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">
.tlo-formularza { background-color: #d5d5d5; font-size:1.0em; }
</style>
</xsl:template>
<xsl:template match="*[local-name()='Wniosek']">
<div class="wniosek">
<xsl:call-template name="NaglowekTechniczny">
<xsl:with-param name="naglowek" select="*[local-name()='Naglowek']"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
</xsl:call-template>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa"><br/>INFORMACJA DLA ROZLICZEŃ KWARTALNYCH O DOKONANYM LIKWIDACYJNYM SPISIE Z NATURY<br/><br/></xsl:with-param>
<xsl:with-param name="naglowek" select="*[local-name()='Naglowek']"/>
<xsl:with-param name="podstawy-prawne">
<table>
<tr>
<td class="etykieta" valign="top">Podstawa prawna:</td>
<td class="wartosc">Art. 14 ust. 5 ustawy z dnia 11 marca 2004 r. o podatku od towarów i usług (t.j. Dz.U. z 2024 r. poz. 361, z późn. zm.), zwanej dalej „ustawą”.</td>
</tr>
<tr>
<td class="etykieta" valign="top">Składający:</td>
<td class="wartosc">Podatnicy, o których mowa w art. 14 ust. 5 ustawy.</td>
</tr>
<tr>
<td class="etykieta" valign="top">Termin składania:</td>
<td class="wartosc">Nie później niż w dniu złożenia deklaracji podatkowej składanej za okres obejmujący dzień rozwiązania spółki, zaprzestania wykonywania czynności podlegających opodatkowaniu przez osoby fizyczne albo przedsiębiorstwa w spadku albo wystąpienia innych powodów wskazanych w informacji.</td>
</tr>
<tr>
<td class="etykieta" valign="top">Miejsce składania:</td>
<td class="wartosc">Urząd skarbowy właściwy dla podatnika.</td>
</tr>
</table>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="MiejsceSkladania">
<xsl:with-param name="sekcja">A.</xsl:with-param>
</xsl:call-template>
<xsl:for-each select="*[local-name()='Podmiot1']">
<xsl:call-template name="Podmiot">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
</xsl:for-each>
<xsl:call-template name="Informacja">
<xsl:with-param name="sekcja">C.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="Zalaczniki">
<xsl:with-param name="sekcja">D.</xsl:with-param>
</xsl:call-template>
</div>
</xsl:template>
<xsl:template name="MiejsceSkladania">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> MIEJSCE I CEL SKŁADANIA INFORMACJI</h2>
<table class="normalna-new">
<tr>
<td class="niewypelnianeopisy-new" style="width:33%">Kod i nazwa urzędu skarbowego, do którego adresowana jest informacja</td>
<td class="wypelniane-new" style="width:auto">
<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
</td>
</tr>
<tr>
<td class="niewypelnianeopisy-new">Szczegółowy cel złożenia informacji</td>
<td class="wypelniane-new">
<xsl:choose>
<xsl:when test="*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_9'] =1">
<input type="checkbox" checked="checked" disabled="disabled"/>1. złożenie informacji
</xsl:when>
<xsl:when test="*[local-name()='PozycjeSzczegolowe']/*[local-name()='P_9'] =2">
<input type="checkbox" checked="checked" disabled="disabled"/>2. korekta informacji
</xsl:when>
</xsl:choose>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="Podmiot">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> DANE IDENTYFIKACYJNE PODATNIKA
</h2>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Rodzaj podatnika</div>
<xsl:choose>
<xsl:when test="*[local-name() = 'OsobaNiefizyczna']">
<input type="checkbox" checked="checked" disabled="disabled"/> 1. podatnik niebędący osobą fizyczną
</xsl:when>
</xsl:choose>
<xsl:choose>
<xsl:when test="*[local-name() = 'OsobaFizyczna']">
<input type="checkbox" checked="checked" disabled="disabled"/> 2. osoba fizyczna
</xsl:when>
</xsl:choose>
</td>
</tr>
</table>
<xsl:for-each select="*[local-name() = 'OsobaFizyczna']">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Identyfikator podatkowy NIP podatnika</div>
<xsl:apply-templates select="*[local-name() = 'NIP']"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:35%">
<div class="opisrubryki">Nazwisko</div>
<xsl:apply-templates select="*[local-name() = 'Nazwisko']"/>
</td>
<td class="wypelniane" style="width:35%">
<div class="opisrubryki">Pierwsze imię</div>
<xsl:apply-templates select="*[local-name() = 'ImiePierwsze']"/>
</td>
<td class="wypelniane">
<div class="opisrubryki">Data urodzenia</div>
<xsl:apply-templates select="*[local-name() = 'DataUrodzenia']"/>
</td>
</tr>
</table>
</xsl:for-each>
<xsl:for-each select="*[local-name() = 'OsobaNiefizyczna']">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Identyfikator podatkowy NIP podatnika</div>
<xsl:apply-templates select="*[local-name() = 'NIP']"/>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opisrubryki">Nazwa pełna</div>
<xsl:apply-templates select="*[local-name() = 'PelnaNazwa']"/>
</td>
</tr>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="Informacja">
<xsl:param name="sekcja"/>
<xsl:for-each select="*[local-name()='PozycjeSzczegolowe']">
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> INFORMACJA O DOKONANYM LIKWIDACYJNYM SPISIE Z NATURY<br/>
</h2>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">10. Powód dokonania spisu:</div>
<xsl:if test="*[local-name()='P_10']='1'">
<input type="checkbox" checked="checked" disabled="disabled"/> 1. rozwiązanie spółki
</xsl:if>
<xsl:if test="*[local-name()='P_10']='2'">
<input type="checkbox" checked="checked" disabled="disabled"/> 2. zaprzestanie wykonywania
czynności podlegających opodatkowaniu przez osoby fizyczne albo przedsiębiorstwa w spadku</xsl:if>
<xsl:if test="*[local-name()='P_10']='9'">
<input type="checkbox" checked="checked" disabled="disabled"/> 9. inny powód</xsl:if>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opisrubryki">11. Ustalona wartość towarów</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_11'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="0"/>
</xsl:call-template>
</div>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opisrubryki">12. Kwota podatku należnego</div>
<div class="kwota">
<xsl:call-template name="TransformataKwotyPLN">
<xsl:with-param name="kwota" select="string(*[local-name()='P_12'])"/>
<xsl:with-param name="czyKwotaZaokraglona" select="1"/>
</xsl:call-template>
</div>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opisrubryki">13. Data zakończenia dokonywania czynności opodatkowanych VAT</div>
<xsl:value-of select="*[local-name()='P_13']"/>
</td>
</tr>
<tr>
<td class="wypelniane">
<div class="opisrubryki">14. Informacje dodatkowe</div>
<xsl:value-of select="*[local-name()='P_14']"/>
</td>
</tr>
</table>
</xsl:for-each>
</xsl:template>
<xsl:template name="Zalaczniki">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> INFORMACJE O ZAŁĄCZONYCH KOPIACH DOKUMENTÓW
</h2>
<table class="normalna">
<tr>
<td class="puste2" style="width: 4%">
<div class="opis-tekstowy">Lp.</div>
</td>
<td class="puste2" style="width: 20%">
<div class="opis-tekstowy">Typ pliku
</div>
</td>
<td class="puste2" style="width: 20%">
<div class="opis-tekstowy">Nazwa pliku (bez ścieżki)
</div>
</td>
<td class="puste2" style="width: 56%">
<div class="opis-tekstowy">Opis pliku
</div>
</td>
</tr>
<xsl:for-each select="*[local-name()='PozycjeSzczegolowe']/*[local-name()='Zalaczniki']/*[local-name()='InfOKopiiDokumentu']">
<tr>
<td class="niewypelniane" style="width: 4%">
<div class="symbol">
<xsl:value-of select="position()"/>
</div>
</td>
<td class="wypelniane" style="width: 20%">
<xsl:value-of select="*[local-name()='TypPliku']"/>
</td>
<td class="wypelniane" style="width: 20%">
<xsl:value-of select="*[local-name()='NazwaPliku']"/>
</td>
<td class="wypelniane" style="width: 54%">
<xsl:value-of select="*[local-name()='OpisPliku']"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>