13010

ID	13010
Data	2023-11-20
Symbol	2023/11/20/13010
Instytucja	Ministerstwo Finansów
Nazwa	WH-WOZ WNIOSEK PODATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA
Czy Aktualny	1

Ustawy (1)

URI://Dziennik_Ustaw/2023/57/16b/1	Ustawa z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (t.j. Dz. U. z 2023 r. poz. 57).

Pliki

• wyroznik.xml
• styl.xsl
• schemat.xsd

Styl

<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:pf="http://crd.gov.pl/wzor/2023/11/20/13010/" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="1.0">
	<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/09/30/eD/DefinicjeSzablony/Posredni_wspolne_v15-0E.xsl"/>
	<xsl:param name="nazwy-dla-kodow" select="true()"/>
	<xsl:param name="schema-naczelnikow-urzedow" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2017/02/06/eD/KodyNaczelnikowUrzedowSkarbowych/KodyNaczelnikowUrzedowSkarbowych_v4-0E.xsd'"/>
	<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
	<xsl:template name="StyleDlaFormularza">
		<style type="text/css">
            .tlo-formularza { background-color:#D8D8D8; }
            .ang { font-style: italic; }
        </style>
	</xsl:template>
	<xsl:template name="TytulDokumentu">
		<div class="naglowek">
   WNIOSEK PODATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA 
   <span class="ang">[APPLICATION OF THE TAXPAYER TO ISSUE AN OPINION ON THE APPLICATION OF AN EXEMPTION]</span>
   </div>
	</xsl:template>
	<xsl:template match="pf:Wniosek">
		<xsl:call-template name="NaglowekTechniczny">
			<xsl:with-param name="naglowek" select="pf:Naglowek"/>
			<xsl:with-param name="uzycie" select="'deklaracja'"/>
		</xsl:call-template>
		<xsl:call-template name="NaglowekTytulowy">
			<xsl:with-param name="naglowek" select="pf:Naglowek"/>
			<xsl:with-param name="uzycie" select="'deklaracja'"/>
			<xsl:with-param name="nazwa">WNIOSEK PODATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA<br/>
   <span class="ang">[APPLICATION OF THE TAXPAYER TO ISSUE AN OPINION ON THE APPLICATION OF AN EXEMPTION]</span></xsl:with-param>
			<xsl:with-param name="podstawy-prawne">
				<table>
					<tr>
						<td class="etykieta">Podstawa prawna:
							<span class="ang"> [Legal basis:]</span>
						</td>
						<td class="wartosc">Art. 26b ust. 1 ustawy z dnia 15 lutego 1992 r. o podatku dochodowym od osób prawnych, zwanej dalej ”ustawą” (Dz.U. z 2022 poz. 2587 z późn. zm.).
							<span class="ang"> [Article 26b paragraph 1 of the Act of February 15, 1992 on Corporate Income Tax, hereinafter referred to as „the Act” (Dz. U. 2022, item 2587 with subsequent amendments).]</span>
						</td>
					</tr>
					<tr>
						<td class="etykieta">Składający:
							<span class="ang"> [Submitter:]</span>
						</td>
						<td class="wartosc">Podatnik podatku dochodowego od osób prawnych.
							<span class="ang"> [Corporate income tax payer.]</span>
						</td>
					</tr>
					<tr>
						<td class="etykieta">Miejsce składania:
							<span class="ang"> [Place of submission:]</span>
						</td>
						<td class="wartosc">Urząd skarbowy, o którym mowa w art. 26b ust. 10 ustawy.
							<span class="ang"> [Tax office referred to in Article 26b (10) of the Act.]</span>
						</td>
					</tr>
				</table>
			</xsl:with-param>
		</xsl:call-template>
		<xsl:call-template name="MiejsceICelWH">
			<xsl:with-param name="sekcja">A.</xsl:with-param>
		</xsl:call-template>
		<xsl:for-each select="pf:Podmiot1">
			<xsl:call-template name="PodatnikWHWOZ">
				<xsl:with-param name="sekcja">B.</xsl:with-param>
			</xsl:call-template>
		</xsl:for-each>
		<xsl:for-each select="pf:Podmiot2">
			<xsl:call-template name="PlatnikWHWOZ">
				<xsl:with-param name="sekcja">C.</xsl:with-param>
			</xsl:call-template>
		</xsl:for-each>
		<xsl:call-template name="TrescWniosku">
			<xsl:with-param name="sekcja">D.</xsl:with-param>
		</xsl:call-template>
		<xsl:call-template name="DaneOWyplatach">
			<xsl:with-param name="sekcja">E.</xsl:with-param>
		</xsl:call-template>
		<xsl:call-template name="DaneKontaktowe">
			<xsl:with-param name="sekcja">F.</xsl:with-param>
		</xsl:call-template>
		<xsl:for-each select="pf:PozycjeSzczegolowe/pf:VATRefundApplication/pf:Zalaczniki">
			<xsl:call-template name="Zalaczniki">
				<xsl:with-param name="sekcja">G.</xsl:with-param>
			</xsl:call-template>
		</xsl:for-each>
		<xsl:if test="*[local-name()='Oswiadczenie']=1">
			<xsl:call-template name="Oswiadczenie"/>
		</xsl:if>
	</xsl:template>
	<xsl:template name="MiejsceICelWH">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> CEL I MIEJSCE ZŁOŻENIA WNIOSKU
				<span class="ang"> [PLACE AND PURPOSE OF FURNISHING THIS DOCUMENT]</span>
			</h2>
		<table class="normalna">
			<tr>
				<td class="niewypelnianeopisy">Szczegółowy cel złożenia wniosku
					<span class="ang"> [Detailed purpose of submitting the application]:</span></td>
				<td class="wypelniane">
					<xsl:for-each select="pf:PozycjeSzczegolowe">
						<xsl:if test="pf:P_5='1'">
							<input type="checkbox" checked="checked" disabled="disabled"/>1. złożenie wniosku 
								<span class="ang"> [submitting the application]</span>
						</xsl:if>
						<xsl:if test="pf:P_5='2'">
							<input type="checkbox" checked="checked" disabled="disabled"/>2. korekta wniosku
								<span class="ang"> [correction of the application]</span>
						</xsl:if>
						<xsl:if test="pf:P_5='3'">
							<input type="checkbox" checked="checked" disabled="disabled"/>3. uzupełnienie wniosku 
								<span class="ang"> [addition to the application]</span>
						</xsl:if>
					</xsl:for-each>
				</td>
			</tr>
			<tr>
				<td class="niewypelnianeopisy" style="width:33%">Naczelnik urzędu skarbowego do którego jest adresowany wniosek 
					<span class="ang"> [Head of the tax office to where the application is addressed]</span></td>
				<td class="wypelniane" style="width:auto">
					<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="PodatnikWHWOZ">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:if test="$sekcja">
				<xsl:value-of select="$sekcja"/>
			</xsl:if>
			Dane identyfikacyjne podatnika<span class="ang"> [Tax payer data]</span>
		</h2>
		<xsl:for-each select="*[local-name() = 'OsobaNiefizyczna']">
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki"> Identyfikator podatkowy NIP
								<span class="ang">[Tax identification number]</span>
							</div>
						<xsl:apply-templates select="*[local-name() = 'NIP']"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">Pełna nazwa
								<span class="ang"> [Full name]</span>
							</div>
						<xsl:apply-templates select="*[local-name()='PelnaNazwa']"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="PlatnikWHWOZ">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:if test="$sekcja">
				<xsl:value-of select="$sekcja"/>
			</xsl:if>
			Dane identyfikacyjne płatnika<span class="ang"> [identification data of tax remitter]</span>
		</h2>
		<xsl:if test="*[local-name() = 'OsobaFizyczna']">
			<xsl:for-each select="*[local-name() = 'OsobaFizyczna']">
				<table class="normalna">
					<tr>
						<xsl:if test="*[local-name() = 'NIP']">
							<td class="wypelniane">
								<div class="opisrubryki"> Identyfikator podatkowy NIP
								<span class="ang">[Tax identification number]</span>
							</div>
								<xsl:apply-templates select="*[local-name() = 'NIP']"/>
							</td>
						</xsl:if>
						<xsl:if test="*[local-name() = 'PESEL']">
							<td class="wypelniane">
								<div class="opisrubryki"> Identyfikator podatkowy numer PESEL
								<span class="ang">[Tax identification number PESEL]</span>
							</div>
								<xsl:apply-templates select="*[local-name() = 'PESEL']"/>
							</td>
						</xsl:if>
					</tr>
				</table>
				<table class="normalna">
					<tr>
						<td class="wypelniane" style="width:40%">
							<div class="opisrubryki">Nazwisko
								<span class="ang"> [Surname]</span>
							</div>
							<xsl:apply-templates select="*[local-name()='Nazwisko']"/>
						</td>
						<td class="wypelniane" style="width:40%">
							<div class="opisrubryki">Pierwsze imię
								<span class="ang"> [First name]</span>
							</div>
							<xsl:apply-templates select="*[local-name()='ImiePierwsze']"/>
						</td>
						<td class="wypelniane" style="width:20%">
							<div class="opisrubryki">Data urodzenia
								<span class="ang"> [Date of birth]</span>
							</div>
							<xsl:apply-templates select="*[local-name()='DataUrodzenia']"/>
						</td>
					</tr>
				</table>
			</xsl:for-each>
		</xsl:if>
		<xsl:if test="*[local-name() = 'OsobaNiefizyczna']">
			<xsl:for-each select="*[local-name() = 'OsobaNiefizyczna']">
				<table class="normalna">
					<tr>
						<td class="wypelniane">
							<div class="opisrubryki"> Identyfikator podatkowy NIP
								<span class="ang">[Tax identification number]</span>
							</div>
							<xsl:apply-templates select="*[local-name() = 'NIP']"/>
						</td>
					</tr>
				</table>
				<table class="normalna">
					<tr>
						<td class="wypelniane">
							<div class="opisrubryki">Pełna nazwa
								<span class="ang"> [Full name]</span>
							</div>
							<xsl:apply-templates select="*[local-name()='PelnaNazwa']"/>
						</td>
					</tr>
				</table>
			</xsl:for-each>
		</xsl:if>
	</xsl:template>
	<xsl:template name="TrescWniosku">
		<xsl:param name="sekcja"/>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<h2 class="tytul-sekcja-blok">
				<xsl:value-of select="$sekcja"/> DANE WNIOSKU<span class="ang"> [APPLICATION DATA]</span>
			</h2>
			<table class="normalna">
				<td class="wypelniane" style="width: 50%">
					<div class="opisrubryki">6. Uzupełnienie/korekta poprzednio złożonego wniosku
						<span class="ang"> [Addition to a previously submitted application form]:</span>
					</div>
					<xsl:if test="pf:P_6='1'">
						<input type="checkbox" checked="checked" disabled="disabled"/>1 - tak
							<span class="ang"> [yes]</span>
						</xsl:if>
					<xsl:if test="pf:P_6='2'">
						<input type="checkbox" checked="checked" disabled="disabled"/>2 - nie
							<span class="ang"> [no]</span>
						</xsl:if>
				</td>
				<td class="wypelniane" style="width: 50%">
					<div class="opisrubryki">6A. Numer referencyjny UPO poprzednio złożonego wniosku, którego dotyczy uzupełnienie/korekta.
						<span class="ang"> [The number of the Official Confirmation of Receipt (UPO) of the submitted application to which the addition applies]</span>
					</div>
					<xsl:value-of select="pf:P_6A"/>
				</td>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="DaneOWyplatach">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> Informacje o wypłatach
			<span class="ang"> [Information on payments]</span>
		</h2>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">24. Rodzaj dochodu 
							<span class="ang"> [Type of income]</span>
						</div>
						<xsl:if test="pf:P_24='1'">
							<input type="checkbox" checked="checked" disabled="disabled"/>dywidendy
								<span class="ang"> [dividends]</span>
						</xsl:if>
						<xsl:if test="pf:P_24='2'">
							<input type="checkbox" checked="checked" disabled="disabled"/>należności licencyjne
								<span class="ang"> [royalities]</span>
						</xsl:if>
						<xsl:if test="pf:P_24='3'">
							<input type="checkbox" checked="checked" disabled="disabled"/>odsetki
								<span class="ang"> [interest]</span>
						</xsl:if>
					</td>
				</tr>
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">25. Treść wniosku 
							<span class="ang"> [Content of the application]</span>
						</div>
						<xsl:value-of select="pf:P_25"/>
					</td>
				</tr>
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">26. Uzupełnienie treści wniosku
							<span class="ang"> [Addition to the content of the application]</span>
						</div>
						<xsl:value-of select="pf:P_26"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="DaneKontaktowe">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> Dane kontaktowe 
			<span class="ang"> [Contact details]</span>
		</h2>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width: 50%">
						<div class="opisrubryki">27. Nr telefonu 
							<span class="ang"> [Phone number]</span>
						</div>
						<xsl:value-of select="pf:P_27"/>
					</td>
					<td class="wypelniane" style="width: 50%">
						<div class="opisrubryki">28. Adres e-mail 
							<span class="ang"> [E-mail address]</span>
						</div>
						<xsl:value-of select="pf:P_28"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="Zalaczniki">
		<xsl:param name="sekcja"/>
		<xsl:param name="pozycja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> Informacja o załączonej kopii dokumentu
				<span class="ang"> [information on attached copies of documents]</span>
		</h2>
		<table class="normalna">
			<tr>
				<td class="puste2" style="width: 4%">
					<div class="opis-tekstowy">Lp.</div>
				</td>
				<td class="puste2" style="width: 20%">
					<div class="opis-tekstowy">Typ pliku
						<span class="ang"> [File type]</span>
					</div>
				</td>
				<td class="puste2" style="width: 20%">
					<div class="opis-tekstowy">Nazwa pliku (bez ścieżki)
						<span class="ang"> [File name (no path)]</span>
					</div>
				</td>
				<td class="puste2" style="width: 56%">
					<div class="opis-tekstowy">Opis pliku
						<span class="ang"> [File description]</span>
					</div>
				</td>
			</tr>
			<xsl:for-each select="pf:InfOKopiiDokumentu">
				<tr>
					<td class="niewypelniane" style="width: 4%">
						<div class="symbol">
							<xsl:value-of select="position()"/>
						</div>
					</td>
					<td class="wypelniane" style="width: 20%">
						<xsl:value-of select="pf:TypPliku"/>
					</td>
					<td class="wypelniane" style="width: 20%">
						<xsl:value-of select="pf:NazwaPliku"/>
					</td>
					<td class="wypelniane" style="width: 54%">
						<xsl:value-of select="pf:OpisPliku"/>
					</td>
				</tr>
			</xsl:for-each>
		</table>
	</xsl:template>
	<xsl:template name="Oswiadczenie">
		<h2 class="tekst">Oświadczenie
			<span class="ang"> [Statement]</span>
		</h2>
		<br/>
		<xsl:if test="pf:Oswiadczenie = '1'">
			<h3 align="justify">Oświadczam, że fakty przedstawione we wniosku o wydanie opinii o stosowaniu preferencji są zgodne z prawdą, oraz że dokumentacja załączona do wniosku jest zgodna z oryginałem.<br/>
				<span class="ang"> [I declare that the facts presented in the application for an opinion on the application of an exemption are true, and that the documentation attached to the application is consistent with the original.]</span>
			</h3>
		</xsl:if>
		<div class="lamstrone"/>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='OkresOd']">
		za okres<span class="ang"> [for period] </span><span class="data">
			<span class="opisrubryki">
				<xsl:call-template name="WezNumerPozycji"/>
			</span>
			<xsl:text>od</xsl:text>
			<span class="ang"> [from] </span>
			<xsl:apply-templates/>
		</span>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='OkresDo']">
		 <span class="data">
			<span class="opisrubryki">
				<xsl:call-template name="WezNumerPozycji"/>
			</span>
			<xsl:text>do</xsl:text>
			<span class="ang"> [to] </span>
			<xsl:apply-templates/>
		</span>
	</xsl:template>
	<xsl:template match="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']">
		<xsl:apply-templates/> 
		<xsl:if test="$nazwy-dla-kodow">
			<span class="nazwa-dla-kodu">
				<xsl:call-template name="ZnajdzWEnumeracji">
					<xsl:with-param name="schema" select="$schema-naczelnikow-urzedow"/>
					<xsl:with-param name="typ" select="'TKodNaczUS'"/>
					<xsl:with-param name="kod" select="text()"/>
				</xsl:call-template>
			</span>
		</xsl:if>
	</xsl:template>
</xsl:stylesheet>