12940
| ID | 12940 |
|---|
| Data | 2023-10-18 |
|---|
| Symbol | 2023/10/18/12940 |
|---|
| Instytucja | Ministerstwo Finansów |
|---|
| Nazwa | ZAP-3 ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
| URI://Dziennik_Ustaw/2022/2500/5/5 | Art. 5 ust. 5 ustawy z dnia 13 października 1995 r. o zasadach ewidencji i identyfikacji podatników i płatników (Dz. U. z 2022 r. poz. 2500) |
|---|
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:pf="http://crd.gov.pl/wzor/2023/10/18/12940/" xmlns:etd="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/09/13/eD/DefinicjeTypy/" version="1.0">
<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/09/13/eD/DefinicjeSzablony/Posredni_wspolne_v14-0E.xsl"/>
<xsl:param name="nazwy-dla-kodow" select="true()"/>
<xsl:param name="schema-naczelnikow-urzedowEX" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/10/12/eD/KodyNaczelnikowUrzedowSkarbowychExNaczWUS/KodyNaczelnikowUrzedowSkarbowychExNaczWUS_v4-0E.xsd'"/>
<xsl:param name="schema-krajow" select="'http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2023/09/06/eD/KodyKrajow/KodyKrajow_v13-0E.xsd'"/>
<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:template name="TytulDokumentu">ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM</xsl:template>
<xsl:template name="StyleDlaFormularza">
<style type="text/css">
.tlo-formularza { background-color:#D3D3D3;}
</style>
</xsl:template>
<xsl:template match="pf:ZgloszenieNIP">
<div class="deklaracja">
<xsl:call-template name="NaglowekTechniczny">
<xsl:with-param name="naglowek" select="pf:Naglowek"/>
<xsl:with-param name="uzycie" select="'deklaracja'"/>
</xsl:call-template>
<xsl:call-template name="NaglowekTytulowy">
<xsl:with-param name="uzycie" select="'deklaracja'"/>
<xsl:with-param name="nazwa">ZGŁOSZENIE AKTUALIZACYJNE OSOBY FIZYCZNEJ BĘDĄCEJ PODATNIKIEM</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="Pouczenie"/>
<xsl:call-template name="MiejsceICelZAP3">
<xsl:with-param name="sekcja">A.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="DaneSkladajacego">
<xsl:with-param name="sekcja">B.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="DataWypelnienia">
<xsl:with-param name="sekcja">C.</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="Przypis"/>
</div>
</xsl:template>
<xsl:template name="MiejsceICelZAP3">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> MIEJSCE ZŁOŻENIA ZGŁOSZENIA</h2>
<table class="normalna">
<tr>
<td class="niewypelnianeopisy" style="width:33%">Naczelnik urzędu skarbowego, do którego jest adresowane zgłoszenie</td>
<td class="wypelniane" style="width:auto">
<xsl:apply-templates select="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']"/>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="DaneSkladajacego">
<xsl:param name="sekcja"/>
<h2 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> DANE SKŁADAJĄCEGO</h2>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>1. DANE IDENTYFIKACYJNE<br/>
<span class="opis-tekstowy">Poz. 7-9 należy wypełnić tylko w przypadku dokonujących pierwszego zgłoszenia ZAP-3:<br/>
- poz. 7 i 8 dotyczą osób, które przed uzyskaniem numeru PESEL miały status podatnika,<br/>
- poz. 9 dotyczy osób, które przed uzyskaniem numeru PESEL miały nadany identyfikator podatkowy NIP.
</span>
</h3>
<xsl:for-each select="pf:Podmiot1/pf:OsobaFizyczna">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:100%">
<div class="opisrubryki">Identyfikator podatkowy numer PESEL</div>
<xsl:apply-templates select="pf:PESEL"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Nazwisko</div>
<xsl:apply-templates select="pf:Nazwisko"/>
</td>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Pierwsze imię</div>
<xsl:apply-templates select="pf:ImiePierwsze"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:30%">
<div class="opisrubryki">Imię ojca</div>
<xsl:apply-templates select="pf:ImieOjca"/>
</td>
<td class="wypelniane" style="width:40%">
<div class="opisrubryki">Imię matki</div>
<xsl:apply-templates select="pf:ImieMatki"/>
</td>
<td class="wypelniane" style="width:30%">
<div class="opisrubryki">Identyfikator podatkowy NIP</div>
<xsl:apply-templates select="pf:NIP"/>
</td>
</tr>
</table>
</xsl:for-each>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>2. ADRES MIEJSCA ZAMIESZKANIA</h3>
<xsl:for-each select="pf:Podmiot1/pf:AdresZamieszkania">
<xsl:apply-templates/>
</xsl:for-each>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>3. DANE KONTAKTOWE<br/>
<span class="opis-tekstowy">Podanie informacji w części B.3. nie jest obowiązkowe. Wpisane niżej dane aktualizują poprzedni stan danych.</span>
</h3>
<xsl:for-each select="pf:Kontakt">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:80%">
<div class="opisrubryki">Telefon</div>
<xsl:apply-templates select="pf:Telefon"/>
</td>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">Rezygnacja z telefonu</div>
<xsl:if test="pf:RezygnacjaZTelefonu ='T'">
<input type="checkbox" checked="checked" disabled="disabled"/>Tak
</xsl:if>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:80%">
<div class="opisrubryki">Faks</div>
<xsl:apply-templates select="pf:Faks"/>
</td>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">Rezygnacja z faksu</div>
<xsl:if test="pf:RezygnacjaZFaksu ='T'">
<input type="checkbox" checked="checked" disabled="disabled"/>Tak
</xsl:if>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:80%">
<div class="opisrubryki">E-mail</div>
<xsl:apply-templates select="pf:Email"/>
</td>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">Rezygnacja z e-mail</div>
<xsl:if test="pf:RezygnacjaZAdresuEmail ='T'">
<input type="checkbox" checked="checked" disabled="disabled"/>Tak
</xsl:if>
</td>
</tr>
</table>
<h4 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>3.1. ADRES DO DORĘCZEŃ
<span class="opis-tekstowy">
<br/>Należy wypełnić tylko wówczas, gdy adres do doręczeń jest inny niż adres miejsca zamieszkania (w części B.2.).
</span>
</h4>
<xsl:for-each select="pf:AdresDoDoreczen">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:75%">
<div class="opisrubryki">Adres do doręczeń<sup>1)</sup>
</div>
<xsl:if test="pf:AdresDoDoreczen1 = '1'">
<input type="checkbox" checked="checked" disabled="disabled"/>1. tak
</xsl:if>
<xsl:if test="pf:AdresDoDoreczen2 = '2'">
<input type="checkbox" checked="checked" disabled="disabled"/>2. nie
</xsl:if>
</td>
</tr>
</table>
<xsl:if test="pf:AdresPol/@rodzajAdresu='DOR'">
<xsl:for-each select="pf:AdresPol">
<xsl:call-template name="AdresTabela"/>
</xsl:for-each>
</xsl:if>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:100%">
<div class="opisrubryki">Utrata aktualności ostatnio wskazanego adresu do doręczeń, innego niż adres w części B.2.</div>
<xsl:if test="pf:UtrataAktualnosciAdresu ='1'">
<input type="checkbox" checked="checked" disabled="disabled"/>1. tak
</xsl:if>
</td>
</tr>
</table>
</xsl:for-each>
<h4 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>3.2. ADRES SKRYTKI POCZTOWEJ<br/>
<span class="opis-tekstowy">Podanie informacji o skrytce pocztowej nie jest obowiązkowe.</span>
</h4>
<xsl:for-each select="pf:AdresSkrytki">
<table class="normalna">
<tr>
<td class="wypelniane" style="width:75%">
<div class="opisrubryki">Adres do doręczeń<sup>1)</sup>
</div>
<xsl:if test="pf:AdresSkrytki1 = '1'">
<input type="checkbox" checked="checked" disabled="disabled"/>1. tak
</xsl:if>
<xsl:if test="pf:AdresSkrytki2 = '2'">
<input type="checkbox" checked="checked" disabled="disabled"/>2. nie
</xsl:if>
</td>
</tr>
</table>
<xsl:if test="pf:AdresPol/@rodzajAdresu='SKR'">
<xsl:for-each select="pf:AdresPol">
<xsl:call-template name="AdresTabela"/>
</xsl:for-each>
</xsl:if>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Rezygnacja</div>
<xsl:if test="pf:Rezygnacja ='1'">
<input type="checkbox" checked="checked" disabled="disabled"/>1. tak
</xsl:if>
</td>
</tr>
</table>
</xsl:for-each>
</xsl:for-each>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/>4. RACHUNEK OSOBISTY - DO ZWROTU PODATKU LUB NADPŁATY<br/>
<span class="opis-tekstowy">Podanie informacji o rachunku bankowym lub rachunku w spółdzielczej kasie oszczędnościowo–kredytowej (poz. 48-52) nie jest obowiązkowe, jeżeli składający nie wybiera tej formy zwrotu podatku lub nadpłaty. Na wskazany rachunek będą dokonywane ewentualne zwroty nadpłaty lub podatku. Można podać jedynie taki rachunek, którego posiadaczem lub współposiadaczem jest składający. Wpisane niżej dane dotyczące rachunku aktualizują poprzedni stan danych. Zaznaczenie kwadratu w poz. 53 oznacza rezygnację przez składającego z otrzymywania ewentualnego zwrotu nadpłaty lub podatku na rachunek osobisty (również z powodu likwidacji rachunku).</span>
</h3>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">48. Kraj siedziby banku (oddziału) (wypełnić wyłącznie dla rachunku zagranicznego)</div>
<xsl:for-each select="pf:RachunekBankowy/pf:KrajSiedzibyBanku">
<xsl:call-template name="PokazKodKraju"/>
</xsl:for-each>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Kod SWIFT (wypełnić wyłącznie dla rachunku zagranicznego)</div>
<xsl:apply-templates select="pf:RachunekBankowy/pf:KodSWIFT"/>
</td>
<td class="wypelniane" style="width:50%">
<div class="opisrubryki">Waluta, w której prowadzony jest rachunek</div>
<xsl:apply-templates select="pf:RachunekBankowy/pf:Waluta"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Posiadacz rachunku (należy wskazać imię i nazwisko posiadacza, a w przypadku gdy jest to rachunek wspólny – imiona i nazwiska wszystkich współposiadaczy):</div>
<xsl:apply-templates select="pf:RachunekBankowy/pf:PosiadaczRachunku"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:80%">
<div class="opisrubryki">Pełny numer rachunku</div>
<span class="opis-tekstowy">Numer IBAN: </span>
<xsl:apply-templates select="pf:RachunekBankowy/pf:NrRachunkuBankowego"/>
</td>
<td class="wypelniane" style="width:20%">
<div class="opisrubryki">Rezygnacja przez składającego z otrzymywania ewentualnego zwrotu podatku lub nadpłaty na rachunek osobisty (również z powodu likwidacji rachunku):</div>
<xsl:for-each select="pf:RezygnacjaZRachunkuBankowego">
<xsl:if test=". ='T'">
<input type="checkbox" checked="checked" disabled="disabled"/>Tak
</xsl:if>
</xsl:for-each>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="DataWypelnienia">
<xsl:param name="sekcja"/>
<h3 class="tytul-sekcja-blok">
<xsl:value-of select="$sekcja"/> PODPIS SKŁADAJĄCEGO / DANE I PODPIS OSOBY REPREZENTUJĄCEJ SKŁADAJĄCEGO</h3>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:100%">
<div class="opisrubryki">Data wypełnienia zgłoszenia</div>
<xsl:value-of select="pf:Naglowek/pf:Data"/>
</td>
</tr>
</table>
</xsl:template>
<xsl:template name="Pouczenie">
<xsl:if test="pf:Pouczenie = '1'">
<table class="normalna">
<td class="niewypelnianeopisy">
<p>Formularz przeznaczony dla osoby fizycznej, spełniającej łącznie poniższe kryteria:</p>
<ul>- ma nadany numer PESEL,<br/>
- nie prowadzi działalności gospodarczej,<br/>
- nie jest zarejestrowanym podatnikiem podatku od towarów i usług,<br/>
- nie jest płatnikiem podatków,<br/>
- nie jest płatnikiem składek na ubezpieczenia społeczne oraz ubezpieczenie zdrowotne.</ul>
<p>Formularz służy do zgłoszenia: aktualnego adresu miejsca zamieszkania (część B.2.), danych kontaktowych (część B.3.) oraz informacji dotyczących rachunku osobistego (część B.4.).</p>
</td>
</table>
<table class="normalna">
<td class="niewypelnianeopisy">
<p>Podstawa Prawna - Ustawa z dnia 13 października 1995 r. o zasadach ewidencji i identyfikacji podatników i płatników (Dz. U. z 2020 r. poz. 170, z późn. zm.), zgodnie z art. 9 ust. 1d.</p>
</td>
</table>
</xsl:if>
</xsl:template>
<xsl:template name="Przypis">
<h3 align="justify">
<font size="2pt">
<sup>1)</sup>
Doręczanie następuje zgodnie z przepisami ustawy z dnia 29 sierpnia 1997 r. - Ordynacja podatkowa (Dz. U. z 2020 r. poz. 1325, z późn. zm.) na adres miejsca zamieszkania, o ile nie wskazano na adres do doręczeń albo skrytki pocztowej.
</font>
</h3>
</xsl:template>
<!--<xsl:template match="pf:ObywatelstwoPL | pf:KodKrajuObywatelstwoPozostale | pf:KodkrajuWydaniaNrId">
<xsl:call-template name="PokazKodKraju"/>
<xsl:if test="position() != last()">
<br/>
</xsl:if>
</xsl:template>-->
<xsl:template match="pf:NrId | pf:RodzajNrId">
<xsl:apply-templates/>
<xsl:if test="position() != last()">
<br/>
</xsl:if>
</xsl:template>
<xsl:template match="*[local-name()='Naglowek']/*[local-name()='KodUrzedu']">
<xsl:apply-templates/>
<xsl:if test="$nazwy-dla-kodow">
<span class="nazwa-dla-kodu">
<xsl:call-template name="ZnajdzWEnumeracji">
<xsl:with-param name="schema" select="$schema-naczelnikow-urzedowEX"/>
<xsl:with-param name="typ" select="'TKodNaczExWUS'"/>
<xsl:with-param name="kod" select="text()"/>
</xsl:call-template>
</span>
</xsl:if>
</xsl:template>
<xsl:template match="*[local-name()='KodKraju'] | *[local-name()='KodkrajuWydania'] |*[local-name()='KodkrajuWydaniaNrId'] |*[local-name()='KodKrajuUrodzenia'] | *[local-name()='P_D3'] |*[local-name()='KodKrajuWydaniaDokumentuTozsamosci']" name="PokazKodKraju">
<xsl:apply-templates/>
<xsl:if test="$nazwy-dla-kodow">
<span class="nazwa-dla-kodu">
<xsl:text>(</xsl:text>
<xsl:call-template name="ZnajdzWEnumeracji">
<xsl:with-param name="schema" select="$schema-krajow"/>
<xsl:with-param name="typ" select="'TKodKraju'"/>
<xsl:with-param name="kod" select="text()"/>
</xsl:call-template>
<xsl:text>)</xsl:text>
</span>
</xsl:if>
</xsl:template>
<xsl:template match="*[local-name()='AdresPol'] | *[local-name()='AdresZagr']" name="AdresTabela">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Kraj</div>
<xsl:apply-templates select="*[local-name()='KodKraju']"/>
</td>
<td class="wypelniane" style="width:40%">
<div class="opisrubryki">Województwo</div>
<xsl:apply-templates select="*[local-name()='Wojewodztwo']"/>
</td>
<td class="wypelniane" style="width:40%">
<div class="opisrubryki">Powiat</div>
<xsl:apply-templates select="*[local-name()='Powiat']"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane" style="width:35%">
<div class="opisrubryki">Gmina</div>
<xsl:apply-templates select="*[local-name()='Gmina']"/>
</td>
<td class="wypelniane">
<div class="opisrubryki">Ulica</div>
<xsl:apply-templates select="*[local-name()='Ulica']"/>
</td>
<td class="wypelniane" style="width:10%">
<div class="opisrubryki">Nr domu</div>
<xsl:apply-templates select="*[local-name()='NrDomu']"/>
</td>
<td class="wypelniane" style="width:10%">
<div class="opisrubryki">Nr lokalu</div>
<xsl:apply-templates select="*[local-name()='NrLokalu']"/>
</td>
</tr>
</table>
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Miejscowość</div>
<xsl:apply-templates select="*[local-name()='Miejscowosc']"/>
</td>
<td class="wypelniane">
<div class="opisrubryki">Kod pocztowy</div>
<xsl:apply-templates select="*[local-name()='KodPocztowy']"/>
</td>
<xsl:if test="*[local-name()='Poczta']">
<td class="wypelniane">
<div class="opisrubryki">Poczta</div>
<xsl:apply-templates select="*[local-name()='Poczta']"/>
</td>
</xsl:if>
</tr>
</table>
<xsl:if test="*[local-name()='NrSkrytkiPocztowej']">
<table class="normalna">
<tr>
<td class="wypelniane">
<div class="opisrubryki">Numer skrytki pocztowej</div>
<xsl:apply-templates select="*[local-name()='NrSkrytkiPocztowej']"/>
</td>
</tr>
</table>
</xsl:if>
</xsl:template>
<xsl:template name="ZnajdzWEnumeracji">
<xsl:param name="schema"/>
<xsl:param name="typ"/>
<xsl:param name="kod"/>
<xsl:variable name="wschema" select="document($schema)"/>
<xsl:value-of select="$wschema//xs:simpleType[@name=$typ]// xs:enumeration[@value = $kod]//xs:documentation"/>
</xsl:template>
</xsl:stylesheet>