11947
| ID | 11947 |
|---|
| Data | 2022-11-30 |
|---|
| Symbol | 2022/11/30/11947 |
|---|
| Instytucja | Ministerstwo Klimatu i Środowiska |
|---|
| Nazwa | Wniosek o wypłatę dodatku elektrycznego dla gospodarstw domowych |
|---|
| Czy Aktualny | 1 |
|---|
Ustawy (1)
| URI://Dziennik_Ustaw/2022/2127/33/4 | Ustawa z dnia 7 października 2022 r. o szczególnych rozwiązaniach służących ochronie odbiorców energii elektrycznej w 2023 roku w związku z sytuacją na rynku energii elektrycznej |
|---|
Pliki
Styl
<?xml version="1.0" encoding="UTF-8"?><!-- Version 1.0 --><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:adr="http://crd.gov.pl/xml/schematy/adres/2009/11/09/" xmlns:ds="http://www.w3.org/2000/09/xmldsig#" xmlns:inst="http://crd.gov.pl/xml/schematy/instytucja/2009/11/16/" xmlns:meta="http://crd.gov.pl/xml/schematy/meta/2009/11/16/" xmlns:oso="http://crd.gov.pl/xml/schematy/osoba/2009/11/16/" xmlns:str="http://crd.gov.pl/xml/schematy/struktura/2009/11/16/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:wnio="http://crd.gov.pl/wzor/2022/11/30/11947/" xmlns:xls="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="/">
<xsl:apply-templates select="wnio:Dokument"/>
</xsl:template>
<xsl:template match="wnio:Dokument">
<html lang="pl">
<head>
<meta name="viewport" content="width=device-width, initial-scale=1"/>
<title>
Dodatek elektryczny dla gospodarstw domowych
</title>
</head>
<body>
<div class="du-view du-no-mt">
<section>
<div class="du-col-12 du-left du-no-mt du-margin-bottom-15">
<h1>
Dodatek elektryczny dla gospodarstw domowych
</h1>
</div>
</section>
<section>
<xsl:call-template name="Urzad"/>
</section>
<section>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Adres gospodarstwa domowego, którego ma dotyczyć dodatek</h2>
</div>
<xsl:call-template name="Adres">
<xsl:with-param name="adresForm" select="wnio:TrescDokumentu/wnio:Adres"/>
</xsl:call-template>
</section>
<xsl:if test="(string-length(wnio:TrescDokumentu/wnio:DaneKontaktowe/adr:Telefon) > 0) or (string-length(wnio:TrescDokumentu/wnio:DaneKontaktowe/wnio:Email) > 0)">
<section>
<xsl:call-template name="DaneKontaktowe"/>
</section>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:AdresDoKorespondencji/wnio:InnyAdresKorespondencji='true'">
<section>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Adres korespondencyjny</h2>
</div>
<xsl:call-template name="Adres">
<xsl:with-param name="adresForm" select="wnio:TrescDokumentu/wnio:AdresDoKorespondencji/wnio:Adres"/>
</xsl:call-template>
</section>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:DaneRozliczeniowe/wnio:RodzajRozliczenia='RACHUNEK_ROZLICZENIOWY'">
<section>
<xsl:call-template name="DaneRozliczeniowe"/>
</section>
</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:DaneRozliczeniowe/wnio:RodzajRozliczenia='PRZEKAZ_POCZTOWY'">
<section>
<xsl:call-template name="PrzekazPocztowy"/>
</section>
</xsl:if>
<section>
<xsl:call-template name="DaneGospodarstwaDomowego"/>
</section>
<section>
<xsl:call-template name="ZrodloCiepla"/>
</section>
<section>
<xsl:call-template name="ZuzytaEnergia"/>
</section>
<section>
<xsl:call-template name="Oswiadczenia"/>
</section>
</div>
<xsl:call-template name="styleCSS"/>
</body>
</html>
</xsl:template>
<xsl:template name="Urzad">
<div class="du-col-12 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Urząd, który przyjmie twój wniosek</h2>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Dane urzędu: </span>
<span class="du-bold du-field">
<xsl:value-of select="wnio:TrescDokumentu/wnio:Urzad"/>
</span>
</div>
</xsl:template>
<xsl:template name="Adres">
<xsl:param name="adresForm"/>
<div class="du-col-12 du-left du-no-mt">
<div class="du-col-12 du-no-mt">
<span class="du-field">Miejscowość: </span>
<span class="du-bold du-field">
<xsl:value-of select="$adresForm/wnio:Miejscowosc"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Województwo: </span>
<span class="du-bold du-field">
<xsl:value-of select="$adresForm/wnio:Wojewodztwo"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Powiat: </span>
<span class="du-bold du-field">
<xsl:value-of select="$adresForm/wnio:Powiat"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Gmina: </span>
<span class="du-bold du-field">
<xsl:value-of select="$adresForm/wnio:Gmina"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Kod pocztowy: </span>
<span class="du-bold du-field">
<xsl:value-of select="$adresForm/adr:KodPocztowy"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Ulica: </span>
<span class="du-bold du-field">
<xsl:choose>
<xsl:when test="$adresForm/wnio:Ulica!=''">
<xsl:value-of select="$adresForm/wnio:Ulica"/>
</xsl:when>
<xsl:otherwise>
<xsl:if test="$adresForm/wnio:BrakUlicy='true'">
<xsl:value-of select="concat(' ', 'Miejscowość nie ma ulicy')"/>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</span>
</div>
<div class="du-col-12 du-no-mt nowrap">Numer domu:
<span class="du-bold">
<xsl:value-of select="$adresForm/wnio:Budynek"/>
</span>
</div>
<div class="du-col-12 du-no-mt nowrap">Numer lokalu:
<span class="du-bold">
<xsl:choose>
<xsl:when test="$adresForm/adr:Lokal!=''">
<xsl:value-of select="$adresForm/adr:Lokal"/>
</xsl:when>
<xsl:otherwise>
<xsl:if test="$adresForm/wnio:BrakLokalu='true'">
<xsl:value-of select="concat(' ', 'Brak numeru lokalu')"/>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</span>
</div>
</div>
</xsl:template>
<xsl:template name="DaneKontaktowe">
<xsl:param name="daneKontaktowe" select="wnio:TrescDokumentu/wnio:DaneKontaktowe"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Dane kontaktowe</h2>
</div>
<div class="du-col-12 du-left du-no-mt">
<xsl:if test="string-length($daneKontaktowe/wnio:Email) > 0">
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Adres e-mail: </span>
<span class="du-bold du-field">
<xsl:value-of select="$daneKontaktowe/wnio:Email"/>
</span>
</div>
</xsl:if>
<xsl:if test="string-length($daneKontaktowe/adr:Telefon) > 0">
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Numer telefonu: </span>
<span class="du-bold du-field">
<xsl:call-template name="tokenize">
<xsl:with-param name="input" select="$daneKontaktowe/adr:Telefon"/>
<xsl:with-param name="length" select="3"/>
</xsl:call-template>
</span>
</div>
</xsl:if>
</div>
</xsl:template>
<xsl:template name="DaneRozliczeniowe">
<xsl:param name="daneRozliczeniowe" select="wnio:TrescDokumentu/wnio:DaneRozliczeniowe"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Numer rachunku, na który zostanie przekazany dodatek</h2>
</div>
<div class="du-col-12 du-left du-no-mt">
<div class="du-col-12 du-no-mt">
<span class="du-field">Numer rachunku bankowego lub rachunku w spółdzielczej kasie oszczędnościowo-kredytowej: </span>
<span class="du-bold du-field">
<span><xsl:value-of select="substring($daneRozliczeniowe/wnio:NumerRachunkuRozliczeniowego, 1, 2)"/> </span>
<xsl:call-template name="tokenize">
<xsl:with-param name="input" select="substring($daneRozliczeniowe/wnio:NumerRachunkuRozliczeniowego, 3)"/>
</xsl:call-template>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Nazwisko właściciela rachunku: </span>
<span class="du-bold du-field">
<xsl:value-of select="$daneRozliczeniowe/wnio:Nazwisko"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Imię właściciela rachunku: </span>
<span class="du-bold du-field">
<xsl:value-of select="$daneRozliczeniowe/wnio:Imie"/>
</span>
</div>
</div>
</xsl:template>
<xsl:template name="tokenize">
<xsl:param name="input"/>
<xsl:param name="length" select="4"/>
<span><xsl:value-of select="substring($input,1,$length)"/> </span>
<xsl:if test="substring($input,$length+1)">
<xsl:call-template name="tokenize">
<xsl:with-param name="input" select="substring($input,$length+1)"/>
<xsl:with-param name="length" select="$length"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template name="PrzekazPocztowy">
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Sposób otrzymania dodatku</h2>
</div>
<div class="du-col-12 du-left du-no-mt">
<div class="du-col-12 du-no-mt">
<span class="du-field">Forma: </span>
<span class="du-bold du-field">PRZEKAZ POCZTOWY</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">
<xsl:if test="wnio:TrescDokumentu/wnio:AdresDoKorespondencji/wnio:InnyAdresKorespondencji='true'">
Przekaz pocztowy otrzymasz na podany adres do korespondencji.</xsl:if>
<xsl:if test="wnio:TrescDokumentu/wnio:AdresDoKorespondencji/wnio:InnyAdresKorespondencji='false'">
Przekaz pocztowy otrzymasz na podany adres.</xsl:if>
</span>
</div>
</div>
</xsl:template>
<xsl:template name="DaneGospodarstwaDomowego">
<xsl:param name="daneGospodarstwa" select="wnio:TrescDokumentu/wnio:DaneGospodarstwaDomowego"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Dane osób gospodarstwa domowego</h2>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Typ gospodarstwa domowego: </span>
<span class="du-bold du-field">
<xsl:value-of select="$daneGospodarstwa/wnio:RodzajGospodarstwaDomowego"/>
</span>
</div>
<xsl:if test="$daneGospodarstwa/wnio:RodzajGospodarstwaDomowego='WIELOOSOBOWE'">
<div class="du-col-12 du-no-mt">
<span class="du-field">Liczba osób: </span>
<span class="du-bold du-field">
<xsl:value-of select="$daneGospodarstwa/wnio:IloscOsob"/>
</span>
</div>
</xsl:if>
<xsl:if test="count($daneGospodarstwa/wnio:OsobyGospodarstwo/wnio:DaneOsoby) > 0">
<xsl:for-each select="$daneGospodarstwa/wnio:OsobyGospodarstwo/wnio:DaneOsoby">
<h2 class="du-h2 du-margin-top-15">
<xsl:value-of select="position()"/>. Dane osoby z gospodarstwa domowego
<xsl:if test="position()='1'">
i wnioskodawcy
</xsl:if>
</h2>
<xsl:call-template name="DaneOsoby"/>
</xsl:for-each>
</xsl:if>
</xsl:template>
<xsl:template name="DaneOsoby">
<div class="du-col-12 du-no-mt">
<span class="du-field">Nazwisko: </span>
<span class="du-bold du-field">
<xsl:value-of select="wnio:Nazwisko"/>
</span>
</div>
<div class="du-col-12 du-no-mt">
<span class="du-field">Imię (imiona): </span>
<span class="du-bold du-field">
<xsl:value-of select="wnio:Imie"/>
<xsl:if test="string-length(wnio:ImieDrugie) > 0">
<xsl:value-of select="wnio:ImieDrugie"/>
</xsl:if>
</span>
</div>
<xsl:choose>
<xsl:when test="string-length(oso:PESEL) > 0">
<div class="du-col-12 du-no-mt">
<span class="du-field">Numer PESEL: </span>
<span class="du-bold du-field">
<xsl:value-of select="oso:PESEL"/>
</span>
</div>
</xsl:when>
<xsl:otherwise>
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Rodzaj dokumentu: </span>
<span class="du-bold du-field">
<xsl:if test="wnio:RodzajDokumentu = 'PASZPORT'">
<span>Paszport</span>
</xsl:if>
<xsl:if test="wnio:RodzajDokumentu = 'KARTA_POBYTU'">
<span>Karta pobytu</span>
</xsl:if>
<xsl:if test="wnio:RodzajDokumentu = 'INNY_DOKUMENT'">
<span>Inny dokument</span>
</xsl:if>
</span>
</div>
<div class="du-col-12 du-no-mt">
<xsl:if test="wnio:RodzajDokumentu != 'INNY_DOKUMENT'">
<span class="du-field nowrap">Seria i numer dokumentu: </span>
</xsl:if>
<xsl:if test="wnio:RodzajDokumentu = 'INNY_DOKUMENT'">
<span class="du-field nowrap">Numer dokumentu: </span>
</xsl:if>
<span class="du-bold du-field">
<xsl:value-of select="wnio:SeriaNumerDokumentu"/>
</span>
</div>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="ZrodloCiepla">
<xsl:param name="zrodloOgrzewania" select="wnio:TrescDokumentu/wnio:ZrodloOgrzewania"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Źródła ciepła</h2>
</div>
<div class="du-col-12 du-left du-no-mt">
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Główne źródło ogrzewania: </span>
<span class="du-bold du-field">
<xsl:if test="$zrodloOgrzewania = 'POMPA_CIEPLA'">
<span>Pompa ciepła</span>
</xsl:if>
<xsl:if test="$zrodloOgrzewania = 'OGRZEWANIE_BOJLER_ELEKTRYCZNY'">
<span>Ogrzewanie elektryczne / bojler elektryczny</span>
</xsl:if>
</span>
</div>
</div>
</xsl:template>
<xsl:template name="ZuzytaEnergia">
<xsl:param name="iloscEnergii" select="wnio:TrescDokumentu/wnio:IloscEnergii"/>
<xsl:param name="zalaczniki" select="wnio:TrescDokumentu/str:Zalaczniki"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">Energia zużyta w twoim gospodarstwie domowym w 2021 r.</h2>
</div>
<div class="du-col-12 du-left du-no-mt">
<div class="du-col-12 du-no-mt">
<span class="du-field nowrap">Wartość: </span>
<span class="du-bold2 du-field">
<xsl:if test="$iloscEnergii = 'DO_5_MWH'">
<span>Do 5 MWh (kwota dodatku 1000 zł)</span>
</xsl:if>
<xsl:if test="$iloscEnergii = 'PONAD_5_MWH'">
<span>Ponad 5 MWh (kwota dodatku 1500 zł)</span>
</xsl:if>
</span>
</div>
<xsl:if test="count($zalaczniki/str:Zalacznik) > 0 and $iloscEnergii = 'PONAD_5_MWH'">
<ol class="du-margin-top-0 du-margin-bottom-0">
<xsl:for-each select="$zalaczniki/str:Zalacznik[@nazwaPliku != '']">
<li>
<div class="du-col-12 du-no-mt">
<span class="du-field">Załącznik: </span>
<span class="du-bold">
<xsl:if test="@kodowanie='base64'">
<xsl:value-of select="@nazwaPliku"/>
<xsl:if test="string-length(str:OpisZalacznika) > 0">-</xsl:if>
<xsl:if test="string-length(str:OpisZalacznika) > 0">
<xsl:value-of select="str:OpisZalacznika"/>
</xsl:if>
</xsl:if>
<xsl:if test="@kodowanie='URI'">
<xsl:value-of select="@nazwaPliku"/>
</xsl:if>
</span>
</div>
</li>
</xsl:for-each>
</ol>
</xsl:if>
</div>
</xsl:template>
<xsl:template name="Oswiadczenia">
<xsl:param name="oswiadczenia" select="wnio:TrescDokumentu/wnio:Oswiadczenia"/>
<div class="du-col-12 du-top-line du-margin-top-20 du-no-mt">
<h2 class="du-h2 du-margin-top-15">
Oświadczenia
</h2>
</div>
<xsl:if test="$oswiadczenia='true'">
<div class="du-col-12 du-no-mt">
<span class="du-field">Oświadczam, że:</span>
</div>
<div class="du-col-12 du-left du-no-mt">
<ul class="du-list">
<li>
<span class="du-list-item">
osoby wymienione we wniosku są członkami mojego gospodarstwa domowego,
</span>
</li>
<li>
<span class="du-list-item">
wszystkie dane we wniosku są prawdziwe i aktualne,
</span>
</li>
<li>
<span class="du-list-item">
członkowie gospodarstwa domowego mieszkają pod adresem, pod którym nie jest wykorzystywana energia elektryczna z mikroinstalacji
</span>
<p class="du-margin-top-0 du-margin-bottom-0 du-margin-left-15">art. 2 pkt 19 i art. 4 ustawy z dnia 20 lutego 2015 r. o odnawialnych źródłach energii (Dz. U. z 2022 r. poz. 1378 i 1383)</p>
</li>
<li>
<span class="du-list-item">
gospodarstwo domowe nie skorzystało z dodatku węglowego
</span>
<p class="du-margin-top-0 du-margin-bottom-0 du-margin-left-15">art. 2 ust. 1 ustawy z dnia 5 sierpnia 2022 r. o dodatku węglowym (Dz. U. poz. 1692, z późn. zm.)</p>
</li>
<li>
<span class="du-list-item">
gospodarstwo domowe nie zakupiło paliwa stałego w cenie 996,60 zł brutto ani niższej za tonę od przedsiębiorcy, któremu przysługiwała za to rekompensata
</span>
<p class="du-margin-top-0 du-margin-bottom-0 du-margin-left-15">art. 2 ust. 1 ustawy z dnia 23 czerwca 2022 r. o szczególnych rozwiązaniach służących ochronie odbiorców niektórych paliw stałych w związku z sytuacją na rynku tych paliw (Dz. U. poz. 1477 i 1692)</p>
</li>
<li>
<span class="du-list-item">
gospodarstwo domowe nie skorzystało z dodatku do niektórych źródeł ciepła dla gospodarstw domowych, ani o niego nie wnioskowało
</span>
<p class="du-margin-top-0 du-margin-bottom-0 du-margin-left-15">art. 24 ust. 1 ustawy z dnia 15 września 2022 r. o szczególnych rozwiązaniach w zakresie niektórych źródeł ciepła w związku z sytuacją na rynku paliw (Dz. U. poz. 1967)</p>
</li>
<li>
<span class="du-list-item">
wiem o odpowiedzialności karnej za złożenie fałszywego oświadczenia
</span>
<p class="du-margin-top-0 du-margin-bottom-0 du-margin-left-15">art. 34 ust. 4 ustawy z dnia 7 października 2022 r. o szczególnych rozwiązaniach służących ochronie odbiorców energii elektrycznej w 2023 roku w związku z sytuacją na rynku energii elektrycznej</p>
</li>
</ul>
</div>
</xsl:if>
</xsl:template>
<xsl:template name="styleCSS">
<style type="text/css">
.du-view article,
.du-view footer,
.du-view header,
.du-view section {
display: block;
}
.du-view div {
font-family: Arial, Helvetica, sans-serif;
font-size: 16px;
line-height: 140%;
word-wrap: break-word;
display: inline-block;
padding: 5px;
}
.du-view,
.du-view * {
-webkit-box-sizing: border-box;
-moz-box-sizing: border-box;
box-sizing: border-box;
}
.du-view {
width: 100%;
height: 100%;
padding: 1%;
line-height: 130%;
}
.du-view h1,
.du-view .h1 {
font-family: Arial, Helvetica, sans-serif;
font-size: 42px;
line-height: 52px;
font-weight: bold;
margin-bottom: 2px;
margin-top: 0;
}
.du-view h2,
.du-view .h2 {
font-family: Arial, Helvetica, sans-serif;
font-size: 24px;
line-height: 34px;
font-weight: bold;
margin-bottom: 12px;
}
.du-view h3,
.du-view .h3 {
font-family: Arial, Helvetica, sans-serif;
font-size: 16px;
font-weight: bold;
margin: 0px 0px;
}
ol {
padding-left: 0;
}
ol li {
list-style: none;
}
/*grid and style for
dotted*/
.du-col-12 {
width: 100%;
}
/*other style*/
.du-text-transform-none {
text-transform: none !important;
}
div .du-no-mt {
padding-left: 0px;
}
.du-left {
text-align: left;
float: left;
}
.du-top-line {
border-top: 1px solid #DCDCDC;
}
.du-bottom-line {
border-bottom: 1px solid #DCDCDC;
}
.du-border {
border: 1px solid black;
min-width: 30px;
min-height: 30px;
margin-bottom: 1px;
}
.du-bold {
font-weight: bold;
text-transform: uppercase;
}
.du-bold2 {
font-weight: bold;
text-transform: none;
}
.du-list {
padding-left: 18px;
margin: 0 0 0 0;
}
.inline {
display: inline;
}
.nowrap {
white-space:nowrap
}
@media print {
.du-view {
font-size: 12px;
}
.du-view h3,
.du-view .h3 {
font-size: 14px;
font-weight: bold;
margin-top: 1%;
margin-bottom: 0;
}
.du-view div {
line-height: 100%;
}
.du-col-12 {
width: 100%;
}
.du-view div {
margin-top: 0px;
}
}
@media screen and (max-width: 650px) {
.du-view div {
font-size: 14px;
}
.du-col-12 {
width: 100%;
padding-right: 1.1%;
}
.du-view h1,
.du-view .h1 {
font-size: 24px;
line-height: 34px;
}
.du-view h2,
.du-view .h2 {
font-size: 18px;
line-height: 24px;
}
}
@media screen and (min-width: 651px) and (max-width: 1024px) {
.du-view h1,
.du-view .h1 {
font-size: 36px;
line-height: 48px;
}
}
.du-margin-top-15 {
margin-top: 15px !important;
}
.du-margin-bottom-15 {
margin-bottom: 15px !important;
}
.du-margin-top-0 {
margin-top: 0px !important;
}
.du-margin-bottom-0 {
margin-bottom: 0px !important;
}
.du-padding-bottom-0 {
padding-bottom: 0px !important;
}
.du-margin-top-20 {
margin-top: 20px;
}
.du-margin-bottom-7 {
margin-bottom: 7px;
}
.du-margin-left-15 {
margin-left: 15px;
}
.du-simple-text {
line-height: 26px;
}
</style>
</xsl:template>
</xsl:stylesheet>