11321

ID	11321
Data	2022-02-07
Symbol	2022/02/07/11321
Instytucja	Ministerstwo Finansów
Nazwa	WH-WOP WNIOSEK PŁATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA
Czy Aktualny	1

Ustawy (1)

URI://Dziennik_Ustaw/2021/2070/16b/1	Art. 16b ust. 1 ustawy z dnia 17 lutego 2005 r. o informatyzacji działalności podmiotów realizujących zadania publiczne (Dz. U. z 2021 r. poz. 2070)

Pliki

• wyroznik.xml
• styl.xsl
• schemat.xsd

Styl

<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:pf="http://crd.gov.pl/wzor/2022/02/07/11321/" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="1.0">
	<xsl:import href="http://crd.gov.pl/xml/schematy/dziedzinowe/mf/2022/01/07/eD/DefinicjeSzablony/WspolneSzablonyWizualizacji_v12-0E.xsl"/>
	<xsl:param name="nazwy-dla-kodow" select="true()"/>
	<xsl:output method="html" encoding="UTF-8" indent="yes" version="4.01" doctype-public="-//W3C//DTD HTML 4.01//EN" doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
	<xsl:template name="TytulDokumentu">
	<div class="naglowek">
   WNIOSEK PŁATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA
   </div>
   </xsl:template>
	<xsl:template match="pf:Wniosek">
		<xsl:call-template name="NaglowekTechniczny">
			<xsl:with-param name="naglowek" select="pf:Naglowek"/>
			<xsl:with-param name="uzycie" select="'deklaracja'"/>
		</xsl:call-template>
		<xsl:call-template name="NaglowekTytulowy">
			<xsl:with-param name="naglowek" select="pf:Naglowek"/>
			<xsl:with-param name="uzycie" select="'deklaracja'"/>
			<xsl:with-param name="nazwa">WNIOSEK PŁATNIKA O WYDANIE OPINII O STOSOWANIU PREFERENCJI W POBORZE ZRYCZAŁTOWANEGO PODATKU DOCHODOWEGO OD NALEŻNOŚCI WYPŁACANYCH NA RZECZ PODATNIKA</xsl:with-param>
			<xsl:with-param name="podstawy-prawne">
				<table>
					<tr>
						<td class="etykieta">Podstawa prawna:</td>
						<td class="wartosc">Art. 26b ust. 1 ustawy z dnia 15 lutego 1992 r. o podatku dochodowym od osób prawnych (Dz. U. z 2021 poz. 1800, z późn. zm.).</td>
					</tr>
					<tr>
						<td class="etykieta">Składający:</td>
						<td class="wartosc">Płatnik podatku dochodowego od osób prawnych.</td>
					</tr>
					<tr>
						<td class="etykieta">Miejsce składania:</td>
						<td class="wartosc">Urząd skarbowy, o którym mowa w art. 26b ust. 10 ustawy.</td>
					</tr>
				</table>
			</xsl:with-param>
		</xsl:call-template>
		<xsl:call-template name="MiejsceICelWH">
			<xsl:with-param name="sekcja">A.</xsl:with-param>
		</xsl:call-template>
		<xsl:for-each select="pf:Podmiot1">
			<xsl:call-template name="Podmiot">
				<xsl:with-param name="sekcja">B.</xsl:with-param>
			</xsl:call-template>
		</xsl:for-each>
		<xsl:call-template name="DaneWniosku">
			<xsl:with-param name="sekcja">C.</xsl:with-param>
		</xsl:call-template>
		<xsl:for-each select="pf:PozycjeSzczegolowe/pf:VATRefundApplication/pf:Zalaczniki">
			<xsl:call-template name="Zalaczniki">
				<xsl:with-param name="sekcja">D.</xsl:with-param>
			</xsl:call-template>
		</xsl:for-each>
		<xsl:if test="*[local-name()='Oswiadczenie']=1">
			<xsl:call-template name="Oswiadczenie"/>
		</xsl:if>
	</xsl:template>
	<xsl:template match="pf:KodKraju | pf:KodKrajuWydania">
		<xsl:apply-templates/> 
        <xsl:if test="$nazwy-dla-kodow">
			<span class="nazwa-dla-kodu">
				<xsl:text>(</xsl:text>
				<xsl:call-template name="ZnajdzWEnumeracji">
					<xsl:with-param name="schema" select="$schema-krajow"/>
					<xsl:with-param name="typ" select="'TKodKraju'"/>
					<xsl:with-param name="kod" select="text()"/>
				</xsl:call-template>
				<xsl:text>)</xsl:text>
			</span>
		</xsl:if>
	</xsl:template>
	<xsl:template name="ZnajdzWEnumeracji">
		<xsl:param name="schema"/>
		<xsl:param name="typ"/>
		<xsl:param name="kod"/>
		<xsl:variable name="wschema" select="document($schema)"/>
		<xsl:value-of select="$wschema//xs:simpleType[@name=$typ]// xs:enumeration[@value = $kod]//xs:documentation"/>
	</xsl:template>
	<xsl:template name="MiejsceICelWH">
		<xsl:param name="sekcja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> CEL I MIEJSCE ZŁOŻENIA WNIOSKU</h2>
		<table class="normalna">
			<tr>
				<td class="niewypelnianeopisy">Cel złożenia</td>
				<td class="wypelniane">
					<xsl:for-each select="pf:Naglowek">
						<xsl:if test="pf:CelZlozenia='1'">
							<input type="checkbox" checked="checked" disabled="disabled"/>1. złożenie wniosku 
						</xsl:if>
						<xsl:if test="pf:CelZlozenia='2'">
							<input type="checkbox" checked="checked" disabled="disabled"/>2. korekta wniosku
						</xsl:if>
					</xsl:for-each>
				</td>
			</tr>
			<tr>
				<td class="niewypelnianeopisy" style="width:33%">Naczelnik urzędu skarbowego, do którego jest adresowany wniosek</td>
				<td class="wypelniane" style="width:auto">
					<xsl:apply-templates select="pf:Naglowek/pf:KodUrzedu"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template name="DaneWniosku">
		<xsl:param name="sekcja"/>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<h2 class="tytul-sekcja-blok">
				<xsl:value-of select="$sekcja"/> DANE WNIOSKU</h2>
			<table class="normalna">
				<td class="wypelniane" style="width: 30%">
					<div class="opisrubryki">6. Uzupełnienie poprzednio złożonego wniosku</div>
					<xsl:if test="pf:P_6='1'">
						<input type="checkbox" checked="checked" disabled="disabled"/>1. tak
						</xsl:if>
					<xsl:if test="pf:P_6='2'">
						<input type="checkbox" checked="checked" disabled="disabled"/>2. nie
						</xsl:if>
				</td>
				<td class="wypelniane" style="width: 50%">
					<div class="opisrubryki">6A. Numer Urzędowego Potwierdzenia Odbioru (UPO) złożenia wniosku, którego dotyczy uzupełnienie</div>
					<div class="kwota">
						<xsl:value-of select="pf:P_6A"/>
					</div>
				</td>
				<td class="wypelniane" style="width: 20%">
					<div class="opisrubryki">9. Identyfikator podatkowy:</div>
					<xsl:if test="pf:P_9='1'">
						<input type="checkbox" checked="checked" disabled="disabled"/>1. NIP
						</xsl:if>
					<xsl:if test="pf:P_9='2'">
						<input type="checkbox" checked="checked" disabled="disabled"/>2. numer PESEL
						</xsl:if>
				</td>
			</table>
		</xsl:for-each>
		<xsl:call-template name="PodmiotWH"/>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width: 100%">
						<div class="opisrubryki">24. Rodzaj dochodu</div>
						<div class="kwota">
							<xsl:value-of select="pf:P_24"/>
						</div>
					</td>
				</tr>
				<tr>
					<td class="wypelniane" style="width: 100%">
						<div class="opisrubryki">25. Treść wniosku</div>
						<div class="kwota">
							<xsl:value-of select="pf:P_25"/>
						</div>
					</td>
				</tr>
				<tr>
					<td class="wypelniane" style="width: 100%">
						<div class="opisrubryki">26. Uzupełnienie treści wniosku</div>
						<div class="kwota">
							<xsl:value-of select="pf:P_26"/>
						</div>
					</td>
				</tr>
				<tr>
					<td class="wypelniane" style="width: 100%">
						<div class="opisrubryki">27. Inne informacje, w tym ułatwiające kontakt z wnioskodawcą</div>
						<div class="kwota">
							<xsl:value-of select="pf:P_27"/>
						</div>
					</td>
				</tr>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="Zalaczniki">
		<xsl:param name="sekcja"/>
		<xsl:param name="pozycja"/>
		<h2 class="tytul-sekcja-blok">
			<xsl:value-of select="$sekcja"/> INFORMACJE O ZAŁĄCZONYCH KOPIACH DOKUMENTÓW</h2>
		<table class="normalna">
			<tr>
				<td class="puste2" style="width: 4%">
					<div class="opis-tekstowy">Lp.</div>
				</td>
				<td class="puste2" style="width: 20%">
					<div class="opis-tekstowy">Typ pliku</div>
				</td>
				<td class="puste2" style="width: 20%">
					<div class="opis-tekstowy">Nazwa pliku (bez ścieżki)</div>
				</td>
				<td class="puste2" style="width: 56%">
					<div class="opis-tekstowy">Opis pliku</div>
				</td>
			</tr>
			<xsl:for-each select="pf:InfOKopiiDokumentu">
				<tr>
					<td class="niewypelniane" style="width: 4%">
						<div class="symbol">
							<xsl:value-of select="position()"/>
						</div>
					</td>
					<td class="wypelniane" style="width: 20%">
						<xsl:value-of select="pf:TypPliku"/>
					</td>
					<td class="wypelniane" style="width: 20%">
						<xsl:value-of select="pf:NazwaPliku"/>
					</td>
					<td class="wypelniane" style="width: 54%">
						<xsl:value-of select="pf:OpisPliku"/>
					</td>
				</tr>
			</xsl:for-each>
		</table>
	</xsl:template>
	<xsl:template name="PodmiotWH">
		<h3 class="tytul-sekcja-blok"> Dane podatnika</h3>
		<xsl:for-each select="pf:PozycjeSzczegolowe">
			<table class="normalna">
				<tr>
					<xsl:if test="*[local-name()='Nazwa']">
						<tr>
							<td class="wypelniane" style="width:60%">
								<div class="opisrubryki">10. Nazwa pełna</div>
								<xsl:apply-templates select="*[local-name()='Nazwa']"/>
							</td>
						</tr>
					</xsl:if>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:35%">
						<div class="opisrubryki">11. Rodzaj numeru identyfikacyjnego</div>
						<xsl:choose>
							<xsl:when test="pf:RodzajNrId='1'">1. numer identyfikacyjny TIN</xsl:when>
							<xsl:when test="pf:RodzajNrId='8'">8. inny rodzaj identyfikacji podatkowej</xsl:when>
						</xsl:choose>
					</td>
					<xsl:if test="*[local-name()='NIP' ]">
						<td class="wypelniane" style="width:35%">
							<div class="opisrubryki">12. Identyfikator podatkowy NIP</div>
							<xsl:apply-templates select="*[local-name() = 'NIP']"/>
						</td>
					</xsl:if>
					<xsl:if test="*[local-name()='NrId' ]">
						<td class="wypelniane" style="width:35%">
							<div class="opisrubryki">12. Numer identyfikacyjny podatnika</div>
							<xsl:apply-templates select="*[local-name()='NrId']"/>
						</td>
					</xsl:if>
					<td class="wypelniane" style="width:30%">
						<div class="opisrubryki">13. Kraj wydania numeru identyfikacyjnego</div>
						<xsl:apply-templates select="pf:KodKrajuWydania"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">14. Kraj</div>
						<xsl:for-each select="pf:P_14">
							<xsl:call-template name="PokazKodKraju"/>
						</xsl:for-each>
					</td>
					<td class="wypelniane" style="width:40%">
						<div class="opisrubryki">15. Województwo</div>
						<xsl:value-of select="pf:P_15"/>
					</td>
					<td class="wypelniane" style="width:40%">
						<div class="opisrubryki">16. Powiat</div>
						<xsl:value-of select="pf:P_16"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane" style="width:35%">
						<div class="opisrubryki">17. Gmina</div>
						<xsl:value-of select="pf:P_17"/>
					</td>
					<td class="wypelniane">
						<div class="opisrubryki">18. Ulica</div>
						<xsl:value-of select="pf:P_18"/>
					</td>
					<td class="wypelniane" style="width:10%">
						<div class="opisrubryki">19. Numer domu</div>
						<xsl:value-of select="pf:P_19"/>
					</td>
					<td class="wypelniane" style="width:10%">
						<div class="opisrubryki">20. Numer lokalu</div>
						<xsl:value-of select="pf:P_20"/>
					</td>
				</tr>
			</table>
			<table class="normalna">
				<tr>
					<td class="wypelniane">
						<div class="opisrubryki">21. Miejscowość</div>
						<xsl:value-of select="pf:P_21"/>
					</td>
					<td class="wypelniane">
						<div class="opisrubryki">22. Kod pocztowy</div>
						<xsl:value-of select="pf:P_22"/>
					</td>
					<td class="wypelniane">
						<div class="opisrubryki">23. Poczta</div>
						<xsl:value-of select="pf:P_23"/>
					</td>
				</tr>
			</table>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="Oswiadczenie">
		<h2 class="tekst">Oświadczenie<br/>
		</h2>
		<h3 align="justify">Oświadczam, że fakty przedstawione we wniosku o wydanie opinii o stosowaniu preferencji są zgodne z prawdą, oraz że dokumentacja załączona do wniosku jest zgodna z oryginałem.
</h3>
		<div class="lamstrone"/>
	</xsl:template>
	<xsl:template name="StyleDlaFormularza">
		<style type="text/css">
            .tlo-formularza { background-color:#D8D8D8; }
        </style>
	</xsl:template>
</xsl:stylesheet>